mutt-sidebar 1.5.20-3 don't build with openssl 1.0.0

zyon · 2010-04-09 15:27:31

Hello,

mutt-sidebar 1.5.20-3 from AUR don't work/build with openssl 1.0.0 from core.

gcc -DPKGDATADIR=\"/usr/share/mutt\" -DSYSCONFDIR=\"/etc\" -DBINDIR=\"/usr/bin\" -DMUTTLOCALEDIR=\"/usr/share/locale\" -DHAVE_CONFIG_H=1 -I.  -I. -I. -I./imap  -Iintl -I/usr/include -I/include -I./intl  -Wall -pedantic -Wno-long-long -march=x86-64 -mtune=generic -O2 -pipe -MT mutt_ssl.o -MD -MP -MF .deps/mutt_ssl.Tpo -c -o mutt_ssl.o mutt_ssl.c
mutt_ssl.c: In function 'check_host':
mutt_ssl.c:655: error: 'STACK' undeclared (first use in this function)
mutt_ssl.c:655: error: (Each undeclared identifier is reported only once
mutt_ssl.c:655: error: for each function it appears in.)
mutt_ssl.c:655: error: 'subj_alt_names' undeclared (first use in this function)
mutt_ssl.c:656: warning: ISO C90 forbids mixed declarations and code
mutt_ssl.c: In function 'ssl_cache_trusted_cert':
mutt_ssl.c:738: warning: assignment from incompatible pointer type
make[2]: *** [mutt_ssl.o] Error 1

Does anybody knows how I can fix it?

Ok, BAD-HACK:

1.) http://schlunix.org/archlinux/core/os/x … pkg.tar.gz
2.) tar xfz openssl-0.9.8l-1-x86_64.pkg.tar.gz
3.) sudo cp usr/lib/l{ibcrypto.so.0.9.8,libssl.so.0.9.8} /usr/lib/

I know that is not nice, but I need mutt-sidebar currently.

Last edited by zyon (2010-04-09 15:40:03)

Gusar · 2010-04-09 16:37:39

The mutt in the main repository contains a patch. Fetch that and modify the mutt-sidebar PKGBUILD to apply it.

brisbin33 · 2010-04-09 17:49:23

yes, then post a pastebin link to the correct PKGBUILD on the AUR comments for this package .

/edit: ok, i went the other way. i tried to apply the ssl patch to the mutt-sidebar PKGBUILD and it didn't go. so i took the repo PKGBUILD and applied the sidebar patch to it.

here's a working PKGBUILD:

# Maintainer: tobias [tobias [at] archlinux.org]
# sidebar patch applied by pbrisbin (at gmail dot com)
_name=mutt
pkgname=mutt-sidebar
pkgver=1.5.20
pkgrel=3
patchdate="20090619"
pkgdesc="A small but very powerful text-based mail client with the sidebar patch"
arch=(i686 x86_64)
license=('GPL')
url="http://www.mutt.org/"
depends=('slang' 'openssl' 'gdbm' 'mime-types' 'zlib' 'libsasl' 'gpgme')
conflicts=("$_name")
provides=("$_name")
makedepends=('gnupg')
install=${_name}.install
source=(ftp://ftp.mutt.org/mutt/devel/${_name}-${pkgver}.tar.gz
        http://lunar-linux.org/~tchan/mutt/patch-${pkgver}.sidebar.$patchdate.txt
        mutt-unmailbox.patch
        mutt_ssl.patch)
url="http://www.mutt.org/"
md5sums=('027cdd9959203de0c3c64149a7ee351c'
         '5786519489877c92e4fff68cf547e869'
         'fa8e03a49a2fa7b294dc8237d928cdb7'
         '3f54850315502ad47405421339ffae60')

build() {
  cd ${srcdir}/${_name}-${pkgver}

  # patch a segfault bug in 1.5.20 -- remove for next release
  patch -p1 < ${srcdir}/mutt-unmailbox.patch || return 1
  # patch for openssl-1
  patch -Np1 -i ${srcdir}/mutt_ssl.patch || return 1
  # patch for sidebar
  patch -p1 -i ${srcdir}/patch-${pkgver}.sidebar.$patchdate.txt

  ./configure --prefix=/usr --sysconfdir=/etc \
    --enable-pop --enable-imap --enable-smtp \
    --with-sasl --with-ssl=/usr --without-idn \
    --enable-hcache --enable-pgp --enable-inodesort \
         --enable-compressed --with-regex \
         --enable-gpgme --with-slang=/usr
  make || return 1
  make DESTDIR=${pkgdir} install
  rm -f ${pkgdir}/usr/bin/{flea,muttbug}
  rm -f ${pkgdir}/usr/share/man/man1/{flea,muttbug}.1
  rm -f ${pkgdir}/etc/mime.types*
  install -Dm644 contrib/gpg.rc ${pkgdir}/etc/Muttrc.gpg.dist
}

Last edited by brisbin33 (2010-04-09 18:33:14)

Arch Linux

#1 2010-04-09 15:27:31

mutt-sidebar 1.5.20-3 don't build with openssl 1.0.0

#2 2010-04-09 16:37:39

Re: mutt-sidebar 1.5.20-3 don't build with openssl 1.0.0

#3 2010-04-09 17:49:23

Re: mutt-sidebar 1.5.20-3 don't build with openssl 1.0.0

Board footer