You are not logged in.

#1 2016-06-25 08:49:45

maxthest
Member
From: United States
Registered: 2016-06-25
Posts: 6

PKGBUILD review request: fossamail and fossamail-lightning

Hello developers, package maintainers, and fellow Arch Linux users. First time here on the forums but I have been using Arch for a while. Recently I have been using Pale Moon and FossaMail, two open source projects that are forks of Mozilla Firefox and Thunderbird. There is an AUR package for Pale Moon but not for FossaMail (aside from the fossamail-bin binary package). Since I prefer my AUR packages to be compiled from source, I created a PKGBUILD for FossaMail and it’s calendar extension Lightning. I am eager to submit to the AUR repository but I would like to make sure it is correct and thorough. This is my first PKGBUILD but I have been following the Creating packages and Arch packaging standards Wiki articles regarding packaging and guidelines.

PKGBUILD

# Maintainer:  Daniel Conover (maxthest) <maxthest@live.com>
# Contributor: 0strodamus <0strodamus at cox dot net>
pkgname=('fossamail' 'fossamail-lightning')
pkgver=25.2.2
_pkgver=25
pkgrel=1
pkgdesc="Open source, Mozilla Thunderbird-based mail, news, chat and calendar client from Moonchild Productions, the developers of Pale Moon."
arch=('i686' 'x86_64')
url="https://www.fossamail.org/"
license=('MPL' 'GPL' 'LGPL')
makedepends=('git' 'python2' 'autoconf2.13' 'unzip' 'zip' 'yasm' 'gcc5'
             'diffutils' 'gconf' 'libpulse' 'hunspell' 'python2-ply' 'jemalloc'
             'libcanberra')
_pmcommit=b270198ecd9d38f239d2cd4ee89ed1ef753b66d3
source=(git+"https://github.com/MoonchildProductions/FossaMail#tag=${pkgver}_Release"
        git+"https://github.com/MoonchildProductions/Pale-Moon#commit=${_pmcommit}"
        mozconfig
        fossamail-app-name.patch
        fossamail.desktop)
md5sums=('SKIP'
         'SKIP'
         'e6daa3c6bf5ecb3bb90bcf4a17e0c664'
         '046caec52a005e065065d20215ddb883'
         'fb7879e01c197bedf45253de50106700')

_objdir=fmbuild

