You are not logged in.

#1 2020-10-01 22:23:31

Helg1980
Member
From: Königsberg
Registered: 2020-07-23
Posts: 37

[Solved] No targets specified and no makefile found.

Hi!

In the process of building a package from AUR I get the error,
despite the fact that when I checked the package before
sending PKGBUILD to AUR with the makepkg command, there was no error.

==> Extracting sources...
  -> Extracting 1.1.tar.gz with bsdtar
bsdtar: Failed to set default locale
==> Removing existing $pkgdir/ directory...
==> Starting build()...
make: *** No targets specified and no makefile found.  Stop.
==> ERROR: A failure occurred in build().
    Aborting...

My Makefile is located in the src/simplest-studio-1.1
The sources are located in the src/simplest-studio-1.1/app

# Maintainer: Helg1980 <depositmail@rambler.ru>
pkgname=simplest-studio
_name=${pkgname}
pkgver=1.1
pkgrel=1
pkgdesc="Simplest Studio 2020 SE"
arch=(x86_64)
url="https://github.com/SimplestStudio/simplest-studio.git"
license=('GPL3')
depends=('qt5-base>=5.15' 'ffmpeg>=4.2' 'libmediainfo>=20.03')
source=("https://github.com/SimplestStudio/simplest-studio/archive/1.1.tar.gz")
md5sums=('SKIP')

build() {
  cd "${srcdir}/simplest-studio-${pkgver}"
  make -j4
}

package() {
  cd "${srcdir}/simplest-studio-${pkgver}"
  make INSTALL_ROOT=${pkgdir} install
  
  cd "${srcdir}/simplest-studio-${pkgver}"
  # install documentation
  install -Dm644 ABOUT -t "${pkgdir}/usr/share/doc/${pkgname}"
  # install license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  # install icon
  install -Dm644 app/simplest-studio.png -t "${pkgdir}/usr/share/icons/hicolor/64x64/apps/"
  # install .desktop
  install -Dm644 app/simplest-studio.desktop -t "${pkgdir}/usr/share/applications/"

}

Last edited by Helg1980 (2020-10-02 08:22:12)

Offline

#2 2020-10-01 23:21:32

loqs
Member
Registered: 2014-03-06
Posts: 11,869

Re: [Solved] No targets specified and no makefile found.

Builds fine on this system.  Issue with cached source file?  You could also give the source a unique name:

source=("$pkgname-pkgver.targ.gz::https://github.com/SimplestStudio/$pkgname/archive/1.1.tar.gz")

Skipping the checksum also does not help ensure it is the correct file.
Edit:

_name=${pkgname}

Unused duplicate variable.

  cd "${srcdir}/simplest-studio-${pkgver}"

You could use $pkgname here.

  make -j4

Please do not override the user configured preference for jobs.

  make INSTALL_ROOT=${pkgdir} install

Unquoted use of $pkgdir will break if it includes spaces in the path.

  cd "${srcdir}/simplest-studio-${pkgver}"

The second cd call is redundant.

Last edited by loqs (2020-10-01 23:29:33)

Offline

#3 2020-10-01 23:59:45

Helg1980
Member
From: Königsberg
Registered: 2020-07-23
Posts: 37

Re: [Solved] No targets specified and no makefile found.

Thanks!

I rewrote PKGBUILD and put the line:

install -Dm755 simplest_studio "$pkgdir"/usr/bin/simplest_studio

Last edited by Helg1980 (2020-10-02 00:51:45)

Offline

Board footer

Powered by FluxBB