You are not logged in.

Pages: 1

#1 2012-02-02 23:31:02

ferda
Member
Registered: 2010-02-05
Posts: 67

Firefox & Thunderbird ESR

Hello everybody,

I hope this hasn’t already been discussed in other places.

Are there any plans to include the new extended support releases (ESR) in the repos?

I’ve modified the PKGBUILDs from ABS to get ESR packages and they have been built without a problem.

# $Id: PKGBUILD 145445 2011-12-22 12:34:40Z ibiru $
# Contributor: Jakub Schmidtke <sjakub@gmail.com>

pkgname=firefox-esr
conflicts=firefox
provides=firefox
pkgver=10.0esr
pkgrel=1
pkgdesc="Standalone web browser from mozilla.org"
arch=('i686' 'x86_64')
license=('MPL' 'GPL' 'LGPL')
depends=('gtk2' 'mozilla-common' 'nss>=3.13.1' 'libxt' 'hunspell' 'startup-notification' 'mime-types' 'dbus-glib' 'alsa-lib' 'sqlite3' 'libnotify' 'desktop-file-utils' 'libvpx' 'libevent' 'hicolor-icon-theme')
makedepends=('unzip' 'zip' 'pkg-config' 'diffutils' 'python2' 'wireless_tools' 'yasm' 'mesa' 'autoconf2.13' 'libidl2' 'xorg-server-xvfb')
url="http://www.mozilla.org/projects/firefox"
install=firefox.install
source=(ftp://ftp.mozilla.org/pub/mozilla.org/firefox/releases//$pkgver/source/firefox-$pkgver.source.tar.bz2
        mozconfig firefox.desktop firefox-install-dir.patch vendor.js)

build() {
  cd "$srcdir/mozilla-esr10"

  cp "$srcdir/mozconfig" .mozconfig
  patch -Np1 -i "$srcdir/firefox-install-dir.patch"

  # Fix PRE_RELEASE_SUFFIX
  sed -i '/^PRE_RELEASE_SUFFIX := ""/s/ ""//' \
    browser/base/Makefile.in

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/firefox"
  export PYTHON="/usr/bin/python2"

  LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
  LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS="$MAKEFLAGS"
  kill $! || true
}

package() {
  cd "$srcdir/mozilla-esr10"
  make -j1 -f client.mk DESTDIR="$pkgdir" install

  install -m644 "$srcdir"/vendor.js "$pkgdir/usr/lib/firefox/defaults/pref"

  for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
      install -Dm644 browser/branding/official/default${i/x*/}.png \
        "$pkgdir/usr/share/icons/hicolor/$i/apps/firefox.png"
  done

  install -Dm644 "$srcdir/firefox.desktop" \
    "$pkgdir/usr/share/applications/firefox.desktop"

  rm -rf "$pkgdir"/usr/lib/firefox/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "$pkgdir/usr/lib/firefox/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/usr/lib/firefox/hyphenation"


  # We don't want the development stuff
  rm -r "$pkgdir"/usr/{include,lib/firefox-devel,share/idl}

  #workaround for now
  #https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf firefox "$pkgdir/usr/lib/firefox/firefox-bin"
}
md5sums=('a274253ffde785ec201649b377ac891d'
         '4b925c654eb2484e26d08f743df118fa'
         'bdeb0380c7fae30dd0ead6d2d3bc5873'
         '594523c536a9be951b52c90dd85aff18'
         '0d053487907de4376d67d8f499c5502b')
# $Id: PKGBUILD 145621 2011-12-24 12:08:31Z ibiru $
# Contributor: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Anders Bostrom <anders.bostrom@home.se>

pkgname=thunderbird-esr
conflicts=thunderbird
provides=thunderbird
pkgver=10.0esr
pkgrel=1
pkgdesc="Standalone Mail/News reader"
arch=('i686' 'x86_64')
license=('MPL' 'GPL')
url="http://www.mozilla.org/thunderbird/"
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hicolor-icon-theme' 'hunspell' 'libevent' 'libnotify' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite3' 'startup-notification')
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'wireless_tools' 'yasm' 'mesa')
optdepends=('libcanberra: for sound support')
install=thunderbird.install
source=(ftp://ftp.mozilla.org/pub/mozilla.org/thunderbird/releases/$pkgver/source/thunderbird-$pkgver.source.tar.bz2
        mozconfig
        thunderbird.desktop
        thunderbird-install-dir.patch
        vendor.js)