prepare() {
  cd FossaMail

  cp ../mozconfig ./.mozconfig

  # Enable parallel compilation and other make flags
  if [ -n "${MAKEFLAGS}" ]; then
    echo -e "mk_add_options MOZ_MAKE_FLAGS=\"$MAKEFLAGS\"" >> .mozconfig
  else
    # Set number of cores to 1, or whatever number is desired
    _cores=1
    echo -e "mk_add_options MOZ_MAKE_FLAGS=\"-j$_cores\"" >> .mozconfig
  fi

  # Set up the object directory
  echo -e "mk_add_options MOZ_OBJDIR=$srcdir/$_objdir/" >> .mozconfig

  # Add optimization flags
  # Enable "Pale Moon-alike" optimizations. Change or remove if nessessary on older CPUs
  echo -e "ac_add_options --enable-optimize=\"-O3 -msse2 -mfpmath=sse\"" >> .mozconfig

  # Update the mozilla (Pale Moon core) submodule
  git submodule init
  git config submodule.mozilla.url $srcdir/Pale-Moon
  git submodule update

  # Apply patches
  patch -Np1 -i ../fossamail-app-name.patch

  # Mark the scrips as executable files
  chmod -R +x build/autoconf/*
  find . -name '*.sh' -exec chmod +x {} \;
}
  
build() {
  cd FossaMail

  export MOZBUILD_STATE_PATH="$srcdir/mozbuild"
  export MOZCONFIG="$srcdir/FossaMail/.mozconfig"

  # _FORTIFY_SOURCE causes build failures
  CPPFLAGS=${CPPFLAGS/-D_FORTIFY_SOURCE=[0-2]/}

  # Hardening
  export LDFLAGS="$LDFLAGS -Wl,-z,now"

  make -f client.mk build

  # Enter the object directory where FossaMail and Lightning are built
  cd "$srcdir/$_objdir"
  make package
  # Distribution files are located in `mozilla/dist' of $_objdir
}

package_fossamail() {
  pkgdesc="Open source, Mozilla Thunderbird-based mail, news and chat client from Moonchild Productions, the developers of Pale Moon."
  depends=('gtk2' 'libxt' 'startup-notification' 'dbus-glib' 'libvpx'
           'alsa-lib' 'libevent' 'nss' 'sqlite' 'hunspell' 'cairo' 'ttf-font')
  optdepends=('fossamail-lightning: addon for calendar support'
              'hyphen: library for hyphenation and justification'
              'libcanberra: for sound support')
  provides=("fossamail=$pkgver")
  conflicts=('fossamail-bin' 'fossamail-git')

  # Enter the object directory where FossaMail will be packaged
  cd "$srcdir/$_objdir"

  install -d "$pkgdir"/usr/{bin,lib}
  # FossaMail is located in `mozilla/dist'
  cp -r mozilla/dist/fossamail/ "$pkgdir/usr/lib/$pkgname"
  ln -s "../lib/$pkgname/fossamail" "$pkgdir/usr/bin/fossamail"

  # Install icons
  for i in 16 22 24 32 48 256; do
      install -Dm644 "$srcdir/FossaMail/mail/branding/official/mailicon$i.png" \
          "$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/fossamail.png"
  done

  # Use system-provided dictionaries
  rm -rf "$pkgdir"/usr/lib/$pkgname/{dictionaries,hyphenation}
  ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname/dictionaries"
  ln -s /usr/share/hyphen "$pkgdir/usr/lib/$pkgname/hyphenation"

  # Avoid duplicate binaries
  # https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  rm -f "$pkgdir/usr/lib/$pkgname/$pkgname-bin"

  # Install desktop file
  install -Dm644 ../fossamail.desktop \
      "$pkgdir/usr/share/applications/fossamail.desktop"
}

package_fossamail-lightning() {
  pkgdesc="Calender plugin that is integrated into FossaMail."
  depends=("fossamail>=$_pkgver")
  provides=("fossamail-lightning=$pkgver")
  conflicts=('fossamail-lightning-bin' 'fossamail-lightning-git')

  cd "$srcdir/$_objdir"
  # Lightning is located at `mozilla/dist/xpi-stage' or 
  # `mozilla/dist/bin/extensions/{some-em:id}'

  # Get em:id from addon installation
  _emid=$(grep em:id mozilla/dist/xpi-stage/lightning/install.rdf | tail -n 1 | \
      sed 's/.*>\(.*\)<.*/\1/')

  install -d "$pkgdir/usr/lib/fossamail/extensions"
  # Copy while dereferencing symbolic links
  cp -Lr mozilla/dist/xpi-stage/lightning/ \
      "$pkgdir/usr/lib/fossamail/extensions/$_emid"
}

mozconfig

export MOZILLA_OFFICIAL=1
export CC=gcc-5
export CXX=g++-5
mk_add_options PYTHON=/usr/bin/python2

mk_add_options MOZ_CO_PROJECT=mail
ac_add_options --enable-application=mail

ac_add_options --prefix=/usr
ac_add_options --libdir=/usr/lib
ac_add_options --with-distribution-id=FossaMail
ac_add_options --enable-jemalloc
ac_add_options --enable-release
ac_add_options --enable-strip
ac_add_options --with-pthreads

ac_add_options --enable-official-branding

# Features
ac_add_options --enable-calendar
ac_add_options --enable-extensions=default
ac_add_options --disable-gstreamer
ac_add_options --disable-installer
ac_add_options --enable-startup-notification
ac_add_options --disable-updater

