[SOLVED]makepkg error: colord is not a clone of https://github.com/...

WFV · 2017-12-29 20:52:05

me@arch-pc ~/PACKAGES/MEBUILDS % asp export colord
==> exporting colord:trunk
me@arch-pc ~/PACKAGES/MEBUILDS % cd colord
me@arch-pc ~/PACKAGES/MEBUILDS/colord % updpkgsums
==> Retrieving sources...
  -> Found 0001-Make-cd_color_get_blackbody_rgb_full-safer.patch
==> Generating checksums for source files...
me@arch-pc ~/PACKAGES/MEBUILDS/colord % makepkg
==> Making package: colord 1.4.1+7+g2c92e03-1 (Fri Dec 29 10:28:49 PST 2017)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
==> ERROR: /tmp/colord is not a clone of https://github.com/hughsie/colord
    Aborting...

What is the cause of this error?
/tmp/colord is not a clone of https://github.com/hughsie/colord
Haven't found anything Google or on the colord website. I can rebuild other packages without issue (Samba, NetworkManager).
Have also tried obtaining it via wget instead of asp but get same results running makepkg. The above run is from the asp PKGBUILD no edits, but did try using this PKGBUILDwhich looks same anyway,.
Here is the asp PKGBUILD that was used (planned to edit later but need to get past the error first):

# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=colord
pkgver=1.4.1+7+g2c92e03
pkgrel=1
pkgdesc="System daemon for managing color devices"
arch=(x86_64)
url="https://www.freedesktop.org/software/colord"
license=(GPL2)
depends=(lcms2 libgusb polkit sqlite systemd dconf dbus libgudev shared-mime-info)
makedepends=(gobject-introspection vala sane bash-completion argyllcms git docbook-utils
             docbook-sgml perl-sgmls meson gtk-doc)
optdepends=('sane: scanner support'
            'argyllcms: color profiling')
replaces=(shared-color-profiles)
options=(!emptydirs)
_commit=2c92e03775a15bcd304ef39e9a3220496fc9168a  # master
source=("git+https://github.com/hughsie/colord#commit=$_commit"
        0001-Make-cd_color_get_blackbody_rgb_full-safer.patch)
sha256sums=('SKIP'
            '73689805d46705c8680d9ae979a2f5203f661741e56aa07dc627b36059ab404b')
validpgpkeys=('163EB50119225DB3DF8F49EA17ACBA8DFA970E17')  # Richard Hughes

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../0001-Make-cd_color_get_blackbody_rgb_full-safer.patch
}

build() {
  arch-meson $pkgname build \
    -Denable-libcolordcompat=true \
    -Denable-sane=true \
    -Denable-vala=true \
    -Denable-print-profiles=true \
    -Dwith-daemon-user=colord
  ninja -C build
}

check() {
  cd build
  meson test
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
  echo 'u colord - "Color management daemon" /var/lib/colord' |
    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
}

# vim:set ts=2 sw=2 et:

Last edited by WFV (2017-12-31 22:08:09)

Scimmia · 2017-12-29 20:55:21

This usually happens when the source URL changes in any way. You can change the upstream URL in the git repo, or just delete it and let makepkg reclone it.

progandy · 2017-12-29 22:15:11

Did you set SRCDEST to /tmp in your makepkg.config? You already have a file or directory called colord in /tmp, but makepkg is trying to clone a git repository in that position and exits with an error. The target for makepkg sources should be an otherwise unused directory or keep them in the same directory as your PKGBUILD.

WFV · 2017-12-30 16:30:28

Thanks Scimmia and progandy - turns out it was as progandy mentioned. I didn't set it in makepkg.config but had SRCDEST and SRCPKGDEST set in an sh file in /etc/profile.d so commented those out and its working. I had tried changing the upstream URL before posting to make sure it was current but had same error result however, didn't know I could delete it. It now fails at end of build on colord-self-test-daemon but that is off topic, will look into it more. What I don't understand is: why do some packages build with SRCDEST set to /tmp but this one wouldn't? Am I not seeing or not understanding something in its PKGBUILD?

progandy · 2017-12-30 16:57:29

You will always get errors if the package tries to download sources to SRCDEST and an unrelated file or directory with the same name already exists. You could delete the offending files from /tmp if you know that you don't need them anymore and then restart the build.

The errors can be a missing file during the validation check, not passing the validation, an error about already existing files or your error that it isn't a clone of the repository.

Arch Linux

#1 2017-12-29 20:52:05

[SOLVED]makepkg error: colord is not a clone of https://github.com/...

#2 2017-12-29 20:55:21

Re: [SOLVED]makepkg error: colord is not a clone of https://github.com/...

#3 2017-12-29 22:15:11

Re: [SOLVED]makepkg error: colord is not a clone of https://github.com/...

#4 2017-12-30 16:30:28

Re: [SOLVED]makepkg error: colord is not a clone of https://github.com/...

#5 2017-12-30 16:57:29

Re: [SOLVED]makepkg error: colord is not a clone of https://github.com/...

Board footer