Arch Linux

chimerical_brio

Member

Registered: 2008-07-20

Posts: 38

Banshee 1.2: compile from source?

I'd really like to start using Banshee 1.2, but it's not that up-to-date in the repositories, there's not a PKGBUILD for it in ABS, and I'm not knowledgable enough to write my own PKGBUILD. If I just compile it from source, will pacman still manage it? Is there a way to have pacman manage it?

wonder

Developer

From: Bucharest, Romania

Registered: 2006-07-05

Posts: 5,941

Website

Re: Banshee 1.2: compile from source?

will pacman still manage it?

no

there a way to have pacman manage it?

write a PKGBUILD and make a package or wait until will be upgraded

---

Give what you have. To someone, it may be better than you dare to think.

Slug0

Member

Registered: 2008-07-22

Posts: 15

Re: Banshee 1.2: compile from source?

I'd also really like to see Banshee 1.2 in the repos or atleast AUR.

babypuncher

Member

From: .au

Registered: 2007-03-12

Posts: 114

Website

Re: Banshee 1.2: compile from source?

Grab the old PKGBUILD from extra through ABS, bump the version number, viola.

"Worked for me".

Last edited by babypuncher (2008-08-07 12:44:27)

stockground

Member

Registered: 2008-07-26

Posts: 7

Re: Banshee 1.2: compile from source?

Alright, I'm not to good with PKGBUILD's yet, but I was able to slap this together following "babypuncher's" idea. It worked for me and I'm currently on version 1.2. But I'm not sure how well I edited the PKGBUILD, so I hope it works for everyone who's anxious for 1.2.

PKGBUILD

# Maintainer: Alec Hussey <alec.hussey@madsoft.org>

pkgname=banshee
pkgver=1.2.0
pkgrel=1
pkgdesc="Music management and playback for GNOME"
arch=('i686' 'x86_64')
url="http://banshee-project.org/"
license=('MIT')
depends=('sqlite3' 'ndesk-dbus-glib>=0.4.1' 'mono-addins>=0.3.1' 'taglib-sharp>=2.0.3.0' 'gstreamer0.10-good-plugins' 'gstreamer0.10-base-plugins' 'gnome-sharp>=2.20.1')
makedepends=('perlxml' 'pkgconfig')
options=('!libtool' '!makeflags' '!emptydirs')
install=banshee.install
source=(http://banshee-project.org/files/banshee/banshee-1-1.2.0.tar.gz)


build() {
  export MONO_SHARED_DIR=${startdir}/src/.wabi
  mkdir -p "${MONO_SHARED_DIR}"
  cd ${startdir}/src/${pkgname}-1-${pkgver}
  LD_PRELOAD="" IPODSHARP_LIBS="-r:/usr/lib/ipod-sharp/ipod-sharp.dll" ./configure --prefix=/usr \
        --sysconfdir=/etc --localstatedir=/var \
    --disable-helix --disable-ipod --enable-njb --disable-docs \
    --with-gstreamer-0-10 --disable-static || return 1
  make || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${startdir}/pkg install || return 1

  install -m755 -d ${startdir}/pkg/usr/share/licenses/${pkgname}
  install -m644 COPYING ${startdir}/pkg/usr/share/licenses/${pkgname}/ || return 1

  install -d -m755 ${startdir}/pkg/usr/share/gconf/schemas
  gconf-merge-schema ${startdir}/pkg/usr/share/gconf/schemas/${pkgname}.schemas ${startdir}/pkg/etc/gconf/schemas/*.schemas || return 1
  rm -f ${startdir}/pkg/etc/gconf/schemas/*.schemas
}

And banshee.install

pkgname=banshee

post_install() {
  usr/sbin/gconfpkg --install ${pkgname}
  update-desktop-database -q
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
}

pre_upgrade() {
  pre_remove $1
}

post_upgrade() {
  post_install $1
}

pre_remove() {
  usr/sbin/gconfpkg --uninstall ${pkgname}
}

post_remove() {
  update-desktop-database -q
  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
}

chimerical_brio

Member

Registered: 2008-07-20

Posts: 38

Re: Banshee 1.2: compile from source?

Awesome, thanks! Worked like a charm.

loupy

Member

Registered: 2006-10-31

Posts: 77

Re: Banshee 1.2: compile from source?

I compiled it with ipod enabled and I still cannot create playlists or sync to my ipod using Banshee.  Does anyone have banshee working with their Ipod?

Odd-rationale

Member

Registered: 2008-02-05

Posts: 102

Re: Banshee 1.2: compile from source?

I tried compiling from the ABS, changing the package version. However, it keeps asking for "boo" (in community), then it asks for "mono-zeroconf" (in AUR).

Did anyone else have to install these? I had trouble compiling mono-zeroconf from the AUR.

Same thing happens with the PKGBUILD posted above.

chimerical_brio

Member

Registered: 2008-07-20

Posts: 38

Re: Banshee 1.2: compile from source?

I had to install them; I used yaourt for mono-zeroconf (yaourt -S mono-zeroconf), and just used pacman for boo (pacman -S boo).

Odd-rationale

Member

Registered: 2008-02-05

Posts: 102

Re: Banshee 1.2: compile from source?

k. it worked now. idk why it didn't before...

Thanks!