You are not logged in.

#1 2018-01-15 13:13:07

xsmile
Member
Registered: 2012-03-31
Posts: 31

Review request - myetherwallet

MyEtherWallet is a client-side script shipped as a web site which is the reason for my request.

Are web sites packaged at all and what is the general practice to do it? Personally I didn't encounter a similar package yet.

My attempt so far looks like this:

PKGBUILD

pkgname=myetherwallet
pkgver=3.11.2.4
pkgrel=1
pkgdesc='Free, open-source, client-side tool for easily & securely interacting with the Ethereum network'
arch=('any')
depends=('xdg-utils')
url='https://github.com/kvhnuke/etherwallet'
license=('MIT')
source=("$url/releases/download/v$pkgver/etherwallet-v$pkgver.zip"
        'myetherwallet.desktop'
        'myetherwallet'
        'LICENSE')
md5sums=('31a387d5601eec30190b7b8cc834987e'
         '7ede310a5ce49d1e13aaafdf486324d2'
         '812af8159b21a3895a9dd5ed6621c912'
         '1d90c6c90650a922d22d50bdc0194e89')

package() {
  cd "$srcdir/etherwallet-v$pkgver"

  # Lib directory
  install -d "$pkgdir/opt/$pkgname"
  cp -a css fonts images js *.html "$pkgdir/opt/$pkgname"
  # Executable
  install -Dm755 "$srcdir/$pkgname" -t "$pkgdir/usr/bin"

  # License
  install -Dm644 "$srcdir/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
  # Menu entry
  install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
  install -Dm644 "images/fav/android-chrome-192x192.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
}

myetherwallet

#!/usr/bin/env bash
libdir=/opt/myetherwallet
xdg-open "$libdir/index.html"

myetherwallet.desktop

[Desktop Entry]
Type=Application
Name=MyEtherWallet
Comment=Free, open-source, client-side tool for easily & securely interacting with the Ethereum network
Icon=myetherwallet
Exec=myetherwallet
Categories=Network;

Offline

Board footer

Powered by FluxBB