Arch Linux

tikrass

Member

Registered: 2017-01-07

Posts: 3

PKGBUILD review request: python2-humblewx

Hello,

I found the python2 package humblewx, which is not part of the AUR yet. I will need it as a dependency for a later package. Because this is the first time I intend to upload something to the AUR, can someone check it for me please? It builds fine on my computer, but I want to be sure, that it is OK.

 # Maintainer: Thibaud Kehler <thibaud.kehler at gmx dot net>
pkgbase=('python2-humblewx')
pkgname=('python2-humblewx')
_module='humblewx'
pkgver='0.2.1'
pkgrel=1
pkgdesc="Library that simplifies creating user interfaces with wxPython."
url="https://github.com/thetimelineproj/humblewx"
depends=('python2')
makedepends=('python2-setuptools')
license=('GPL3')
arch=('any')
source=("https://files.pythonhosted.org/packages/source/h/humblewx/humblewx-${pkgver}.tar.gz")
md5sums=('1d3b30936aecf7570565a73878ed7f73')

build() {
    cd "${srcdir}/${_module}-${pkgver}"
    python2 setup.py build
}

package() {
    depends+=()
    cd "${srcdir}/${_module}-${pkgver}"
    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}

mis

Member

Registered: 2016-03-16

Posts: 234

Re: PKGBUILD review request: python2-humblewx

$ namcap PKGBUILD
PKGBUILD (python2-humblewx) W: Missing Maintainer tag
PKGBUILD (python2-humblewx) E: Child package python2-humblewx does not have a valid package() function

pkgbase=('python2-humblewx')
pkgname=('python2-humblewx')

Just use pkgname=python2-humblewx

   depends+=()

Remove that line from package() function.

And just a minor thing, but namcap gives a warning. Remove the leading space from the Maintainer line.
Other than that it looks good to me.

Edit:
Also just minor: It's common to keep the order of the variables like it's in the PKGBUILD prototype /usr/share/pacman/PKGBUILD.proto
I mean license= and arch=

Last edited by mis (2017-01-07 17:48:54)