You are not logged in.

#1 2015-12-28 22:48:39

0strodamus
Member
Registered: 2014-01-22
Posts: 92

[SOLVED] Cannot delete or correct my AUR mesa-nosystemd package

I've uploaded a completely broken mesa-nosystemd package to the AUR. I should have left the pkgbase be opencl-mesa-nosystemd as that is the first package in the array. Instead, I placed mesa-nosystemd as the first package in my PKGBUILD so that it would be the AUR pkgbase. In typical moron fashion, I didn't realize at the time that change would break the PKGBUILD.

I have tried various things within git to delete and replace this package without success. I know that sounds pretty vague. I tried using information I found on stackoverflow here and here, I submitted a file request within the AUR web interface to have the package deleted, so that I can push a fixed version with opencl-mesa-nosystemd as the pkgbase.

Should I continue to wait for a response to my file request or is this something I should be able to do myself within git? Any help would be greatly appreciated!

Last edited by 0strodamus (2015-12-29 23:19:56)


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

#2 2015-12-28 23:12:06

progandy
Member
Registered: 2012-05-17
Posts: 5,184

Re: [SOLVED] Cannot delete or correct my AUR mesa-nosystemd package

You can set "pkgbase" manually without relying on the order in the pkgname array. Then you should be able to commit an update.
I also suggest you modify the PKGBUILD so that the packaging order doesn't matter.


| alias CUTF='LANG=en_XX.UTF-8@POSIX ' |

Offline

#3 2015-12-29 02:18:41

0strodamus
Member
Registered: 2014-01-22
Posts: 92

Re: [SOLVED] Cannot delete or correct my AUR mesa-nosystemd package

Thanks for replying. I added pkgbase=('mesa-nosystemd') to my PKGBUILD, reran mksrcinfo, and committed the change:

$ git commit -am 'update to 11.1.0-2'

git push is giving me the following error. This is the same error I was getting before adding pkgbase to my PKGBUILD. The odd thing is that now even if I re-arrange the pkgname array to match what I first uploaded, the same error occurs.

Counting objects: 24, done.
Delta compression using up to 8 threads.
Compressing objects: 100% (24/24), done.
Writing objects: 100% (24/24), 2.51 KiB | 0 bytes/s, done.
Total 24 (delta 11), reused 0 (delta 0)
remote: error: The following error occurred when parsing commit
remote: error: d0848047a09395f938c8ba9ce088139582c345ad:
remote: error: missing mandatory field: pkgver
remote: error: hook declined to update refs/heads/master
To ssh://aur@aur.archlinux.org/mesa-nosystemd.git
 ! [remote rejected] master -> master (hook declined)
error: failed to push some refs to 'ssh://aur@aur.archlinux.org/mesa-nosystemd.git'

Both my PKGBUILD and .SRCINFO have pkgvers.

# Maintainer: 0strodamus <0strodamus at cox dot net>
# Contributor: Eric Vidal <eric@obarun.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>

pkgbase=('mesa-nosystemd')
pkgname=('opencl-mesa-nosystemd' 'libva-mesa-driver-nosystemd' 'mesa-vdpau-nosystemd' 'mesa-nosystemd' 'mesa-libgl-nosystemd')
pkgver=11.1.0
pkgrel=2
arch=('i686' 'x86_64')
makedepends=('python2-mako' 'libxml2' 'libx11' 'glproto' 'libdrm' 'dri2proto' 'dri3proto' 'presentproto' 
             'libxshmfence' 'libxxf86vm' 'libxdamage' 'libvdpau' 'libva' 'wayland' 'elfutils' 'llvm'
             'libomxil-bellagio' 'libgcrypt' 'libclc' 'clang')
url="http://mesa3d.sourceforge.net"
license=('custom')
source=(ftp://ftp.freedesktop.org/pub/mesa/${pkgver}/mesa-${pkgver}.tar.xz{,.sig}
        LICENSE)
sha256sums=('9befe03b04223eb1ede177fa8cac001e2850292c8c12a3ec9929106afad9cf1f'
            'SKIP'
            '7fdc119cf53c8ca65396ea73f6d10af641ba41ea1dd2bd44a824726e01c8b3f2')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

prepare() {
  cd ${srcdir}/?esa-*

  # Fix detection of libLLVM when built with CMake
  sed -i 's/LLVM_SO_NAME=.*/LLVM_SO_NAME=LLVM/' configure
}

