Arch Linux

Evex

Member

Registered: 2015-01-30

Posts: 7

[Solved] Cinnamon Network Manager issue

Recently I started running into an issue with Network Manager on Cinnamon. When I go to the Network options in the Setting Panel an error pops up and gives me a message saying "The system network services are not compatible with this version." This issue just started happening about a week ago and I've just been using iw and wpa_supplicant to connect to networks in the meantime figuring the issue would be fixed with a later update. It works for now but I'd really rather have Network Manager take care of it. I've downgraded the networkmanager and network-manager-applet after noticing that the package was recently updated on the 10th. That did not do the trick. This issue is happening on both my i686 and x86_64 machines. I'm running Cinnamon on lightdm.

Last edited by Evex (2015-02-28 19:24:51)

Head_on_a_Stick

Member

From: The Wirral

Registered: 2014-02-20

Posts: 9,003

Website

Re: [Solved] Cinnamon Network Manager issue

https://bbs.archlinux.org/viewtopic.php?id=192939

---

Jin, Jîyan, Azadî

Evex

Member

Registered: 2015-01-30

Posts: 7

Re: [Solved] Cinnamon Network Manager issue

No dice... I cloned the git for the control center and made the modification to the source. After recompiling and installing, the issue persisted.

MrWeatherbee

Member

Registered: 2007-08-01

Posts: 288

Re: [Solved] Cinnamon Network Manager issue

FWIW, the patch I provided was applied with the PKGBUILD for cinnamon-control-center v2.4.2 from ABS. I have no idea if the files in git have changed or not, or whether those changes would matter or not.

Anyway, the patch is very simple for a very simple and specific problem: the minimum and maximum allowed NetworkManager version is hard-coded into cinnamon-control-center, and the coded max-version disallows use of anything greater than NetworkManager 0.9.x. If you are running 0.9.x and still getting the error message, obviously, something else is going wrong with your system because 0.9.x did not require the use of the patch in the first place.

Is it possible that during your work trying to get things working again that NetworkManager was inadvertently disabled? I ask because NetworkManager being disabled will generate the exact same error dialog and crippled settings dialog as does running a version  outside that allowed by the code in cinnamon-control-center.

In other words, is it possible that after the upgrade to NetworkManager v1.0.0, you initially had the problem that the patch would fix, but after changing things around on your system looking for a fix, you could have created another issue which needs to be addressed first?

Sorry I could not be of more help.

Last edited by MrWeatherbee (2015-01-30 22:31:08)

Evex

Member

Registered: 2015-01-30

Posts: 7

Re: [Solved] Cinnamon Network Manager issue

Well the issue is happening on all my machines(Desktops and Laptops). These machines have recently been clean installed from scratch.

Evex

Member

Registered: 2015-01-30

Posts: 7

Re: [Solved] Cinnamon Network Manager issue

This did end up being the fix

I ran into the same problem today when I moved my work laptop from ubuntu to arch. Downgrading Networkmanager made the cinnamon settings work, however that older version crashes when I connect to openvpn connection. Is there an easy way of applying this patch on a running system?

Not sure what you mean by 'easy way of applying this patch on a running system'? It'd be much harder to apply it to a system that wasn't running.

The basic steps are the same for any package patch.

- Get a copy of the original PKGBUILD and related files (.install file, other patches, etc.) from ABS or from the Arch packages web portal:
https://projects.archlinux.org/svntogit … rol-center

- Modify the PKGBUILD as necessary (to include the patch, etc.)
- place the patch in the build-folder with PKGBUILD and related files
- run makepkg (as normal user)
- install the new package (as root)
- enjoy

Is that easy enough?

----------

Here's the modified PKGBUILD I used:

# $Id: PKGBUILD 123172 2014-11-27 02:40:19Z faidoc $
# Maintainer: Alexandre Filgueira <alexfilgueira@cinnarch.com>
# Based on gnome-control-center:
# Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Jan de Groot <jgc@archlinux.org>

pkgname=cinnamon-control-center
pkgver=2.4.2
pkgrel=1
pkgdesc="The Control Center for Cinnamon"
arch=('i686' 'x86_64')
depends=('cinnamon-settings-daemon' 'cinnamon-translations' 'cinnamon-menus'
         'libgnomekbd' 'network-manager-applet')
optdepends=('gnome-color-manager: for color management tasks')
makedepends=('intltool' 'gnome-common' 'docbook-xsl')
url="https://github.com/linuxmint/cinnamon-control-center"
install=cinnamon-control-center.install
license=('GPL')
options=('!emptydirs')
groups=('aidenir_modified')
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/cinnamon-control-center/archive/$pkgver.tar.gz"
        'networkmanager_version_check.patch')
sha256sums=('7d25193a3cc13c12f22864f3c9a907acfaa616392cb2b7ab4e0624f0d200f188'
            'f55eb718462250aeba0e3a29db6b1c2b22697ea9f5b8224c293f5e4823ae75cd')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../networkmanager_version_check.patch 

}

build() {
  cd $pkgname-$pkgver

  ./autogen.sh --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --enable-systemd \
      --disable-update-mimedb

  #https://bugzilla.gnome.org/show_bug.cgi?id=656229
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  # Remove unused stuff
  make -C panels/sound DESTDIR="$pkgdir" uninstall
  make -C panels/sound/data DESTDIR="$pkgdir" install
  make -C shell DESTDIR="$pkgdir" uninstall-binPROGRAMS uninstall-directoryDATA uninstall-uiDATA
  rm "$pkgdir"/usr/share/applications/cinnamon-{control-center,datetime-panel,region-panel,sound-panel}.desktop
  rm -R "$pkgdir/etc"

  # Fix a warning
  chown 102:0 "$pkgdir/usr/share/polkit-1/rules.d"
  chmod 700 "$pkgdir/usr/share/polkit-1/rules.d"
}

Compare this PKGBUILD to the original, and you'll see that only a few things were added:

groups=('aidenir_modified')

The 'groups=' option is used to identify this package as a member of a group of your choosing (I, of course, did not use 'aidenir_modified' for my group, but took the liberty here, as an example, of using your online name. In conjunction with this, you add the same group to the '/etc/pacman.conf' IgnoreGroup option (e.g.,  IgnoreGroup= aidenir_modified), and this will prevent the unpatched, official 'cinnamon-control-center' package from overwriting your patched package. As soon as the official package is fixed, you can change or override that 'ignore' setting to allow the official package to upgrade your patched package.

source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/cinnamon-control-center/archive/$pkgver.tar.gz"
        'networkmanager_version_check.patch')

sha256sums=('7d25193a3cc13c12f22864f3c9a907acfaa616392cb2b7ab4e0624f0d200f188'
            'f55eb718462250aeba0e3a29db6b1c2b22697ea9f5b8224c293f5e4823ae75cd')

The two snippets above simply:
1) add the patch file to the source array;
2) add the sha256 hash of the patch file to the hash array.

When you create your patch file (likely via copy-and-paste from this page), re-calculate the hash and change it in the PKGBUILD if necessary.

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../networkmanager_version_check.patch 

}

Finally, the above snippet adds the 'patch' command to the PKGBUILD's 'prepare()' function.

----
Edit = code alignment