md5sums=('20b4c841ac8b1d475787760d68c0c1c5'
         'ca98c2bf1017b33e19dae22fdcef2e73'
         'af3e5b344d2edf1c7d61bb0a5a96de9a'
         'aea906acf72c43dd82ead2fabcc1c6db'
         '5a53179d14ae9631b7afe5e4d0fc0b25')

build() {
  cd "$srcdir/comm-esr10"
  patch -Np1 -i "$srcdir/thunderbird-install-dir.patch"

  cp "$srcdir/mozconfig" .mozconfig

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/thunderbird"
  export PYTHON="/usr/bin/python2"

  make -j1 -f client.mk build MOZ_MAKE_FLAGS="$MAKEFLAGS"
}

package() {
  cd "$srcdir/comm-esr10"
  make -j1 -f client.mk DESTDIR="$pkgdir" install

  install -m644 "$srcdir"/vendor.js "$pkgdir/usr/lib/thunderbird/defaults/pref/"

  for i in 16x16 22x22 24x24 32x32 48x48 256x256; do
      install -Dm644 other-licenses/branding/thunderbird/mailicon${i/x*/}.png \
          "$pkgdir/usr/share/icons/hicolor/$i/apps/thunderbird.png"
  done

  install -Dm644 "$srcdir/thunderbird.desktop" \
      "$pkgdir/usr/share/applications/thunderbird.desktop"

  rm -rf "$pkgdir"/usr/lib/thunderbird/{dictionaries,hyphenation}
  ln -sf /usr/share/hunspell "$pkgdir/usr/lib/thunderbird/dictionaries"
  ln -sf /usr/share/hyphen "$pkgdir/usr/lib/thunderbird/hyphenation"

  # We don't want the development stuff
  rm -r "$pkgdir"/usr/{include,lib/thunderbird-devel,share/idl}
}

These are the adresses for the PKGBUILDs of the corresponding i18n packages:
http://paste.pocoo.org/show/544894 http://paste.pocoo.org/show/544897

Offline

#2 2012-03-30 13:18:30

max-k
Member
From: Lyon - France
Registered: 2007-11-23
Posts: 38

Re: Firefox & Thunderbird ESR

Hi,
I'm really interested in this support.
Could you maintain these packages in AUR.
Perhaps we could vote for them and make them included in community.

Offline

#3 2012-03-30 13:21:08

max-k
Member
From: Lyon - France
Registered: 2007-11-23
Posts: 38

Re: Firefox & Thunderbird ESR

Latest release of thunderbird is here :
ftp://ftp.mozilla.org/pub/mozilla.org/t … ce.tar.bz2
Latest release of firefox is here :
ftp://ftp.mozilla.org/pub/mozilla.org/f … ce.tar.bz2

Offline

#4 2012-03-30 15:39:45

fsckd
Forum Fellow
Registered: 2009-06-15
Posts: 4,173

Re: Firefox & Thunderbird ESR

AUR can be searched: http://aur.archlinux.org/packages.php?K=firefox-esr http://aur.archlinux.org/packages.php?K=thunderbird-esr

aur S & M :: forum rules :: Community Ethos
Resources for Women, POC, LGBT*, and allies

Offline

#5 2012-06-05 14:32:39

max-k
Member
From: Lyon - France
Registered: 2007-11-23
Posts: 38

Re: Firefox & Thunderbird ESR

ferda wrote:

Hello everybody,
These are the adresses for the PKGBUILDs of the corresponding i18n packages:
http://paste.pocoo.org/show/544894 http://paste.pocoo.org/show/544897

Your pastebin is dead.

Offline

#6 2012-06-05 16:49:17

tomk
Forum Fellow
From: Ireland
Registered: 2004-07-21
Posts: 9,839

Re: Firefox & Thunderbird ESR

Firefox ESR site wrote:

Who is it not for?
Individual users who always want the latest features, performance enhancements and technologies in their browser

So... not for Arch users then, I guess. wink

IMO ESR is incompatible with the Arch approach, so I'd be surprised if it ever turns up in the repos. The AUR, however, would be perfect for it.

http://www.mozilla.org/en-US/firefox/organizations/

Offline

Pages: 1

Board footer

Powered by FluxBB