You are not logged in.

Pages: 1 2

#26 2007-10-16 12:29:53

voonte
Member
Registered: 2007-08-02
Posts: 15

Re: Chinese input in KDE [Solved]

sweiss wrote:

If I recall correctly, there was a release of Qt with the qt-immodule included, but it was quickly removed because it broke binary compatibility.

Gentoo seem to have two USE flags for the immqt patch.

euse -i immqt
local use flags (searching: immqt)
************************************************************
[-    ] immqt (x11-libs/qt):
Enable binary incompatible version of immodule for Qt

[+ C  ] immqt-bc (x11-libs/qt):
Enable binary compatible version of immodule for Qt

I haven't actually tested this, but I guess this could be a solution.

Offline

#27 2013-07-18 10:24:38

Heikete
Member
Registered: 2007-04-28
Posts: 40

Re: Chinese input in KDE [Solved]

Is there any progress in solving scim input in Qt apps?  I can't compile scim-qtimm because I got an error

 The Qt library was not compiled with the qt-immodule patch

I found there should be a package qt-enhanced with the relevant patch applied, however I can't even find the correct source for this.
I need Japanese input in Skype is there any other version of Skype that should work?
My exports:

export XMODIFIERS="@im=SCIM"
export GTK_IM_MODULE="scim"
export QT_IM_MODULE="scim"
export LC_CTYPE="pl_PL.UTF-8"
export XIM_PROGRAM="scim -d"
scim -d

There's no problem in most of GTK apps, I use openoffice instead of LibreOffice, but Skype is urgent.

Offline

#28 2013-07-18 10:35:14

Si
Member
Registered: 2006-09-11
Posts: 57

Re: Chinese input in KDE [Solved]

Are you running 64-bit? If so, you need the 32-bit Qt qt-im-module plugin in order to use scim in Skype. I had a similar problem with gcin, and I had to create my own package for adding the 32-bit qt-im-module plugin.

Offline

#29 2013-07-18 15:19:45

Heikete
Member
Registered: 2007-04-28
Posts: 40

Re: Chinese input in KDE [Solved]

Yes I'm using 64-bit arch. Could you post the PKBUILD that you have used?

Offline

#30 2013-07-22 10:04:30

Si
Member
Registered: 2006-09-11
Posts: 57

Re: Chinese input in KDE [Solved]

First, you'll need 32-bit qmake. I use this PKGBUILD for generating a lib32-qt4-dev package that includes qmake and other tools. It's slightly out of date, but it's fairly easy to update it to the latest. Just compare this and the stock lib32-qt4's PKGBUILD.

# $Id: PKGBUILD 80785 2012-12-03 16:17:19Z bluewind $
# Maintainer: Florian Pritz <flo@xssn.at>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

_pkgbasename=qt4
pkgname=(lib32-$_pkgbasename lib32-$_pkgbasename-dev)
pkgver=4.8.4
pkgrel=5
pkgdesc='A cross-platform application and UI framework (32-bit)'
arch=('x86_64')
url='http://qt-project.org/'
license=('GPL3' 'LGPL')
depends=(lib32-{fontconfig,sqlite3,alsa-lib,glib2,dbus-core,openssl}
         lib32-lib{png,tiff,mng,gl,sm,xrandr,xv,xi} $_pkgbasename)
optdepends=('lib32-libxinerama: Xinerama support'
            'lib32-libxcursor: Xcursor support'
            'lib32-libxfixes: Xfixes support')
makedepends=(cups gcc-multilib lib32-{mesa,libcups,libxfixes,gtk2})
options=('!libtool')
provides=(lib32-qtwebkit)
replaces=(lib32-qtwebkit 'lib32-qt<=4.8.4')
conflicts=(lib32-qtwebkit lib32-qt)
_pkgfqn="qt-everywhere-opensource-src-${pkgver}"
source=("http://releases.qt-project.org/qt4/source/${_pkgfqn}.tar.gz")
md5sums=('89c5ecba180cae74c66260ac732dc5cb')

