You are not logged in.

#1 2021-05-26 21:35:02

scrollrk
Member
Registered: 2021-05-26
Posts: 2

New package xmonad-cinnamon sanity check

Hi,

I plan on submitting xmonad-cinnamon as my first AUR package. This is not my git project. I plan on submitting a pull request to fix the errors in the README.md and link to the AUR for install.

Just wanted to make sure that this isn't going to be so niche that only a couple of people may ever use it. Any other comments/suggestions are welcome.

# Maintainer: Ryan King <ryan.spencer.king@pm.me>
# Contributors: Tuomo Syvänperä @syvanpera(GitHub)
pkgname=xmonad-cinnamon-git
_pkgname=xmonad-cinnamon
pkgver=1.0
pkgrel=1
pkgdesc="Starts xmonad inside a cinnamon session."
arch=('any')
url="https://github.com/syvanpera/xmonad-cinnamon.git"
license=('MIT')
depends=('xmonad' 'cinnamon-session' 'cinnamon-settings-daemon')
provides=('xmonad-cinnamon')
optdepends=('gdm: Recommended display manager' 'lightdm: Recommended display manager')
source=('git+https://github.com/syvanpera/xmonad-cinnamon.git')
sha256sums=('SKIP')

build() {
  cd "$_pkgname"

  make
}

package() {
  cd "$_pkgname"

  make DESTDIR="$pkgdir/" install
}

Offline

#2 2021-05-26 22:22:00

loqs
Member
Registered: 2014-03-06
Posts: 13,448

Re: New package xmonad-cinnamon sanity check

pkgname=xmonad-cinnamon-git
...
source=('git+https://github.com/syvanpera/xmonad-cinnamon.git')

If you are building from git you need to specify git in makedepends.
See also VCS_package_guidelines#The_pkgver()_function to set the pkgver.

license=('MIT')

See PKGBUILD#license for how MIT licenses should be handled.

Offline

#3 2021-05-27 04:24:08

scrollrk
Member
Registered: 2021-05-26
Posts: 2

Re: New package xmonad-cinnamon sanity check

I restarted from /usr/share/pacman/PKGBUILD-vcs.proto. Filled in the fields. Made appropriate pkgver for a git with no tags or releases. Added the MIT LICENSE install and ended up with this.

# Maintainer: Ryan King <ryan.spencer.king@pm.me>
# Contributors: Tuomo Syvänperä @syvanpera(GitHub)
pkgname=xmonad-cinnamon-git
pkgver=r2.cd41608
pkgrel=1
pkgdesc="Starts xmonad inside a cinnamon session."
arch=('any')
url="https://github.com/syvanpera/xmonad-cinnamon.git"
license=('MIT')
depends=('xmonad' 'cinnamon-session' 'cinnamon-settings-daemon')
optdepends=('gdm: Recommended display manager'
            'lightdm: Recommended display manager')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/syvanpera/xmonad-cinnamon.git')
noextract=()
md5sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${pkgname%-git}"
        make
}

package() {
	cd "$srcdir/${pkgname%-git}"
	make DESTDIR="$pkgdir/" install
        install -Dm644 "LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"
}

Thanks for pointing me in the right direction.

Offline

#4 2021-05-29 00:01:41

loqs
Member
Registered: 2014-03-06
Posts: 13,448

Re: New package xmonad-cinnamon sanity check

        install -Dm644 "LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"

Should use ${pkgname}.  Everything else looks fine.

Offline

Board footer

Powered by FluxBB