build() {
  cd ${srcdir}/?esa-*

  #autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --with-dri-driverdir=/usr/lib/xorg/modules/dri \
    --with-gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast \
    --with-dri-drivers=i915,i965,r200,radeon,nouveau,swrast \
    --with-egl-platforms=x11,drm,wayland \
    --with-sha1=libgcrypt \
    --enable-llvm-shared-libs \
    --enable-egl \
    --enable-gbm \
    --enable-gallium-llvm \
    --enable-shared-glapi \
    --enable-glx \
    --enable-glx-tls \
    --enable-dri \
    --enable-osmesa \
    --enable-gles1 \
    --enable-gles2 \
    --enable-texture-float \
    --enable-xa \
    --enable-vdpau \
    --enable-omx \
    --enable-nine \
    --enable-opencl --enable-opencl-icd \
    --with-clang-libdir=/usr/lib

    # --help

  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=${srcdir}/fakeinstall install
}

package_opencl-mesa-nosystemd() {
  pkgdesc="OpenCL support for AMD/ATI Radeon mesa drivers"
  depends=('expat' 'libdrm' 'elfutils' 'libxfixes' 'libxext' 'opencl-icd-loader' 'libclc' 'clang')
  provides=('opencl-mesa')
  conflicts=('opencl-mesa')
  replaces=('opencl-mesa')
  optdepends=('opencl-headers: headers necessary for OpenCL development')
  
  install -m755 -d ${pkgdir}/etc
  mv -v ${srcdir}/fakeinstall/etc/OpenCL ${pkgdir}/etc/
  
  install -m755 -d ${pkgdir}/usr/lib/gallium-pipe
  mv -v ${srcdir}/fakeinstall/usr/lib/lib*OpenCL* ${pkgdir}/usr/lib/
  mv -v ${srcdir}/fakeinstall/usr/lib/gallium-pipe/pipe_{r600,radeonsi}.so ${pkgdir}/usr/lib/gallium-pipe/

  install -m755 -d "${pkgdir}/usr/share/licenses/opencl-mesa"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/opencl-mesa/"
}

package_libva-mesa-driver-nosystemd() {
  pkgdesc="VA-API implementation for gallium"
  depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'elfutils')
  provides=('libva-mesa-driver')
  conflicts=('libva-mesa-driver')
  replaces=('libva-mesa-driver')
  install -m755 -d ${pkgdir}/usr/lib
  mv -v ${srcdir}/fakeinstall/usr/lib/dri ${pkgdir}/usr/lib
   
  install -m755 -d "${pkgdir}/usr/share/licenses/libva-mesa-driver"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/libva-mesa-driver/"
}

package_mesa-vdpau-nosystemd() {
  pkgdesc="Mesa VDPAU drivers"
  depends=('libdrm' 'libx11' 'llvm-libs' 'expat' 'elfutils')
  provides=('mesa-vdpau')
  conflicts=('mesa-vdpau')
  replaces=('mesa-vdpau')
  install -m755 -d ${pkgdir}/usr/lib
  mv -v ${srcdir}/fakeinstall/usr/lib/vdpau ${pkgdir}/usr/lib
   
  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-vdpau"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-vdpau/"
}

