[SOLVED] vi is leaving temporary~ files behind!

speed145a · 2008-11-20 16:18:24

it seems that vi has decided to start leaving the ~ files after i save the file i am working on. this is a very annoying behavior as it is cluttering all my directories.

i have googled, man'd and searched the forums for a solution but i haven't found it.

is there a setting i can change? do i need to grab an older version of vi?

Last edited by speed145a (2008-11-20 19:05:29)

fwojciec · 2008-11-20 16:20:51

add:

set nobackup

to vimrc

speed145a · 2008-11-20 16:34:12

i found a "virc" file but no vimrc. where should i look? or do i need to create it?

rson451 · 2008-11-20 16:47:50

Put that in .virc instead if you are using vi and not vim.

perbh · 2008-11-20 17:44:14

I'm sorry for hijacking (yet) another post, but ...

I have tried in vain to find (on google) the difference between vi and vim (other than EXINIT vs .vimrc, size, etc).

Can anyone plueeeze tell me the difference?!

fwojciec · 2008-11-20 17:47:29

perbh wrote:

I'm sorry for hijacking (yet) another post, but ...
I have tried in vain to find (on google) the difference between vi and vim (other than EXINIT vs .vimrc, size, etc).
Can anyone plueeeze tell me the difference?!

http://www.dc.turkuamk.fi/docs/soft/vim/vim_diff.html

perbh · 2008-11-20 17:53:36

Ahhh - just what I've been looking for!! Thank you ever so much!

speed145a · 2008-11-20 18:22:29

thanks for the quick replies!!!

i'm sorry for this noob question but could someone spell out how to make this adjustment?

here is my /etc/virc file

" An example for a vimrc file.
"
" Maintainer:    Bram Moolenaar <Bram@vim.org>
" Last change:    2008 Jul 02
"
" To use it, copy it to
"     for Unix and OS/2:  ~/.vimrc
"          for Amiga:  s:.vimrc
"  for MS-DOS and Win32:  $VIM\_vimrc
"        for OpenVMS:  sys$login:.vimrc

" When started as "evim", evim.vim will already have done these settings.
if v:progname =~? "evim"
  finish
endif

" Use Vim settings, rather then Vi settings (much better!).
" This must be first, because it changes other options as a side effect.
set nocompatible

" allow backspacing over everything in insert mode
set backspace=indent,eol,start

if has("vms")
  set nobackup        " do not keep a backup file, use versions instead
else
  set backup        " keep a backup file
endif
set history=50        " keep 50 lines of command line history
set ruler        " show the cursor position all the time
set showcmd        " display incomplete commands
set incsearch        " do incremental searching

" For Win32 GUI: remove 't' flag from 'guioptions': no tearoff menu entries
" let &guioptions = substitute(&guioptions, "t", "", "g")

" Don't use Ex mode, use Q for formatting
map Q gq

" CTRL-U in insert mode deletes a lot.  Use CTRL-G u to first break undo,
" so that you can undo CTRL-U after inserting a line break.
inoremap <C-U> <C-G>u<C-U>

" In many terminal emulators the mouse works just fine, thus enable it.
if has('mouse')
  set mouse=a
endif

" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
  syntax on
  set hlsearch
endif

" Only do this part when compiled with support for autocommands.
if has("autocmd")

  " Enable file type detection.
  " Use the default filetype settings, so that mail gets 'tw' set to 72,
  " 'cindent' is on in C files, etc.
  " Also load indent files, to automatically do language-dependent indenting.
  filetype plugin indent on

  " Put these in an autocmd group, so that we can delete them easily.
  augroup vimrcEx
  au!

  " For all text files set 'textwidth' to 78 characters.
  autocmd FileType text setlocal textwidth=78

  " When editing a file, always jump to the last known cursor position.
  " Don't do it when the position is invalid or when inside an event handler
  " (happens when dropping a file on gvim).
  " Also don't do it when the mark is in the first line, that is the default
  " position when opening a file.
  autocmd BufReadPost *
    \ if line("'\"") > 1 && line("'\"") <= line("$") |
    \   exe "normal! g`\"" |
    \ endif

  augroup END

else

  set autoindent        " always set autoindenting on

endif " has("autocmd")

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
" Only define it when not defined already.
if !exists(":DiffOrig")
  command DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
          \ | wincmd p | diffthis
endif

Last edited by speed145a (2008-11-20 18:42:17)

speed145a · 2008-11-20 18:45:43

should i install vim instead perhaps?

speed145a · 2008-11-20 19:05:11

i got it!

i had to CREATE a ~/.virc file and put the line: "set nobackup"

thanks for the help!!

Arch Linux

#1 2008-11-20 16:18:24

[SOLVED] vi is leaving temporary~ files behind!

#2 2008-11-20 16:20:51

Re: [SOLVED] vi is leaving temporary~ files behind!

#3 2008-11-20 16:34:12

Re: [SOLVED] vi is leaving temporary~ files behind!

#4 2008-11-20 16:47:50

Re: [SOLVED] vi is leaving temporary~ files behind!

#5 2008-11-20 17:44:14

Re: [SOLVED] vi is leaving temporary~ files behind!

#6 2008-11-20 17:47:29

Re: [SOLVED] vi is leaving temporary~ files behind!

#7 2008-11-20 17:53:36

Re: [SOLVED] vi is leaving temporary~ files behind!

#8 2008-11-20 18:22:29

Re: [SOLVED] vi is leaving temporary~ files behind!

#9 2008-11-20 18:45:43

Re: [SOLVED] vi is leaving temporary~ files behind!

#10 2008-11-20 19:05:11

Re: [SOLVED] vi is leaving temporary~ files behind!

Board footer