[SOLVED] python2-terminaltables split package dependency issue

cmorgenstern · 2019-04-06 04:36:43

I maintain an AUR package that depends on both python-terminaltables and python2-terminaltables.

Recently, when attempting to clean build this package, makepkg has been complaining that it is unable to find python2-terminaltables. I can see that python2-terminaltables is provided for within the python-terminaltables PKGBUILD, but there does not exist a web page describing the package - on the contrary, attempting to resolve https://www.archlinux.org/packages/comm … naltables/ produces the following:

In contrast, python-requests is the base package that provides python2-requests, but that package still has a web page and is listed under Split Packages for the base package.

Is this just an oversight as far as python-terminaltables is concerned? Or is this going to start happening to other python split packages as well?

Last edited by cmorgenstern (2019-04-07 23:07:17)

V1del · 2019-04-06 08:08:06

https://bbs.archlinux.org/viewtopic.php … 1#p1840271

Lone_Wolf · 2019-04-06 11:22:46

Looks like the binary package for python2-terminaltables was removed without updating the pkbuild .

Looking at that PKGBUILD the build() and check() functions both run 2 independent procedures.
The only thing those 2 packages share is the sourcecode, I wonder why this ever became a split package instead of 2 separate ones.

Anyway, creating a separate python2 pacakge from that split pkgbuild ~~looks~~ is easy.

I changed pkgrel to 5.1 to avoid confusion. It builds ok, not done any usage tests.

# Maintainer: Christian Rebischke <chris.rebischke[at]archlinux[dot]org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>

pkgbase=python2-terminaltables
_pyname=terminaltables
pkgname=('python2-terminaltables')
pkgver=3.1.0
pkgrel=5.1
pkgdesc="Generate simple tables in terminals from a nested list of strings, python2 version"
arch=('any')
url="https://github.com/Robpol86/terminaltables"
license=('MIT')
makedepends=( 'python2' 'python2-setuptools')
checkdepends=('python2-pytest' 'python2-colorama' 'python2-termcolor' 'python2-colorclass')
source=("${_pyname}-${pkgver}.tar.gz::https://github.com/Robpol86/${_pyname}/archive/v${pkgver}.tar.gz")
sha512sums=('dc49458652fff8bc6094d316d84c9b8e9fca1a26e3230c0b668bc03ec8528793f4ef024e8032d4a56fbfabfdfd4a1142870f550f0b373ba6a42dd2e3ead3f501')

build() {
  cd ${_pyname}-${pkgver}
    python2 setup.py build
}

check() {
    cd ${_pyname}-${pkgver}
    py.test2
}

package_python2-terminaltables() {
  depends=('python2')
  cd ${_pyname}-${pkgver}
  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm 644 example*.py -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
}

# vim:set et sw=2 ts=2 tw=79:

Last edited by Lone_Wolf (2019-04-06 11:23:29)

cmorgenstern · 2019-04-06 22:41:39

V1del wrote:

https://bbs.archlinux.org/viewtopic.php … 1#p1840271

Thanks for sharing that V1del. I subscribed to the arch-dev-public mailing list as well so I'll be forewarned about substantial changes to official packages going forward.

Lone_Wolf wrote:

Anyway, creating a separate python2 pacakge from that split pkgbuild ~~looks~~ is easy.
I changed pkgrel to 5.1 to avoid confusion. It builds ok, not done any usage tests.

Thanks as well Lone_Wolf. I checked the TODO and it looks like python2-colorclass is also slated for removal, so I'll look into getting a PKGBUILD written for that one as well.

I will also test building and using python2-terminaltables from the PKGBUILD you wrote to see if the AUR package I maintain will still run successfully.

cmorgenstern · 2019-04-06 23:36:27

Lone_Wolf: Built and tested the PKGBUILD for python2-terminaltables as a dependency of the AUR package I maintain, and the AUR package builds and runs successfully.

If you want to do more testing, go ahead. Otherwise, I'm happy to upload it to the AUR and maintain it.

cmorgenstern · 2019-04-07 23:06:46

python2-terminaltables has been added to the AUR. I listed you as a contributor Lone_Wolf - thanks again for your assistance. Marking this thread as solved.

Arch Linux

#1 2019-04-06 04:36:43

[SOLVED] python2-terminaltables split package dependency issue

#2 2019-04-06 08:08:06

Re: [SOLVED] python2-terminaltables split package dependency issue

#3 2019-04-06 11:22:46

Re: [SOLVED] python2-terminaltables split package dependency issue

#4 2019-04-06 22:41:39

Re: [SOLVED] python2-terminaltables split package dependency issue

#5 2019-04-06 23:36:27

Re: [SOLVED] python2-terminaltables split package dependency issue

#6 2019-04-07 23:06:46

Re: [SOLVED] python2-terminaltables split package dependency issue

Board footer