# Debug
ac_add_options --disable-tests
ac_add_options --disable-mochitests
ac_add_options --disable-debug
ac_add_options --disable-debug-symbols
ac_add_options --disable-valgrind

# System libraries
ac_add_options --enable-system-cairo
ac_add_options --enable-system-hunspell
ac_add_options --enable-system-sqlite
ac_add_options --enable-system-ffi
ac_add_options --enable-system-pixman
ac_add_options --with-system-bz2
ac_add_options --with-system-icu
ac_add_options --with-system-jpeg
ac_add_options --with-system-libevent
ac_add_options --with-system-libvpx
ac_add_options --with-system-nspr
ac_add_options --with-system-nss
ac_add_options --with-system-png
ac_add_options --with-system-ply
ac_add_options --with-system-zlib
ac_add_options --with-system-webp
ac_add_options --x-libraries=/usr/lib

# Sound support
ac_add_options --enable-alsa
ac_add_options --disable-pulseaudio
ac_add_options --disable-oss

# Strip debugging symbols
STRIP_FLAGS="--strip-debug"

fossamail-app-name.patch

diff --git a/mail/branding/official/configure.sh b/mail/branding/official/configure.sh
index d83be62..f016c3e
--- a/mail/branding/official/configure.sh
+++ b/mail/branding/official/configure.sh
@@ -1,2 +1,2 @@
 MOZ_APP_DISPLAYNAME=FossaMail
-MOZ_APP_NAME=FossaMail
+MOZ_APP_NAME=fossamail

fossamail.desktop

[Desktop Entry]
Name=FossaMail
GenericName=Mail Client
GenericName[ast]=Client de correu
GenericName[ca]=Client de correu
GenericName[cs]=Poštovní klient
GenericName[da]=E-postklient
GenericName[de]=E-Mail-Anwendung
GenericName[el]=Λογισμικό αλληλογραφίας
GenericName[es]=Cliente de correo
GenericName[fi]=Sähköpostiohjelma
GenericName[fr]=Client de messagerie
GenericName[gl]=Cliente de correo electrónico
GenericName[he]=לקוח דוא״ל
GenericName[hr]=Klijent e-pošte
GenericName[hu]=Levelezőkliens
GenericName[it]=Client email
GenericName[ja]=電子メールクライアント
GenericName[ko]=메일 클라이언트
GenericName[nl]=E-mailprogramma
GenericName[pl]=Klient poczty
GenericName[pt_BR]=Cliente de E-mail
GenericName[ru]=Почтовый клиент
GenericName[sk]=Poštový klient
GenericName[ug]=ئېلخەت دېتالى
GenericName[uk]=Поштова програма
GenericName[vi]=Phần mềm khách quản lý thư điện tử
GenericName[zh_CN]=邮件新闻客户端
GenericName[zh_TW]=郵件用戶端
Comment=Send and receive mail with FossaMail
Exec=fossamail %u
Terminal=false
Type=Application
Icon=fossamail
Categories=Network;Email;
MimeType=message/rfc822;x-scheme-handler/mailto;application/x-xpinstall;
StartupNotify=true
Actions=ComposeMessage;OpenAddressBook;

[Desktop Action ComposeMessage]
Name=Write new message
Exec=fossamail -compose

[Desktop Action OpenAddressBook]
Name=Open address book
Exec=fossamail -addressbook

