Arch Linux

hifi25nl

Member

Registered: 2011-05-07

Posts: 263

Rygel light PKGBUILD without gtk3 dependency

I am trying to make a "Rygel light" without gtk3 dependency. Below is the first working PKGBUILD and original one.
I  have changed some configuration settings and I have removed all gtk3 files from installation.
What do you think?

Modified:

pkgname=rygel-light
pkgver=0.36.2
pkgrel=1
pkgdesc="UPnP AV MediaServer and MediaRenderer light version without gtk3 for headless servers"
url="https://wiki.gnome.org/Projects/Rygel"
arch=(x86_64)
license=(LGPL)
depends=(gupnp-av gupnp-dlna libgee libunistring tracker libmediaart)
makedepends=(vala intltool python gobject-introspection git valadoc)
optdepends=('gst-plugins-base: Extra media codecs'
            'gst-plugins-good: Extra media codecs'
            'gst-plugins-bad: Extra media codecs'
            'gst-plugins-ugly: Extra media codecs'
            'gst-libav: Extra media codecs'
            'tracker-miners: Share indexed media files')
backup=(etc/rygel.conf)
groups=(gnome)
_commit=7d0e90cd4cc4d59e36d7e8681ff41c3a66d3bc09  # tags/rygel-0.36.2^0
source=("git+https://gitlab.gnome.org/GNOME/rygel.git#commit=$_commit")
sha256sums=('SKIP')
provides=('rygel')
conflicts=('rygel')
pkgver() {
  cd rygel
  git describe --tags | sed 's/^RYGEL_//;s/^rygel-//;s/_/./g;s/-/+/g'
}

prepare() {
  cd rygel
  NOCONFIGURE=1 ./autogen.sh
}

build() {
    cd rygel
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
              --disable-static --disable-gst-launch-plugin \
              --disable-apidocs --with-media-engine=simple
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd rygel
  make check
}

package() {
  cd rygel
  make DESTDIR="$pkgdir" install
  rm -f $pkgdir/usr/bin/rygel-preferences
  rm -rf $pkgdir/usr/share/applications
  rm -rf $pkgdir/usr/share/gtk-doc
  rm -rf $pkgdir/usr/share/icons
  rm -rf $pkgdir/usr/share/rygel/icons
  rm -f $pkgdir/usr/share/rygel/rygel-preferences.ui
}

Original:

pkgname=rygel
pkgver=0.36.2
pkgrel=1
pkgdesc="UPnP AV MediaServer and MediaRenderer that allows you to easily share audio, video and pictures, and control of media player on your home network"
url="https://wiki.gnome.org/Projects/Rygel"
arch=(x86_64)
license=(LGPL)
depends=(gupnp-av gupnp-dlna libgee gtk3 libunistring tracker libmediaart)
makedepends=(vala intltool python gobject-introspection git valadoc)
optdepends=('gst-plugins-base: Extra media codecs'
            'gst-plugins-good: Extra media codecs'
            'gst-plugins-bad: Extra media codecs'
            'gst-plugins-ugly: Extra media codecs'
            'gst-libav: Extra media codecs'
            'tracker-miners: Share indexed media files')
backup=(etc/rygel.conf)
groups=(gnome)
_commit=7d0e90cd4cc4d59e36d7e8681ff41c3a66d3bc09  # tags/rygel-0.36.2^0
source=("git+https://gitlab.gnome.org/GNOME/rygel.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^RYGEL_//;s/^rygel-//;s/_/./g;s/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
              --disable-static --enable-mediathek-plugin --enable-gst-launch-plugin \
              --enable-apidocs
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

eschwartz

Fellow

Registered: 2014-08-08

Posts: 4,097

Re: Rygel light PKGBUILD without gtk3 dependency

You should explicitly disable gtk3 support via ./configure --without-ui, to prevent automagic dependencies: https://wiki.gentoo.org/wiki/Project:Qu … pendencies

Also, you need to quote "$pkgdir".

Question: does the package in [extra] need gtk3 except for the rygel-preferences executable? If so, perhaps the gtk3 dependency can be made optional, and you could just use the existing package.

Last edited by eschwartz (2018-10-08 13:31:19)

---

Managing AUR repos The Right Way -- aurpublish (now a standalone tool)

hifi25nl

Member

Registered: 2011-05-07

Posts: 263

Re: Rygel light PKGBUILD without gtk3 dependency

Ok, thanks for the  --without-ui suggestion.