You are not logged in.
As said in the title? Thank you.
# Maintainer: Acar Burak <acarbura at gmail dot com>
pkgname=alexandra
pkgver=1.4.0
pkgrel=1
pkgdesc="Qt5 Video library with posters, fetchable, searchable tags, selectable player..."
arch=("x86_64")
url="https://github.com/jeka-js/alexandra"
license=("GPL2")
depends=("qt5-base" "desktop-file-utils" "hicolor-icon-theme")
optdepends=("libmediainfo: for technical info")
provides=("$pkgname")
conflicts=("$pkgname-git" "$pkgname")
install="$pkgname.install"
source=("$pkgname-master.zip::https://github.com/jeka-js/$pkgname/archive/master.zip")
md5sums=('1b07a73cad17613ad8bf72893921722a')
build() {
cd "$srcdir/$pkgname-master"
qmake-qt5 PREFIX="/usr"
make
}
package() {
cd "$srcdir/$pkgname-master"
make INSTALL_ROOT="$pkgdir/" install
}
Offline
The main issue is that you are pulling the source files from git HEAD, but using a fixed $pkgver.
Please read up on VCS PKGBUILDS....
https://wiki.archlinux.org/index.php/VC … guidelines
Offline
Thank you, slithery. I've tried to avoid (seemingly unsuccessfully) git as my noob brain couldn't grasp the intricacies of the pkgver thing!
Offline
If you want to create a fixed version package rather than a git package then you could just use https://github.com/jeka-js/alexandra/archive/1.4.0.zip as the source instead of downloading the current git HEAD.
Offline
It doesn't need to "provide" itself, and it really shouldn't "conflict" with itself. There's also not much point in "conflict"ing with a -git package that doesn't exist.
License is wrong. The license specifies "or (at your option) any later version", making it GPL, not just GPL2.
Overall, looks pretty good.
Offline
Thanks again. What about this as git version:
# Maintainer: Acar Burak <acarbura at gmail dot com>
_pkgname=alexandra
pkgname=alexandra-git
pkgver=1.4.0
pkgrel=1
pkgdesc="Qt5 Video library with posters, fetchable, searchable tags, selectable player..."
arch=("x86_64")
url="https://github.com/jeka-js/alexandra"
license=("GPL2")
depends=("qt5-base" "desktop-file-utils" "hicolor-icon-theme")
optdepends=("libmediainfo: for technical info")
provides=("$_pkgname" "$pkgname" )
conflicts=("$_pkgname" "$pkgname")
install="$_pkgname.install"
source=("$_pkgname::git+https://github.com/jeka-js/$pkgname")
md5sums=('1b07a73cad17613ad8bf72893921722a')
pkgver() {
cd "$srcdir/$_pkgname"
printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
build() {
cd "$srcdir/$_pkgname"
qmake-qt5 PREFIX="/usr"
make
}
package() {
cd "$srcdir/$_pkgname"
make INSTALL_ROOT="$pkgdir/" install
}
Offline
It doesn't need to "provide" itself, and it really shouldn't "conflict" with itself. There's also not much point in "conflict"ing with a -git package that doesn't exist.
License is wrong. The license specifies "or (at your option) any later version", making it GPL, not just GPL2.
Overall, looks pretty good.
Thank you. I've stolen those, that is, mis-stolen it seems. Will correct.
Offline
Latest (git version):
# Maintainer: Acar Burak <acarbura at gmail dot com>
_pkgname=alexandra
pkgname=alexandra-git
pkgver=1.4.0
pkgrel=1
pkgdesc="Qt5 Video library with posters, fetchable, searchable tags, selectable player..."
arch=("x86_64")
url="https://github.com/jeka-js/alexandra"
license=("GPL")
depends=("qt5-base" "desktop-file-utils" "hicolor-icon-theme")
optdepends=("libmediainfo: for technical info")
provides=("$_pkgname" )
conflicts=("$pkgname")
install="$_pkgname.install"
source=("$_pkgname::git+https://github.com/jeka-js/$pkgname")
md5sums=('1b07a73cad17613ad8bf72893921722a')
pkgver() {
cd "$srcdir/$_pkgname"
printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}
build() {
cd "$srcdir/$_pkgname"
qmake-qt5 PREFIX="/usr"
make
}
package() {
cd "$srcdir/$_pkgname"
make INSTALL_ROOT="$pkgdir/" install
}
Offline
You still have it conflicting with itself.
There's no reason to use printf in that pkgver function.
A checksum on a VCS source doesn't make sense. Use 'SKIP'.
Last edited by Scimmia (2016-01-07 16:09:01)
Offline
You still have it conflicting with itself.
Damn, yes!
A checksum on a VCS source doesn't make sense. Use 'SKIP'.
Yes, forgot that.
There's no reason to use printf in that pkgver function.
Well, I don't understand that pkgver function anyway, have just copied it.
Such a good software with no alternative I guess and yet only an innocent noob to package it?!
Last edited by fluxboxer (2016-01-07 16:29:46)
Offline
The pkgver function is run, and whatever it outputs is put into the pkgver variable. Just running the git describe command will do that. Adding the printf %s is similar to doing echo $(echo <something>)
Offline
Right, thank you Bug Wrangler.
Offline