Some notes:

  • FossaMail is a fork of Firefox/Thunderbird. It uses the same build setup and configurations as such (mozconfig, client.mk, and mach)

  • The depends and makedepends are based off of the palemoon PKGBUILD on the AUR as FossaMail uses the Pale Moon browser core.

  • As such, gcc5 gcc5 is required to build as FossaMail and Pale Moon cannot compile with gcc6 without some major patching, and the developers at the upstream do not recommend using later versions of GCC.
       Edited: To my amazement, gcc5 is no longer an AUR package but an official one maintained by the Arch Linux team. I guess the ABI changes in gcc6 are causing havoc everywhere. tongue

  • The build setup is similar to the official Thunderbird PKGBUILD as well as the installation patches.

  • I have build this package on a separate machine and installed it on another without any issues. I am currently using it as my main email client (helps with testing smile )

  • I have run namcap on both the built packages and the PKGBUILD and found no noticeable issues.

  • If you wish to build the package yourself for verification, be warned that it may take a while, as with most Mozilla-based projects.

  • I have yet to test this on an i686 variant of Arch Linux.

  • As with Pale Moon, there is a redistribution license. Since this is a source based package and the build script will be pulling sources from the official repositories, I do not believe this will affect the package or need to add custom to the license field but I would like a second opinion on this just in case.

Last edited by maxthest (2016-07-12 01:42:58)


http://betanews.com/2016/04/27/windows- … broadcast/   ... no wonder why people are starting to think Windows 10 is a virus.

Friends don't let friends (be forced to) install Windows 10.

Offline

#2 2016-06-25 16:09:32

Case_Of
Member
Registered: 2015-10-09
Posts: 6

Re: PKGBUILD review request: fossamail and fossamail-lightning

About FossaMail, I was maintaining a fossamail-git pkgbuild on aur, but I removed it because wolfbeast (on github) and Moonchild (on Palemoon/FossaMail forums), the project main developer, was saying that they are testing the building process with particular settings, and then share them on their mirror. So you should ask him for all the details about it to avoid weird bugs.

Last edited by Case_Of (2016-06-25 16:10:46)

Offline

#3 2016-06-25 21:35:35

maxthest
Member
From: United States
Registered: 2016-06-25
Posts: 6

Re: PKGBUILD review request: fossamail and fossamail-lightning

Case_Of wrote:

About FossaMail, I was maintaining a fossamail-git pkgbuild on aur, but I removed it because wolfbeast (on github) and Moonchild (on Palemoon/FossaMail forums), the project main developer, was saying that they are testing the building process with particular settings, and then share them on their mirror. So you should ask him for all the details about it to avoid weird bugs.

Huh. In that case, I will head to the Pale Moon forums and ask about FossaMail build instructions and settings tuned for FossaMail.

You can follow along if you are interested.

I have been looking for build instructions on FossaMail prior to writing this PKGBUILD but I have not found any, so I assumed that the build setup was the same as the other Mozilla-based projects.

Last edited by maxthest (2016-06-25 21:38:59)


http://betanews.com/2016/04/27/windows- … broadcast/   ... no wonder why people are starting to think Windows 10 is a virus.

Friends don't let friends (be forced to) install Windows 10.

Offline

#4 2016-06-28 01:07:24

0strodamus
Member
Registered: 2014-01-22
Posts: 92

Re: PKGBUILD review request: fossamail and fossamail-lightning

@Case_Of: I enjoyed using your fossamail-git PKGBUILD while it lasted. Thank you for uploading and maintaining it for as long as you did!

@maxthest: Looking forward to using your PKGBUILD in the future! Are the install dir patches necessary? I haven't been using them with fossamail-git or palemoon.


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

#5 2016-06-28 01:48:23

maxthest
Member
From: United States
Registered: 2016-06-25
Posts: 6

Re: PKGBUILD review request: fossamail and fossamail-lightning

0strodamus wrote:

Looking forward to using your PKGBUILD in the future! Are the install dir patches necessary? I haven't been using them with fossamail-git or palemoon.

Hello 0strodamus,

Thank you for the support. smile
To answer your question, yes, they are necessary. Arch Linux package guidelines state that directory names must be striped from hyphens that are attached with version numbers (i.e. /usr/lib/{pkg} and not /usr/lib/{pkg}-{ver}, such as firefox and not firefox-38.0.1) unless it is a major version suffix (i.e. /usr/lib/{pkg}{majorversion}, such as gtk2). This is to keep consistent of the rolling release style packages that Arch favors. I cannot seem to change the lib name from the configure scripts thus that is why I have created patches for the lib installation. The official Thunderbird package on Arch Linux also uses installation patches to fix this.

