PKGBUILD review (xfce4-docklike-plugin)

AnnS · 2025-08-01 17:58:30

Hi! I don't have experience creating PKGBUILDs but I've followed the instructions to create one and I'd like if you could please review it and maybe give me some feedback.

I have created two versions, one to download a tar and the other to build from a git repository.

_pkgname=xfce4-docklike-plugin
pkgname=xfce4-docklike-plugin-git
pkgver=r1070.3581066
pkgrel=1
pkgdesc="A modern, minimalist taskbar for Xfce"
arch=('x86_64')
url="https://gitlab.xfce.org/panel-plugins/xfce4-docklike-plugin"
license=('GPL3')
depends=('xfce4-panel')
makedepends=('meson' 'ninja' 'python-tqdm' 'git')
source=("git+$url.git")
provides=("$_pkgname")
options=('!debug')
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$_pkgname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  arch-meson ${srcdir}/${_pkgname} build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"

  install -D -m644 "${srcdir}/${_pkgname}/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

pkgname=xfce4-docklike-plugin
pkgver=0.5.0
pkgrel=1
pkgdesc="A modern, minimalist taskbar for Xfce"
arch=('x86_64')
url="https://gitlab.xfce.org/panel-plugins/xfce4-docklike-plugin"
license=('GPL3')
depends=('xfce4-panel')
makedepends=('meson' 'ninja' 'python-tqdm')
source=("$pkgname-$pkgver.tar.gz::$url/-/archive/$pkgname-$pkgver/$pkgname-$pkgname-$pkgver.tar.gz")
provides=("$pkgname")
options=('!debug')
sha256sums=('6e32a6c04306dd800cb40396d07dd957adeefd42633f8dd676b90acbf8bd29b0')

prepare() {
  tar xvf ${pkgname}-${pkgver}.tar.gz
}

build() {
  arch-meson ${srcdir}/${pkgname}-${pkgname}-${pkgver} build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"

  install -D -m644 "${srcdir}/${pkgname}-${pkgname}-${pkgver}/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Thank you!

Last edited by AnnS (2025-08-01 18:16:07)

Lone_Wolf · 2025-08-02 11:57:11

prepare() {
  tar xvf ${pkgname}-${pkgver}.tar.gz
}

makepkg knows how to extract many archives, no need to do that manually.

arch-meson wrote:

# Highly opinionated wrapper for Arch Linux packaging

some packagers (including me) disagree with the settings in arch-meson and refuse to use it.

one example

--auto-features enabled

That tells the software being build to enable everything it can detect. Whether enabled stuff will be useful/needed is NOT tested .

This can lead to longer buildtimes, larger packages, more chances to break etc.

AnnS · 2025-08-06 15:16:22

Thnak you for the feedback! I'll make the changes.

Arch Linux

#1 2025-08-01 17:58:30

PKGBUILD review (xfce4-docklike-plugin)

#2 2025-08-02 11:57:11

Re: PKGBUILD review (xfce4-docklike-plugin)

#3 2025-08-06 15:16:22

Re: PKGBUILD review (xfce4-docklike-plugin)

Board footer