Arch Linux

PRStoetzer

Member

Registered: 2018-06-11

Posts: 3

[SOLVED] Request for PKGBUILD - Elantech libfprint fork

I am not sure where to begin with trying to write a PKGBUILD for this fork of libprint that supports Elantech fingerprint readers (https://github.com/iafilatov/libfprint). There's an orphaned AUR package (https://aur.archlinux.org/packages/libfprint-elantech/), but the Github repository that came from has been deleted.

Thanks in advance!

Last edited by PRStoetzer (2018-06-26 17:22:20)

arisinfenix

Member

From: Germany

Registered: 2018-06-20

Posts: 37

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

# Maintainer: Your Name <youremail@domain.com>

pkgname=libfprint-elantech-git
pkgver=r352.8d2c931
pkgrel=1
pkgdesc="A fork of libfrpint with ElanTech fingerprint reader driver"
arch=(x86_64)
url="https://github.com/iafilatov/libfprint"
license=(LGPL)
depends=(glib2 pixman nss libusb)
makedepends=(git meson ninja gtk-doc libx11 libxv)
conflicts=(libfprint)
provides=(libfprint)
source=(git+https://github.com/iafilatov/libfprint.git)
md5sums=(SKIP)

pkgver() {
  cd libfprint
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  meson ../libfprint --prefix /usr
  ninja
}

package() {
  cd build
  DESTDIR="$pkgdir" ninja install
}

edit: added confilcts and provides

Last edited by arisinfenix (2018-06-26 11:15:10)

PRStoetzer

Member

Registered: 2018-06-11

Posts: 3

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

Thanks for the quick reply! Builds, installs, and works perfectly!

arisinfenix

Member

From: Germany

Registered: 2018-06-20

Posts: 37

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

Nice
So you can mark this thread solved. (by editing your first post)

loqs

Member

Registered: 2014-03-06

Posts: 18,828

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

There's an orphaned AUR package (https://aur.archlinux.org/packages/libfprint-elantech/), but the Github repository that came from has been deleted.

You might consider becoming the maintainer of the orphaned AUR package with the working PKGBUILD or flagging it for removal as it has no upstream source as is.

PRStoetzer

Member

Registered: 2018-06-11

Posts: 3

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

There's an orphaned AUR package (https://aur.archlinux.org/packages/libfprint-elantech/), but the Github repository that came from has been deleted.

You might consider becoming the maintainer of the orphaned AUR package with the working PKGBUILD or flagging it for removal as it has no upstream source as is.

I will do so. I wasn't sure what the etiquette was around submitting someone else's PKGBUILD.

arisinfenix

Member

From: Germany

Registered: 2018-06-20

Posts: 37

Re: [SOLVED] Request for PKGBUILD - Elantech libfprint fork

Feel free. I suggest a removal request for libfprint-elantech since it lacks the -git suffix in the package name and upload the new PKGBUILD as libfprint-elantech-git.