As for the executable name, I debated on that for a while and I decided to keep it all lower case to be consistent with how Pale Moon's and Thunderbird's executables are all lower case. I could not change it by passing MOZ_APP_NAME=fossamail into the mozconfig file (it gets overwritten during the configuration) thus I created a patch to keep it all lower case.

Last edited by maxthest (2016-06-28 01:49:35)


http://betanews.com/2016/04/27/windows- … broadcast/   ... no wonder why people are starting to think Windows 10 is a virus.

Friends don't let friends (be forced to) install Windows 10.

Offline

#6 2016-06-28 03:02:28

0strodamus
Member
Registered: 2014-01-22
Posts: 92

Re: PKGBUILD review request: fossamail and fossamail-lightning

That's weird. There are no directory names with version numbers and hyphens in the build I've been using. If it's of any interest, here's the last PKGBUILD and mozconfig.in I compiled and am currently running. I'm not sure how much I may have changed (if anything at all), but this started out as Case_Of's fossamail-git AUR PKGBUILD. I agree that lower-case naming is the way to go. You could do that during packaging instead of using a patch.

PKGBUILD

# Maintainer: 0strodamus <0strodamus at cox dot net>
# Contributor: Quentin Retornaz <quentin dot retornaz at yahoo dot fr>
# Contributor: WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor: artiom <a.mv at gmx dot fr>

pkgname=fossamail
pkgver=25.2.1
pkgrel=1
pkgdesc="Open Source, Mozilla Thunderbird-based mail, news, and chat client."
arch=('i686' 'x86_64')
url="https://www.fossamail.org/"
#url="https://github.com/MoonchildProductions/FossaMail"
license=('MPL' 'GPL' 'LGPL')
depends=('gtk2' 'dbus-glib' 'desktop-file-utils' 'libxt' 'mime-types' 'nss' 'alsa-lib' 'hunspell'
         'nspr' 'libjpeg-turbo' 'zlib' 'bzip2' 'libpng' 'libevent' 'libvpx')
makedepends=('git' 'python2' 'autoconf2.13' 'unzip' 'zip' 'yasm')
optdepends=('hunspell: spell checker and morphological analyzer'
            'hyphen: library for hyphenation and justification')
conflicts=('fossamail-bin' 'fossamail-git')
install=fossamail.install
source=(fossamail.desktop
		mozconfig.in
        git+"https://github.com/MoonchildProductions/FossaMail.git")
sha256sums=('bedf655a9b8c06124769b51ad2f36abdd9da15a8f79c03ad8fac513e77e54989'
			'234ec09ca4c77df3a4be4201a22d0226b2169751baa270487c7423c4364ba148'
            'SKIP')

prepare() {
  cd FossaMail
  git submodule update --init
  chmod -R +x *
  cd ..
  cp mozconfig.in FossaMail/.mozconfig
  if [[ -d "$srcdir/fmbuild" ]]; then
    rm -rf "$srcdir/fmbuild"
  fi
  mkdir "$srcdir/fmbuild"
}

build() {
  cd FossaMail
  export CPPFLAGS="$CPPFLAGS -O2"
  export MOZ_OBJDIR="$srcdir/fmbuild"
  make -f client.mk build
}

