[Request] ffmpegthumbnailer with embedded coverart support

addicted · 2017-01-14 12:46:46

Here is repo with modified ffmpegthumbnailer.
I tested this & it's working.Though i have to copy some file from /usr/local to /usr directory.
AUR for this will be a good idea

Last edited by addicted (2017-01-23 13:30:18)

WorMzy · 2017-01-14 13:09:59

I think you forgot to include a link..

addicted · 2017-01-23 13:31:37

sorry i forgot to add repo url.
I updated main post with url now.

metak · 2017-01-23 14:24:56

It's in the main repos since forever... ;-) https://www.archlinux.org/packages/extr … umbnailer/

ugjka · 2017-01-23 14:49:33

Alternative if you use kde https://aur.archlinux.org/packages/audio-thumbs5/

Last edited by ugjka (2017-01-23 15:29:04)

addicted · 2017-01-24 03:45:15

The difference between master & embeddedcover branch is embedded can show cover art file inside mkv file.
in main repo master branch is present.
@metak Can you confirm embedded cover is showing using that?(may be embedded cover merged to master branch)
I haven't used repo ffmpegthumbnailer since i started using embeddedcover branch & it's a pain to remove it , test repo package & again revert back.
@ugjka thanks for suggestion.But that's for kde

metak · 2017-01-24 10:40:58

@addicted sorry about that, I completely missed that you were talking about separate branch... ;-)
Anyway, you could just modify the official package?

pkgname=ffmpegthumbnailer-embeddedcover-git
pkgver=2.1.2.3.gc4d4e21
pkgrel=1
pkgdesc="Lightweight video thumbnailer that can be used by file managers."
url="https://github.com/dirkvdb/ffmpegthumbnailer"
license=('GPL2')
arch=('i686' 'x86_64')
depends=('ffmpeg' 'libjpeg' 'libpng')
makedepends=('cmake' 'git')
optdepends=('gvfs: support for gio uris')
conflicts=('ffmpegthumbnailer')
provides=('ffmpegthumbnailer')
source=("git+${url}#branch=embeddedcover")
sha1sums=('SKIP')

pkgver() {
  cd ffmpegthumbnailer
  git describe --tags | sed 's/-/./g'
}

build() {
  cd ffmpegthumbnailer
  cmake . \
	-DCMAKE_BUILD_TYPE=Release \
	-DCMAKE_INSTALL_PREFIX=/usr \
	-DCMAKE_INSTALL_LIBDIR=lib \
	-DENABLE_GIO=ON \
	-DENABLE_THUMBNAILER=ON
  make
}

package() {
  cd ffmpegthumbnailer
  make DESTDIR="${pkgdir}" install
}

Arch Linux

#1 2017-01-14 12:46:46

[Request] ffmpegthumbnailer with embedded coverart support

#2 2017-01-14 13:09:59

Re: [Request] ffmpegthumbnailer with embedded coverart support

#3 2017-01-23 13:31:37

Re: [Request] ffmpegthumbnailer with embedded coverart support

#4 2017-01-23 14:24:56

Re: [Request] ffmpegthumbnailer with embedded coverart support

#5 2017-01-23 14:49:33

Re: [Request] ffmpegthumbnailer with embedded coverart support

#6 2017-01-24 03:45:15

Re: [Request] ffmpegthumbnailer with embedded coverart support

#7 2017-01-24 10:40:58

Re: [Request] ffmpegthumbnailer with embedded coverart support

Board footer