XMonad manageHook - unable to catch Hangouts window by name/title

mika.perlin · 2016-02-12 11:15:18

Hi,

So I use Google Hangouts as my chat client, and I would like to have a special hook for managing Hangouts windows (namely, tiling them and swapping them down, so that they don't pop up in the master window pane).
The output of xprop on Hangouts (minus the giant icon) is:

_NET_WM_ICON_GEOMETRY(CARDINAL) = 750, 0, 181, 23
_NET_WM_DESKTOP(CARDINAL) = 3
WM_STATE(WM_STATE):
		window state: Normal
		icon window: 0x0
_NET_WM_USER_TIME(CARDINAL) = 39741567
WM_NORMAL_HINTS(WM_SIZE_HINTS):
		program specified location: 11, 34
WM_NAME(UTF8_STRING) = "Hangouts"
_NET_WM_NAME(UTF8_STRING) = "Hangouts"
XdndAware(ATOM) = BITMAP
_MOTIF_WM_HINTS(_MOTIF_WM_HINTS) = 0x2, 0x0, 0x1, 0x0, 0x0
_NET_WM_ICON(CARDINAL) = 	Icon (64 x 64):
WM_WINDOW_ROLE(STRING) = "pop-up"
WM_CLASS(STRING) = "crx_nckgahadagoaajjgafhacjanaoiihapd", "google-chrome"
_NET_WM_WINDOW_TYPE(ATOM) = _NET_WM_WINDOW_TYPE_NORMAL
_NET_WM_PID(CARDINAL) = 20659
WM_LOCALE_NAME(STRING) = "en_US.UTF-8"
WM_CLIENT_MACHINE(STRING) = "MAPHost"
WM_PROTOCOLS(ATOM): protocols  WM_DELETE_WINDOW, _NET_WM_PING

I try to achieve my desired behavior for Hangouts with the relevant parts of my xmonad config file:

myManageHook = composeAll . concat $
  [
    [ (title =? t) --> doCenterFloat | t <- floatTitles ],
    [ (title =? t) --> sink | t <- sinkTitles ], -- does not work for Hangouts <<<<<<<<<<<<<<<<<< line of interest
    [ (roleName =? r) --> sink | r <- sinkRoles ], -- fix for Hangouts  <<<<<<<<<<<<<<<<<<<<<<<<< line of interest
    [ (className =? c) --> doIgnore | c <- ignoreClasses ],
    [ (className =? c) --> doCenterFloat | c <- floatClasses ]
  ]
  where
    roleName = stringProperty "WM_WINDOW_ROLE"
    sink = (ask >>= doF . W.sink) <+> doF W.swapDown
    floatTitles = ["bashrun"]
    sinkTitles = ["Hangouts"] -- <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< line of interest
    sinkRoles = ["pop-up"] -- <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< line of interest
    ignoreClasses = ["Xfce4-notifyd"]
    floatClasses = ["Xfce4-appfinder","Xfce4-panel","Nm-connection-editor",
                    "Nm-openconnect-auth-dialog"," ","Wicd-client.py","Python2",
                    "Thunar","Arandr","Wrapper-1.0","google-chrome"]

where I have imported XMonad.StackSet as W, and I later append myManageHook to XMonad's manageHook (my entire config file is provided below, for reference). As I pointed out in the above code, catching Hangouts by title is not working. To have Hangouts do what I want, I currently catch it via the window role name, which awkwardly requires me to force pop-up windows into the tiling window layer. As my code suggests, I am able to catch other windows (i.e. bashrun, but I have also tried xfce4-terminal, inkscape, gimp, and emacs) by the WM_NAME property.

At one point I noticed that for all of the windows I could catch via title, the name property is labeled "WM_NAME(STRING)" by xprop, as opposed to "WM_NAME(UTF8_STRING)" for Hangouts. I therefore suspected that the problem might be due to the fact that XMonad's ManageHook is not catching UTF8_STRING properties, but falsified this suspicion by successfully catching and floating gimp via both the WM_NAME (which was a STRING) and _NET_WM_NAME (which was a UTF8_STRING) properties.

Any ideas on why I can't catch Hangouts windows by name, or on what other (sane) workarounds I can use?

Thanks.

xmonad.hs contents:

{-- todo:

sink Hangouts by window title (instead of role)
floating window management - get raise on click to work properly
sort out border color bug(?)
sort/comment imported modules - i.e. what is each module used for?

--}

import Control.Monad
import Data.Map as M
import Data.Monoid
import System.Exit
import System.IO
import XMonad
import XMonad.Actions.CycleWS
import XMonad.Actions.ConstrainedResize as CR
import XMonad.Actions.CopyWindow
import XMonad.Actions.NoBorders
import XMonad.Actions.WorkspaceNames
import XMonad.Config.Xfce
import XMonad.Hooks.EwmhDesktops
import XMonad.Hooks.ManageDocks
import XMonad.Hooks.ManageHelpers
import XMonad.Hooks.Place
import XMonad.Hooks.SetWMName
import XMonad.Layout.Fullscreen as FS
import XMonad.Layout.NoBorders
import XMonad.Layout.Renamed
import XMonad.Layout.ResizableTile
import XMonad.Layout.Spacing
import XMonad.Layout.ToggleLayouts
import XMonad.Layout.WindowNavigation
import XMonad.StackSet as W
import XMonad.Util.EZConfig
import XMonad.Util.Run (spawnPipe)
import XMonad.Util.NamedScratchpad

---------------------------------------------------------------------------------
-- variables

myBorderWidth = 1
myNormalBorderColor = "#000000"
myFocusedBorderColor = "#777777"
myFocusFollowsMouse = True

myWorkspaces = Prelude.map show [0..10] ++ ["NSP"]

scriptDir = "~/scripts/"

myTerminal = "xfce4-terminal"
myRun = "bashrun"

---------------------------------------------------------------------------------
-- window rules

myManageHook = composeAll . concat $
  [
    [ (title =? t) --> doCenterFloat | t <- floatTitles ],
    [ (title =? t) --> sink | t <- sinkTitles ],
    [ (roleName =? r) --> sink | r <- sinkRoles ], -- fix for Hangouts
    [ (className =? c) --> doIgnore | c <- ignoreClasses ],
    [ (className =? c) --> doCenterFloat | c <- floatClasses ]
  ]
  where
    roleName = stringProperty "WM_WINDOW_ROLE"
    sink = (ask >>= doF . W.sink) <+> doF W.swapDown
    floatTitles = ["bashrun"]
    sinkTitles = ["Hangouts"]
    sinkRoles = ["pop-up"]
    ignoreClasses = ["Xfce4-notifyd"]
    floatClasses = ["Xfce4-appfinder","Xfce4-panel","Nm-connection-editor",
                    "Nm-openconnect-auth-dialog"," ","Wicd-client.py","Python2",
                    "Thunar","Arandr","Wrapper-1.0","google-chrome"]

---------------------------------------------------------------------------------
-- scratchpads

termName = "term"
calcName = "calc"
altTermName = "alt-term"
htopName = "htop"
mixerName = "mixer"
myScratchPads = [ padTemplate termName termHook,
                  padTemplate altTermName altTermHook,
                  padTemplate calcName calcHook,
                  padTemplate htopName htopHook,
                  NS mixerName mixerCommand mixerID mixerHook ]
  where
    padTemplate name padHook =
        NS name (scriptDir ++ "pads " ++ name) (title =? ("pad-" ++ name)) padHook
    termHook = customFloating $ W.RationalRect l t w h
      where
        h = 1/2
        w = 0.45
        t = (1-h)*9/10
        l = (1/2-w)/2
    altTermHook = customFloating $ W.RationalRect l t w h
      where
        h = 1/2
        w = 0.45
        t = (1-h)*9/10
        l = 1/2+(1/2-w)/2
    calcHook = customFloating $ W.RationalRect l t w h
      where
        h = 2/3
        w = 2/5
        t = 1/25
        l = 1-w
    htopHook = customFloating $ W.RationalRect l t w h
      where
        h = 4/5
        w = 1/2
        t = (1-h)/2
        l = (1-w)/2
    mixerCommand = "pavucontrol"
    mixerID = className =? "Pavucontrol"
    mixerHook = customFloating $ W.RationalRect l t w h
      where
        h = 4/5
        w = 1/2
        t = (1-h)/2
        l = (1-w)/2

---------------------------------------------------------------------------------
-- layout definitions

normal = renamed [Replace "normal"] $ ResizableTall 1 (1/50) (1/2) []
latex = renamed [Replace "latex"] $ ResizableTall 1 (1/50) (39/100) []
chat = renamed [Replace "chat"] $ ResizableTall 1 (1/50) (73/100) []
skype = renamed [Replace "skype"] $ ResizableTall 1 (1/50) (64/100) []
full = renamed [Replace "full"] $ Full

(|+|) :: (LayoutClass l a, LayoutClass r a) =>
         (l a, Int) -> r a -> (Choose l r a, Int)
(a,n) |+| b = (a ||| b, n+1)
countedLayouts = (normal,1) |+| latex |+| chat |+| skype
layouts = fst countedLayouts
layoutCount = snd countedLayouts

myLayoutHook = smartBorders $ avoidStruts $ windowNavigation $ smartSpacing 3 $
               toggleLayouts full layouts

myPlacement = withGaps (16,16,16,16) (fixed (0.5,0.5))

---------------------------------------------------------------------------------
-- key commands

-- define number row, arrow keys, and modification keys
numRow = ["`"] ++ (Prelude.map show [1..9]) ++ ["0","-"]
arrows = [["<L>","<R>","<U>","<D>"],["n","i","u","e"],["r","s","p","v"]]
modKeys = ["","C-","S-","M1-"]

-- define window actions in each direction performed by modification keys
actLeft = [prevWS, swapTo Prev, shiftToPrev, shiftToPrev >> prevWS]
actRight = [nextWS, swapTo Next, shiftToNext, shiftToNext >> nextWS]
actUp = [prevScreen, swapPrevScreen, shiftPrevScreen, shiftPrevScreen >> swapPrevScreen]
actDn = [nextScreen, swapNextScreen, shiftNextScreen, shiftNextScreen >> swapNextScreen]

{-
  for each set of actions, pair up modification keys with the respective action
  e.g. ("C-", swapTo Prev)
-}
modActions = [ zip modKeys dirFuns | dirFuns <- [actLeft,actRight,actUp,actDn] ]


-- for each set of arrow keys, pair up arrows with respective modification key and action
dirControlsSet = join [ zip dirs modActions | dirs <- arrows ]

-- collect all appropriate combinations of keys and workspace actions into a single list
dirControls = join [ [ (dir,mod,fun) | let dir = fst set, (mod,fun) <- snd set ]
                     | set <- dirControlsSet ]

-- note: check output of 'xmodmap' for modifier key map (i.e. M1, M4, etc.)

myKeys = \conf -> mkKeymap conf $
    ---------- workspace management ----------
    [
     ("M4-" ++ mod ++ key, windows $ func ws)
         | (ws,key) <- zip myWorkspaces numRow,
           (mod,func) <- [ ("", W.greedyView), ("S-", W.shift),
                           ("M1-", \i -> W.greedyView i . W.shift i) ]
    ]
    ++
    [ ("M4-C-" ++ key, swapWithCurrent ws) | (ws,key) <- zip myWorkspaces numRow ]
    ++
    [ ("M4-" ++ mod ++ dir, func) | (dir,mod,func) <- dirControls ]
    ++
    [
     ("M1-z", toggleWS' ["NSP"]),
     ---------- layout management ----------
     ("M4-<Space>", nextLayout),
     ("M4-S-<Space>", prevLayout),
     ("M4-M1-<Space>", setLayout $ layoutHook conf),
     ("M4-z", sendMessage $ Toggle "full"),
     ("M4-x", sendMessage Shrink),
     ("M4-c", sendMessage Expand),
     ("M4-S-x", sendMessage $ IncMasterN 1),
     ("M4-S-c", sendMessage $ IncMasterN (-1)),
     ("M4-M1-x", sendMessage MirrorExpand),
     ("M4-M1-c", sendMessage MirrorShrink),
     ("M4-b", sendMessage ToggleStruts),
     ---------- window management ----------
     ("M1-<Tab>", windows focusUp >> windows shiftMaster),
     ("M1-S-<Tab>", windows focusDown >> windows shiftMaster),
     ("M4-w", windows focusUp),
     ("M4-f", windows focusDown),
     ("M4-S-w", windows swapUp),
     ("M4-S-f", windows swapDown),
     ("M4-q", windows focusMaster),
     ("M4-a", windows shiftMaster),
     ("M4-t", withFocused $ windows . sink),
     ("M4-<Esc>", kill),
     ---------- spawning ----------
     ("M4-<Tab>", spawn $ terminal conf),
     ("M1-`", spawn myRun),
     ("M1-<F1>", namedScratchpadAction myScratchPads termName),
     ("M1-<F2>", namedScratchpadAction myScratchPads altTermName),
     ("M1-<F3>", namedScratchpadAction myScratchPads calcName),
     ("M1-<F4>", namedScratchpadAction myScratchPads htopName),
     ("M1-<F5>", namedScratchpadAction myScratchPads mixerName),
     ---------- media keys ----------
     ("<XF86AudioMute>", runScript "volume toggle"),
     ("<XF86AudioLowerVolume>", runScript "volume dec"),
     ("<XF86AudioRaiseVolume>", runScript "volume inc"),
     ("<XF86MonBrightnessDown>", runScript "light dec"),
     ("<XF86MonBrightnessUp>", runScript "light inc"),
     ("<XF86Display>", spawn "arandr"),
     ("<XF86Search>", spawn myRun),
     ---------- testing media keys ----------
     ("<XF86AudioMicMute>", runScript "volume toggle"),
     ("<XF86Tools>", runScript "volume toggle"),
     ("<XF86LaunchA>", runScript "volume toggle"),
     ("<XF86MyComputer>", runScript "volume toggle"),
     ---------- volume ----------
     ("C-/", runScript "volume toggle"),
     ("C-<D>", runScript "volume dec"),
     ("C-<U>", runScript "volume inc"),
     ("C-S-<D>", runScript "volume min"),
     ("C-S-<U>", runScript "volume max"),
     ("C-S-/", runScript "volume med"),
     ---------- backlight ----------
     ("M1-<D>", runScript "light dec"),
     ("M1-<U>", runScript "light inc"),
     ("M1-S-<U>", runScript "light max"),
     ("M1-S-<D>", runScript "light dim"),
     ("M1-S-/", runScript "light med"),
     ---------- screenshots ----------
     ("M4-\\", runScript "print"),
     ("M4-M1-\\", runScript "print -s"),
     ---------- misc ----------
     ("M1-;", runScript "touchpad-toggle"),
     ("M4-/", windows copyToAll),
     ("M4-S-/", killAllOtherCopies),
     ("C-M4-<Backspace>", io $ exitWith ExitSuccess)
    ]
    where nextLayout = sendMessage NextLayout
          prevLayout = do { replicateM_ (layoutCount-1) $ sendMessage NextLayout}
          runScript s = spawn $ scriptDir ++ s

---------------------------------------------------------------------------------
-- cursor actions

myMouseBindings (XConfig {}) = fromList $
  [
   ((mod1Mask, button1), move),
   ((mod1Mask, button3), resize False),
   ((mod1Mask .|. controlMask, button3), resize True),
   ((mod1Mask .|. shiftMask, button1), resize False),
   ((mod1Mask .|. shiftMask .|. controlMask, button1), resize True)
  ]
    where
      move = raiseFloating mouseMoveWindow
      resize b = raiseFloating $ \w -> CR.mouseResizeWindow w b
      raiseFloating f = \w -> withWindowSet $ \s -> do
                          XMonad.focus w >> (if M.member w $ floating s
                                             then f w >> windows W.shiftMaster
                                             else f w)

---------------------------------------------------------------------------------
-- bring floating window to the front when clicked
-- note: only works on unfocused windows (i.e. it does not work properly)

floatClickFocusHandler :: Event -> X All
floatClickFocusHandler ButtonEvent { ev_window = w, ev_event_type = t }
    | t == buttonPress = do withWindowSet $ \ws -> do
                              if M.member w $ floating ws
                              then (XMonad.focus w >> windows shiftMaster)
                              else return ()
                            return $ All True
floatClickFocusHandler _ = return $ All True

---------------------------------------------------------------------------------
-- run XMonad

main = do
  xmonad $ xfceConfig {
        terminal = myTerminal,
        borderWidth = myBorderWidth,
        normalBorderColor = myNormalBorderColor,
        focusedBorderColor = myFocusedBorderColor,
        focusFollowsMouse = myFocusFollowsMouse,
        modMask = mod4Mask,
        XMonad.keys = myKeys,
        XMonad.workspaces = myWorkspaces,
        layoutHook = myLayoutHook,
        manageHook = namedScratchpadManageHook myScratchPads
                     <+> placeHook myPlacement
                     <+> myManageHook
                     <+> manageDocks
                     <+> fullscreenManageHook
                     <+> manageHook defaultConfig,
        mouseBindings = myMouseBindings,
        startupHook = ewmhDesktopsStartup >> setWMName "LG3D",
        handleEventHook = ewmhDesktopsEventHook
                          <+> FS.fullscreenEventHook
                          <+> floatClickFocusHandler
    }

Last edited by mika.perlin (2016-02-12 11:17:58)

altercation · 2016-12-31 03:43:30

I figured this out. I'm just rebuilding my XMonad config after a couple years away from it and wanted to manage Hangouts in particular (though possibly some other chrome based popups as well).

Basically, you need a newish (for XMonad) contrib module named XMonad.Hooks.DynamicProperties.

I tried for a LONG time to get this to work with the version from 0.12 (at the time of this post, the current release version of XMonad, which I personally installed from the Arch Haskell repo, but which should, I think, be the same in the main repos).

That version is apparently broken, for it wasn't till I dumped a copy of the version I found on github that I got it to work. See: https://github.com/xmonad/xmonad-contri … roperty.hs (I saved that to .xmonad/lib/XMonad/Hooks/DynamicProperty.hs which apparently XMonad will check first for modules, so it should override the default version).

Then I included the follow code in my XMonad.hs:

myHandleEventHook = docksEventHook
    <+> fadeWindowsEventHook
    <+> dynamicPropertyChange "WM_NAME" myDynHook
    <+> handleEventHook def

myDynHook = composeAll
    [ (className =? "Google-chrome-beta" <&&> title =? "Google Hangouts - es@ethanschoonover.com" --> doCenterFloat)
    ]

Ideally I'd want to match this to just a substring, but I just got it working and thought of this thread, which I'd come across before. Hope it helps.

Arch Linux

#1 2016-02-12 11:15:18

XMonad manageHook - unable to catch Hangouts window by name/title

#2 2016-12-31 03:43:30

Re: XMonad manageHook - unable to catch Hangouts window by name/title

Board footer