Arch Linux

Vbaxbear

Member

Registered: 2015-12-28

Posts: 29

Install oracle-sqldeveloper

Hello,

I try to install the oracle-sqldeveloper but I am not sure how to do this exactly.

First of all I downloaded it from the oracle site as .zip and then I tried to find out how to change the pkgbuild thing that it can find the zip and install it. But wasn't able to manage that.

Here ist the content of this file:

# Maintainer:  Matt Parnell/ilikenwf <parwok@gmail.com>
# Contributor: G. Richard Bellamy <rbellamy@pteradigm.com>
# Contributor: Hugo Osvaldo Barrera <hugo@barrera.io>
# Contributor: ptk042 <ptk042@gmail.com>
# Contributor: mmm <markotahal@gmail.com>
# Contributor: xduugu <xduugu@gmx.com>
# Contributor: Evangelos Foutras <foutrelis@gmail.com>
# Contributor: David Fuhr <david.fuhr@web.de>
# what the heck

pkgname=oracle-sqldeveloper
pkgver=4.1.5.21.78
pkgrel=1
pkgdesc="A graphical tool for database development"
arch=('any')
url="http://www.oracle.com/technetwork/developer-tools/sql-developer/downloads/index.html"
license=('custom:OTN')
depends=('java-environment' 'bash' 'perl')
optdepends=('ksh')
source=(manual://sqldeveloper-$pkgver-no-jre.zip
        oracle-sqldeveloper.desktop
        oracle-sqldeveloper.sh
        LICENSE
        java_home.patch)
DLAGENTS+=('manual::/usr/bin/echo The source file for this package needs to be downloaded manually, since it requires a login and is not redistributable.;/usr/bin/echo Please visit http://www.oracle.com/technetwork/developer-tools/sql-developer/downloads/index.html.; exit 1;')
md5sums=('190e51deff4831c5cf070a405f992053'
         '59783d9d8c5f9da8256fa14d0e61a35e'
         '26c1dc933a9ab58a4245f4f351717645'
         '71a4092467209c160d0f34abbc08e049'
         'fe446201cc0d5326ecb757c384c67232')

# don't compress the package - we're just going to uncompress during install in a moment
PKGEXT='.pkg.tar'

package() {
  cd "$srcdir/sqldeveloper"

  patch -Np1 < "$srcdir/java_home.patch"
  find . \( -iname "*.exe" -o -iname "*.dll" \) -exec rm -f "{}" +
  find . -type f -exec install -Dm644 "{}" "$pkgdir/opt/oracle-sqldeveloper/{}" \;
  chmod +x "$pkgdir/opt/$pkgname/sqldeveloper.sh"

  install -Dm755 "$srcdir/$pkgname.sh"      "$pkgdir/usr/bin/$pkgname"
  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "$srcdir/LICENSE"          "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  
  msg "You will need to set JAVA_HOME or run this package for the first time from the console to set the jdk path."
}

# vim:set ts=2 sw=2 et:

My downloaded zip is in ~/Downloads/*.zip

Could you possibly tell me how to change it?

When I try to install the sqldeveloper I get this error:
Failure while downloading manual://sqldeveloper-4.1.5.21.78-no-jre.zip
Aborting...
Makepkg was unable to build oracle-sqldeveloper.

Thank you in advance.

toz

Member

Registered: 2011-10-28

Posts: 497

Re: Install oracle-sqldeveloper

No need to change the PKGBUILD file. Just copy your downloaded version of sqldeveloper-4.1.5.21.78-no-jre.zip to the base directory of where your PKGBUILD (and other package files) are. Then run "makepkg -si".

Vbaxbear

Member

Registered: 2015-12-28

Posts: 29

Re: Install oracle-sqldeveloper

Thank you very much, it worked. For some reason, I found the answer before some where in the depth of this site but just didn't really understood it - don't ask why, no special reason

Last edited by Vbaxbear (2017-01-14 17:36:33)