package() {
  cd "${srcdir}/fmbuild"
  make package
  cd mozilla/dist
  install -d "$pkgdir"/usr/{bin,lib}
  cp -r FossaMail/ "$pkgdir/usr/lib/fossamail"
  mv "$pkgdir/usr/lib/fossamail/FossaMail" "$pkgdir/usr/lib/fossamail/fossamail"
  ln -s ../lib/fossamail/fossamail "$pkgdir/usr/bin/fossamail"
  install -Dm644 "$srcdir/fossamail.desktop" "$pkgdir/usr/share/applications/fossamail.desktop"

  # icons
  install -Dm644 FossaMail/chrome/icons/default/default16.png "$pkgdir/usr/share/icons/hicolor/16x16/apps/fossamail.png"
  install -Dm644 FossaMail/chrome/icons/default/default32.png "$pkgdir/usr/share/icons/hicolor/32x32/apps/fossamail.png"
  install -Dm644 FossaMail/chrome/icons/default/default48.png "$pkgdir/usr/share/icons/hicolor/48x48/apps/fossamail.png"
  install -Dm644 FossaMail/chrome/icons/default/default256.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/fossamail.png"

  # remove duplicate binary
  rm -f "$pkgdir/usr/lib/fossamail/FossaMail-bin"
}

mozconfig.in

export MOZILLA_OFFICIAL=1
export CC=gcc-5
export CXX=g++-5
mk_add_options PYTHON=/usr/bin/python2
ac_add_options --enable-official-branding
ac_add_options --with-distribution-id=FossaMail
ac_add_options --enable-application=mail
ac_add_options --enable-optimize="-O2"
ac_add_options --enable-strip
mk_add_options MOZ_MAKE_FLAGS="-j8"
mk_add_options _FORTIFY_SOURCE=0
mk_add_options MOZ_CO_PROJECT=mail

# disable junk
ac_add_options --disable-b2g-bt
ac_add_options --disable-b2g-camera
ac_add_options --disable-b2g-ril
ac_add_options --disable-accessibility
ac_add_options --disable-codesighs
ac_add_options --disable-crashreporter
ac_add_options --disable-jemalloc # see https://github.com/MoonchildProductions/Pale-Moon/issues/39
ac_add_options --disable-gamepad
ac_add_options --disable-installer
ac_add_options --disable-logging
ac_add_options --disable-mobile-optimize
ac_add_options --disable-metro
ac_add_options --disable-maintenance-service
ac_add_options --disable-necko-wifi
ac_add_options --disable-parental-controls
ac_add_options --disable-updater
ac_add_options --disable-webrtc
ac_add_options --disable-websms-backend
ac_add_options --disable-windows-mobile-components
ac_add_options --disable-gstreamer
ac_add_options --disable-gnomevfs
ac_add_options --disable-safe-browsing
ac_add_options --disable-startup-notification
ac_add_options --disable-url-classifier
ac_add_options --disable-valgrind

# disable tests, debug
ac_add_options --disable-tests
ac_add_options --disable-mochitests
ac_add_options --disable-debug
ac_add_options --disable-debug-symbols

# enable useful features
ac_add_options --enable-chrome-format=omni

# use system libs
ac_add_options --x-libraries=/usr/lib
ac_add_options --with-system-nspr
ac_add_options --with-system-jpeg
ac_add_options --with-system-zlib
ac_add_options --with-system-bz2
ac_add_options --with-system-png
ac_add_options --with-system-libevent
ac_add_options --with-system-libvpx
ac_add_options --with-system-icu
ac_add_options --with-system-webp
ac_add_options --enable-system-hunspell
ac_add_options --enable-system-sqlite
ac_add_options --enable-system-ffi
ac_add_options --enable-system-pixman

directory tree

