Arch Linux

STREBLO

Member

Registered: 2015-02-15

Posts: 135

[SOLVED] Building empty package

I've been trying to build a package using makepkg just to install it on my computer and my package file keeps ending up as an empty package with no binary. Makepkg completes with no errors so I'm not sure what I'm doing wrong, but here's my pkgbuild.

pkgname=raspbed
pkgver=1.2
pkgrel=1
pkgdesc="Controller and call bell for Volker hospital bed."
arch=('any')
url="https://github.com/Ramsdenj/Raspbed"
license=('GPL3')
depends=('qt5-base' 'boost')
optdepends=('skype: Call bell support')
makedepends=('git')
install=${pkgname}.install
changelog=${pkgname}.Changelog

_gitroot="https://github.com/Ramsdenj/Raspbed.git"
_gitname="RaspbedGit"
_gitpackage="Packages/Arch"

build() {
	cd "${srcdir}"
	git clone "${_gitroot}" "${_gitname}"
	cd "${_gitname}/${_gitpackage}/${pkgname}-${pkgver}"
	
	qmake
}

check() {
	cd "${srcdir}/${_gitname}/${_gitpackage}/${pkgname}-${pkgver}"
	make -k check
}

package() {
	cd "${srcdir}/${_gitname}/${_gitpackage}/${pkgname}-${pkgver}"
	make DESTDIR="$pkgdir/" install
}

Last edited by STREBLO (2015-10-12 08:01:24)

Trilby

Inspector Parrot

Registered: 2011-11-29

Posts: 30,517

Website

Re: [SOLVED] Building empty package

The makefile does not use DESTDIR - infact it implicitly sets DESTDIR as empty for some reason.  Instead it uses INSTALL_ROOT, so set that instead and it will work.

Also, you should update the PKGBUILD to not manually clone from git but to use the VCS PKGBUILD structure:

_gitname="raspbed"
pkgname="${_gitname}-git"
pkgver=1.2
pkgrel=1
pkgdesc="Controller and call bell for Volker hospital bed."
arch=('any')
url="https://github.com/Ramsdenj/Raspbed"
license=('GPL3')
depends=('qt5-base' 'boost')
optdepends=('skype: Call bell support')
makedepends=('git')
source=("${_gitname}::git://github.com/Ramsdenj/Raspbed.git")
sha256sums=('SKIP')

build() {
	cd "raspbed/Packages/Arch/raspbed-1.2"
	qmake
}

package() {
	cd "raspbed/Packages/Arch/raspbed-1.2"
	make INSTALL_ROOT="$pkgdir/" install
}

---

"UNIX is simple and coherent" - Dennis Ritchie; "GNU's Not Unix" - Richard Stallman

STREBLO

Member

Registered: 2015-02-15

Posts: 135

Re: [SOLVED] Building empty package

Thanks! After that and a few changes t's working great.