build() {
  cd $srcdir/$_pkgfqn

  export QT4DIR=$srcdir/$_pkgfqn
  export LD_LIBRARY_PATH=${QT4DIR}/lib:${LD_LIBRARY_PATH}
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  # some of those are likely unnecessary, but I'm too lazy to find and remove them
  sed -i "/^QMAKE_LINK\s/s|g++|g++ -m32|g" mkspecs/common/g++-base.conf
  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/g++-base.conf
  sed -i "s|-O2|${CXXFLAGS} -m32|" mkspecs/common/gcc-base.conf
  sed -i "/^QMAKE_LFLAGS_RPATH/s| -Wl,-rpath,||g" mkspecs/common/gcc-base-unix.conf
  sed -i "/^QMAKE_LFLAGS\s/s|+=|+= ${LDFLAGS} -m32|g" mkspecs/common/gcc-base.conf
  sed -i "s|-Wl,-O1|-m32 -Wl,-O1|" mkspecs/common/g++-unix.conf
  sed -e "s|-O2|$CXXFLAGS -m32|" \
      -e "/^QMAKE_RPATH/s| -Wl,-rpath,||g" \
      -e "/^QMAKE_LINK\s/s|g++|g++ -m32|g" \
      -e "/^QMAKE_LFLAGS\s/s|+=|+= $LDFLAGS|g" \
      -i mkspecs/common/g++.conf

  ./configure -confirm-license -opensource -v -platform linux-g++-32 \
    -prefix /opt/lib32-qt4 \
    -libdir /usr/lib32 \
    -plugindir /usr/lib32/qt/plugins \
    -importdir /usr/lib32/qt/imports \
    -datadir /usr/share/qt \
    -translationdir /usr/share/qt/translations \
    -sysconfdir /etc \
    -system-sqlite \
    -no-phonon \
    -no-phonon-backend \
    -webkit \
    -graphicssystem raster \
    -openssl-linked \
    -nomake demos \
    -nomake examples \
    -nomake docs \
    -nomake tools \
    -optimized-qmake \
    -no-rpath \
    -dbus-linked \
    -reduce-relocations \
    -no-openvg

  make
}

package_lib32-qt4() {
  cd $srcdir/$_pkgfqn
  make INSTALL_ROOT=$pkgdir install

  # Fix wrong path in pkgconfig files
  find ${pkgdir}/usr/lib32/pkgconfig -type f -name '*.pc' \
    -exec perl -pi -e "s, -L${srcdir}/?\S+,,g" {} \;
  # Fix wrong path in prl files
  find ${pkgdir}/usr/lib32 -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d;s/\(QMAKE_PRL_LIBS =\).*/\1/' {} \;

  #rm -rf "${pkgdir}"/usr/{include,share,bin}
  rm -rf "${pkgdir}"/{usr/{include,share,bin,tests},opt}
  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}

package_lib32-qt4-dev() {
  conflicts=(lib32-$_pkgbasename lib32-qtwebkit)
  provides=(lib32-$_pkgbasename lib32-qtwebkit)
  replaces=(lib32-$_pkgbasename lib32-qtwebkit)
  cd $srcdir/$_pkgfqn
  make INSTALL_ROOT=$pkgdir install

  # Fix wrong path in pkgconfig files
  find ${pkgdir}/usr/lib32/pkgconfig -type f -name '*.pc' \
    -exec perl -pi -e "s, -L${srcdir}/?\S+,,g" {} \;
  # Fix wrong path in prl files
  find ${pkgdir}/usr/lib32 -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d;s/\(QMAKE_PRL_LIBS =\).*/\1/' {} \;

  mkdir -p "$pkgdir/usr/share/licenses"
  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}

Then, you'll need to build the 32-bit qt-im-module for your input method. I use gcin, you can probably use mine as an example, but I suspect compiling scim will be quite different.

# $Id: PKGBUILD 162854 2012-07-02 00:37:56Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: damir <damir@archlinux.org>

_pkgbasename=gcin
pkgname=lib32-$_pkgbasename
pkgver=2.8.0
pkgrel=1
pkgdesc='Input method server supporting various input methods'
url='http://hyperrate.com/dir.php?eid=67'
license=('LGPL')
arch=('x86_64')
depends=('lib32-gtk2' 'lib32-libxtst')
makedepends=('lib32-qt4' 'lib32-anthy' 'lib32-libchewing')
optdepends=('lib32-qt4: support for qt4 input method'
            'lib32-gtk3: support for gtk3 input method'
            'lib32-anthy: support for anthy input method'
            'lib32-libchewing: support for chewing input method')
source=("http://www.csie.nctu.edu.tw/~cp76/gcin/download/${_pkgbasename}-${pkgver}.tar.xz")
sha1sums=('69fe604939bc013f043ff0b4baa63b7951b26c95')

install=install

build() {
    export CC="gcc -m32"
    export CXX="g++ -m32"
    export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
    cd "${srcdir}/${_pkgbasename}-${pkgver}"

    sed '/include suffixes-rule/a \
        CFLAGS+='"${CFLAGS}"' \
        LDFLAGS+='"${LDFLAGS}"' \
        OPTFLAGS=' \
    -i Makefile

    sed -e "s/LIB='lib'/LIB='lib32'/g" -i configure
    sed -e "s/LIB='lib64'/LIB='lib32'/g" -i configure
    sed -e 's/\/usr\/bin\/moc/\/opt\/lib32-qt4\/bin\/moc/' -i configure
    ./configure --prefix=/usr --use_i18n=Y --use_gtk3=N --use_anthy=N --use_chewing=N
    make
}

package() {
    cd "${srcdir}/${_pkgbasename}-${pkgver}"
    make DESTDIR="${pkgdir}" install
    rm -rf "${pkgdir}"/usr/{bin,share}
}

Offline

Pages: 1 2

Board footer

Powered by FluxBB