/usr/lib/fossamail/
├── application.ini
├── blocklist.xml
├── chrome
│   └── icons
│       └── default
│           ├── default16.png
│           ├── default22.png
│           ├── default24.png
│           ├── default256.png
│           ├── default32.png
│           └── default48.png
├── chrome.manifest
├── components
│   ├── components.manifest
│   ├── libdbusservice.so
│   └── libmozgnome.so
├── defaults
│   ├── messenger
│   │   └── mailViews.dat
│   └── pref
│       └── channel-prefs.js
├── dependentlibs.list
├── dictionaries
│   ├── en-US.aff
│   └── en-US.dic
├── extensions
│   └── {972ce4c6-7e08-4474-a285-3208198ce6fd}
│       ├── icon.png
│       ├── install.rdf
│       └── preview.png
├── fossamail
├── isp
│   ├── Bogofilter.sfd
│   ├── DSPAM.sfd
│   ├── movemail.rdf
│   ├── POPFile.sfd
│   ├── rss.rdf
│   ├── SpamAssassin.sfd
│   └── SpamPal.sfd
├── libfreebl3.chk
├── libfreebl3.so
├── libldap60.so
├── libldif60.so
├── libmozalloc.so
├── libnss3.so
├── libnssckbi.so
├── libnssdbm3.chk
├── libnssdbm3.so
├── libnssutil3.so
├── libprldap60.so
├── libsmime3.so
├── libsoftokn3.chk
├── libsoftokn3.so
├── libssl3.so
├── libxul.so
├── mozilla-xremote-client
├── omni.ja
├── platform.ini
├── plugin-container
├── precomplete
├── removed-files
├── run-mozilla.sh
└── searchplugins
    └── duckduckgo.xml

Last edited by 0strodamus (2016-06-28 03:09:35)


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

#7 2016-06-28 18:22:18

maxthest
Member
From: United States
Registered: 2016-06-25
Posts: 6

Re: PKGBUILD review request: fossamail and fossamail-lightning

After looking at the PKGBUILD you posted, and comparing it to mine, I realized that I am an idiot. tongue
My earlier iterations of PKGBUILD used the make -f client.mk install command in the packaging phase, which depends on the defined installdir in the baseconfig.mk file. But since I split the package into two (fossamail and fossamail-lightning, respecfully), using the MOZ_OBJDIR object directory and using the install/cp commands, I DON'T NEED to patch the baseconfig.mk files. A big 'oops' on my part. neutral
Thanks for pointing this out and making it so obvious to me. I have updated my PKGBUILD and the respected files. I am going to keep one patch file just in case because I do not know how safely I can just rename the compiled binary files without affecting the rest of the application. Further experimentation required.


http://betanews.com/2016/04/27/windows- … broadcast/   ... no wonder why people are starting to think Windows 10 is a virus.

Friends don't let friends (be forced to) install Windows 10.

Offline

#8 2016-06-30 02:25:15

0strodamus
Member
Registered: 2014-01-22
Posts: 92

Re: PKGBUILD review request: fossamail and fossamail-lightning

I'm glad what I posted was helpful. I've been renaming the binaries for a long time now without any problems, so I think it should be ok. However, you should definitely verify everything because I'm an idiot too! tongue


archlinux | OpenRC | TOMOYO Linux | Xfce

"In his house at R'lyeh dead Cthulhu waits dreaming."

Offline

#9 2016-07-11 08:04:20

maxthest
Member
From: United States
Registered: 2016-06-25
Posts: 6

Re: PKGBUILD review request: fossamail and fossamail-lightning

Updated PKGBUILD to target recent version of FossaMail.

0strodamus wrote:

I'm glad what I posted was helpful. I've been renaming the binaries for a long time now without any problems, so I think it should be ok. However, you should definitely verify everything because I'm an idiot too! tongue

I did a little experiment where I set the name in the configure scripts to something long and conspicuous, grepped it, and I got a match from one of the compiled binaries, libxul.so to be specific. I am not sure why the application name is referenced there but I do know that libxul.so is used by extensions so I guess that the plugins make use of the MOZ_APP_NAME somehow, or maybe it is just referencing build info. I do not know for sure. I will have to dig into the source code when I have the time but for now I will leave the patch up just in case.

Since I am not receiving much attention from this thread, I am guessing my PKGBUILD and supplemented files are sound and I might put them up on the AUR sometime this week.

Last edited by maxthest (2016-07-11 08:04:57)


http://betanews.com/2016/04/27/windows- … broadcast/   ... no wonder why people are starting to think Windows 10 is a virus.

Friends don't let friends (be forced to) install Windows 10.

Offline

Board footer

Powered by FluxBB