package_mesa-nosystemd() {
  pkgdesc="an open-source implementation of the OpenGL specification"
  depends=('libdrm' 'wayland' 'libxxf86vm' 'libxdamage' 'libxshmfence' 'elfutils' 
           'libomxil-bellagio' 'expat' 'libgcrypt' 'libtxc_dxtn' 'llvm-libs')
  optdepends=('opengl-man-pages: for the OpenGL API man pages'
              'mesa-vdpau-nosystemd: for accelerated video playback'
              'libva-mesa-driver-nosystemd: for accelerated video playback')
  provides=('libglapi' 'osmesa' 'libgbm' 'libgles' 'libegl' 'khrplatform-devel'
            'ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri' 'mesa')
  conflicts=('libglapi' 'osmesa' 'libgbm' 'libgles' 'libegl' 'khrplatform-devel'
             'ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri' 'mesa')
  replaces=('libglapi' 'osmesa' 'libgbm' 'libgles' 'libegl' 'khrplatform-devel'
            'ati-dri' 'intel-dri' 'nouveau-dri' 'svga-dri' 'mesa-dri' 'mesa')

  install -m755 -d ${pkgdir}/etc
  mv -v ${srcdir}/fakeinstall/etc/drirc ${pkgdir}/etc
  
  install -m755 -d ${pkgdir}/usr/lib/xorg/modules/dri
  # ati-dri, nouveau-dri, intel-dri, svga-dri, swrast
  mv -v ${srcdir}/fakeinstall/usr/lib/xorg/modules/dri/* ${pkgdir}/usr/lib/xorg/modules/dri
   
  mv -v ${srcdir}/fakeinstall/usr/lib/bellagio  ${pkgdir}/usr/lib
  mv -v ${srcdir}/fakeinstall/usr/lib/d3d  ${pkgdir}/usr/lib
  mv -v ${srcdir}/fakeinstall/usr/lib/*.so* ${pkgdir}/usr/lib/

  mv -v ${srcdir}/fakeinstall/usr/include ${pkgdir}/usr
  mv -v ${srcdir}/fakeinstall/usr/lib/pkgconfig ${pkgdir}/usr/lib/
  
  install -m755 -d ${pkgdir}/usr/lib/mesa
  # move libgl/EGL/glesv*.so to not conflict with blobs - may break .pc files ?
  mv -v ${pkgdir}/usr/lib/libGL.so* 	${pkgdir}/usr/lib/mesa/
  mv -v ${pkgdir}/usr/lib/libEGL.so* 	${pkgdir}/usr/lib/mesa/
  mv -v ${pkgdir}/usr/lib/libGLES*.so*	${pkgdir}/usr/lib/mesa/

  install -m755 -d "${pkgdir}/usr/share/licenses/mesa"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa/"
}

package_mesa-libgl-nosystemd() {
  pkgdesc="Mesa 3-D graphics library"
  depends=('mesa-nosystemd')
  provides=('libgl' 'mesa-libgl')
  conflicts=('mesa-libgl')
  replaces=('libgl' 'mesa-libgl')
 
  # See FS#26284
  install -m755 -d "${pkgdir}/usr/lib/xorg/modules/extensions"
  ln -s libglx.xorg "${pkgdir}/usr/lib/xorg/modules/extensions/libglx.so"

  ln -s /usr/lib/mesa/libGL.so.1.2.0 ${pkgdir}/usr/lib/libGL.so.1.2.0
  ln -s libGL.so.1.2.0	             ${pkgdir}/usr/lib/libGL.so.1
  ln -s libGL.so.1.2.0               ${pkgdir}/usr/lib/libGL.so

  ln -s /usr/lib/mesa/libEGL.so.1.0.0 ${pkgdir}/usr/lib/libEGL.so.1.0.0
  ln -s libEGL.so.1.0.0	              ${pkgdir}/usr/lib/libEGL.so.1
  ln -s libEGL.so.1.0.0               ${pkgdir}/usr/lib/libEGL.so

  ln -s /usr/lib/mesa/libGLESv1_CM.so.1.1.0 ${pkgdir}/usr/lib/libGLESv1_CM.so.1.1.0
  ln -s libGLESv1_CM.so.1.1.0	            ${pkgdir}/usr/lib/libGLESv1_CM.so.1
  ln -s libGLESv1_CM.so.1.1.0               ${pkgdir}/usr/lib/libGLESv1_CM.so

  ln -s /usr/lib/mesa/libGLESv2.so.2.0.0 ${pkgdir}/usr/lib/libGLESv2.so.2.0.0
  ln -s libGLESv2.so.2.0.0               ${pkgdir}/usr/lib/libGLESv2.so.2
  ln -s libGLESv2.so.2.0.0               ${pkgdir}/usr/lib/libGLESv2.so

  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-libgl"
  install -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-libgl/"
}
# Generated by mksrcinfo v8
# Tue Dec 29 01:11:58 UTC 2015
pkgbase = mesa-nosystemd
	pkgver = 11.1.0
	pkgrel = 2
	url = http://mesa3d.sourceforge.net
	arch = i686
	arch = x86_64
	license = custom
	makedepends = python2-mako
	makedepends = libxml2
	makedepends = libx11
	makedepends = glproto
	makedepends = libdrm
	makedepends = dri2proto
	makedepends = dri3proto
	makedepends = presentproto
	makedepends = libxshmfence
	makedepends = libxxf86vm
	makedepends = libxdamage
	makedepends = libvdpau
	makedepends = libva
	makedepends = wayland
	makedepends = elfutils
	makedepends = llvm
	makedepends = libomxil-bellagio
	makedepends = libgcrypt
	makedepends = libclc
	makedepends = clang
	source = ftp://ftp.freedesktop.org/pub/mesa/11.1.0/mesa-11.1.0.tar.xz
	source = ftp://ftp.freedesktop.org/pub/mesa/11.1.0/mesa-11.1.0.tar.xz.sig
	source = LICENSE
	sha256sums = 9befe03b04223eb1ede177fa8cac001e2850292c8c12a3ec9929106afad9cf1f
	sha256sums = SKIP
	sha256sums = 7fdc119cf53c8ca65396ea73f6d10af641ba41ea1dd2bd44a824726e01c8b3f2

pkgname = opencl-mesa-nosystemd
	pkgdesc = OpenCL support for AMD/ATI Radeon mesa drivers
	depends = expat
	depends = libdrm
	depends = elfutils
	depends = libxfixes
	depends = libxext
	depends = opencl-icd-loader
	depends = libclc
	depends = clang
	optdepends = opencl-headers: headers necessary for OpenCL development
	provides = opencl-mesa
	conflicts = opencl-mesa
	replaces = opencl-mesa

pkgname = libva-mesa-driver-nosystemd
	pkgdesc = VA-API implementation for gallium
	depends = libdrm
	depends = libx11
	depends = llvm-libs
	depends = expat
	depends = elfutils
	provides = libva-mesa-driver
	conflicts = libva-mesa-driver
	replaces = libva-mesa-driver

pkgname = mesa-vdpau-nosystemd
	pkgdesc = Mesa VDPAU drivers
	depends = libdrm
	depends = libx11
	depends = llvm-libs
	depends = expat
	depends = elfutils
	provides = mesa-vdpau
	conflicts = mesa-vdpau
	replaces = mesa-vdpau

pkgname = mesa-nosystemd
	pkgdesc = an open-source implementation of the OpenGL specification
	depends = libdrm
	depends = wayland
	depends = libxxf86vm
	depends = libxdamage
	depends = libxshmfence
	depends = elfutils
	depends = libomxil-bellagio
	depends = expat
	depends = libgcrypt
	depends = libtxc_dxtn
	depends = llvm-libs
	optdepends = opengl-man-pages: for the OpenGL API man pages
	optdepends = mesa-vdpau-nosystemd: for accelerated video playback
	optdepends = libva-mesa-driver-nosystemd: for accelerated video playback
	provides = libglapi
	provides = osmesa
	provides = libgbm
	provides = libgles
	provides = libegl
	provides = khrplatform-devel
	provides = ati-dri
	provides = intel-dri
	provides = nouveau-dri
	provides = svga-dri
	provides = mesa-dri
	provides = mesa
	conflicts = libglapi
	conflicts = osmesa
	conflicts = libgbm
	conflicts = libgles
	conflicts = libegl
	conflicts = khrplatform-devel
	conflicts = ati-dri
	conflicts = intel-dri
	conflicts = nouveau-dri
	conflicts = svga-dri
	conflicts = mesa-dri
	conflicts = mesa
	replaces = libglapi
	replaces = osmesa
	replaces = libgbm
	replaces = libgles
	replaces = libegl
	replaces = khrplatform-devel
	replaces = ati-dri
	replaces = intel-dri
	replaces = nouveau-dri
	replaces = svga-dri
	replaces = mesa-dri
	replaces = mesa

pkgname = mesa-libgl-nosystemd
	pkgdesc = Mesa 3-D graphics library
	depends = mesa-nosystemd
	provides = libgl
	provides = mesa-libgl
	conflicts = mesa-libgl
	replaces = libgl
	replaces = mesa-libgl

While I can appreciate the suggestion to modify the PKGBUILD, I would like to keep my PKGBUILD as close to Arch's PKGBUILD as possible. Thanks again for the reply.


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

#4 2015-12-29 02:20:13

Scimmia
Fellow
Registered: 2012-09-01
Posts: 11,471

Re: [SOLVED] Cannot delete or correct my AUR mesa-nosystemd package

The error seems pretty straight forward. Commit d0848047a09395f938c8ba9ce088139582c345ad doesn't have a pkgver.

Online

#5 2015-12-29 23:19:00

0strodamus
Member
Registered: 2014-01-22
Posts: 92

Re: [SOLVED] Cannot delete or correct my AUR mesa-nosystemd package

Thanks for commenting! I'm completely new to using git, so it wasn't obvious to me. I was able to delete the commit and push a working PKGBUILD with a pkgbase as suggested by progandy. Thanks for the help, I really appreciate it!


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

Board footer

Powered by FluxBB