[SOLVED] Dependecies problems with foxit reader AUR package

jacopastorius · 2019-01-19 12:12:57

Hi all. I am trying to install foxit reader from aur package.
The problem is with gstreamer0.10-base dependecy

[du@du foxitreader]$ makepkg -si
==> Making package: foxitreader 2.4.4.0911-1 (Sat Jan 19 13:07:40 2019)
==> Checking runtime dependencies...
==> Installing missing dependencies...
[sudo] password for du: 
error: target not found: gstreamer0.10-base
==> ERROR: 'pacman' failed to install missing dependencies.

Here is PKGBUILD

# Maintainer: Muflone http://www.muflone.com/contacts/english/
# Contributor: Stephen Zhang <zsrkmyn at gmail dot com>
# Contributor: TDY <tdy@archlinux.info>

pkgname=foxitreader
pkgver=2.4.4.0911
_foxitrevision=r057d814
pkgrel=1
pkgdesc="A fast, secure and complete PDF viewer"
arch=('x86_64')
url="https://www.foxitsoftware.com/products/pdf-reader/"
license=('custom:EULA')
depends=('libsecret' 'libxslt' 'libxcomposite' 'libgl' 'libxrender' 'gstreamer0.10-base'
         'libxi' 'libsm' 'fontconfig' 'dbus' 'openssl-1.0' 'desktop-file-utils')
makedepends=('p7zip' 'chrpath')
optdepends=('gtk2: use GTK+ dialogs under GTK+ based desktop environments')
source=("http://cdn09.foxitsoftware.com/pub/foxit/reader/desktop/linux/2.x/${pkgver%.*.*}/en_us/FoxitReader.enu.setup.${pkgver}.x64.run.tar.gz"
        "https://www.foxitsoftware.com/products/pdf-reader/eula.html"
        "${pkgname}.patch"
        "${pkgname}-excluded_files")
sha256sums=('6b579bd4ecdf86f7e70a009886c511da0b5085b831b0d6afc42442cabc249b90'
            '7814e03ea944f5ee5ff791e97c13446a5274989a1679758a92af0405d0fc7dce'
            'ee0f65819d00fea89f40112c769c704c7b663ff852e9d1d6e36d1b6d054d9c05'
            'e558529c6dbea047eee744b011ffcc214547c503896b14211ebf5f6309ef4e9f')

build() {
  local _file
  local _line
  local _position
  # Clean installer dir
  if [ -d "${pkgname}-installer" ]
  then
    rm -rf "${pkgname}-installer"
  fi
  mkdir "${pkgname}-installer"
  # Decompress .run installer
  _file="FoxitReader.enu.setup.${pkgver}(${_foxitrevision}).x64.run"
  LANG=C grep --only-matching --byte-offset --binary \
              --text $'7z\xBC\xAF\x27\x1C' "${_file}" | cut -f1 -d: | 
         while read _position
         do
           dd if="${_file}" \
              bs=1M iflag=skip_bytes status=none skip=${_position} \
              of="${pkgname}-installer/bin-${_position}.7z"
         done
  # Clean build dir
  if [ -d "${pkgname}-build" ]
  then
    rm -rf "${pkgname}-build"
  fi
  # Decompress 7z files (some files are damaged during the extraction)
  cd "${pkgname}-installer"
  install -m 755 -d "${srcdir}/${pkgname}-build"
  for _file in *.7z
  do
    7z -bd -bb0 -y x -o"${srcdir}/${pkgname}-build" ${_file} 1>/dev/null 2>&1 || true
  done
  # Apply final patches
  cd "${srcdir}/${pkgname}-build"
  patch -p1 --no-backup-if-mismatch -i "${srcdir}/${pkgname}.patch"
  # Remove insecure RPATH
  for _file in "lib/libFcitxQt5DBusAddons.so.1.0" \
               "lib/libQt5PrintSupport.so.5.3.2" \
               "platforminputcontexts/libfcitxplatforminputcontextplugin.so" \
               "printsupport/libcupsprintersupport.so"
  do
    echo "  -> Removing insecure RPATH from ${_file}"
    chrpath --delete "${_file}"
  done
  # Remove unneeded files
  rm "Activation" "Activation.desktop" "Activation.sh" \
     "countinstalltion" "countinstalltion.sh" \
     "installUpdate" "ldlibrarypath.sh" \
     "maintenancetool.sh" "Uninstall.desktop" \
     "Update.desktop" "updater" "updater.sh"
  find -type d -name ".svn" -exec rm -rf {} +
  find -type f -name ".directory" -exec rm -rf {} +
  find -type f -name "*~" -exec rm {} +
  # Remove excluded files
  while IFS='' read -r _line
  do
    if [ "${_line::2}" = "# " ]
    then
      echo "  -> Removing excluded files from ${_line:2}..."
    elif [ -n "${_line}" -a "${_line::1}" != "#" ]
    then
      rm "${srcdir}/${pkgname}-build/${_line}"
    fi
  done < "${srcdir}/${pkgname}-excluded_files"
}

package() {
  install -m 755 -d "${pkgdir}/usr/lib/${pkgname}"
  cd "${srcdir}/${pkgname}-build"
  cp -r * "${pkgdir}/usr/lib/${pkgname}"
  # Install icon and desktop files
  install -m 755 -d "${pkgdir}/usr/share/pixmaps"
  install -m 644 "images/FoxitReader.png" \
    "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  install -m 755 -d "${pkgdir}/usr/share/applications"
  install -m 755 "FoxitReader.desktop" \
    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  rm FoxitReader.desktop
  # Install license file
  install -m 755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/eula.html"
  # Install launcher script
  cd "${pkgdir}"
  install -m 755 -d "${pkgdir}/usr/bin"
  ln -s "/usr/lib/${pkgname}/FoxitReader.sh" "${pkgdir}/usr/bin/${pkgname}"

Searching for related installed packages:

[du@du foxitreader]$ sudo pacman -Qs gstreamer
local/gst-plugins-base 1.14.4-1
    GStreamer Multimedia Framework Base Plugins
local/gst-plugins-base-libs 1.14.4-1
    GStreamer Multimedia Framework Base Libraries
local/gst-plugins-good 1.14.4-1
    GStreamer Multimedia Framework Good Plugins
local/gstreamer 1.14.4-1
    GStreamer open-source multimedia framework core library
local/parole 1.0.1-2 (xfce4-goodies)
    Modern media player based on the GStreamer framework
local/phonon-qt5-gstreamer 4.9.0-5
    Phonon GStreamer backend for Qt5

gstreamer0.10-base is not present in main arch repos but it is in AUR. What should I do? Given the extreme priority to not risk anything in system breakes caused by conflicting dependecies

EDIT: Solution in post #3

Last edited by jacopastorius (2019-01-19 15:11:50)

Muflone · 2019-01-19 12:18:49

Hi

I'm not convinced about your arguments.

Do you want to install foxitreader from the AUR but you don't want to install its dependencies from the AUR?

About any breakage, I don't think you'll have any break but as usual, nothing is garanteed.

WorMzy · 2019-01-19 12:19:15

gstreamer0.10 packages don't conflict with their gstreamer/gst counterparts. You can build the AUR packages and install them (preferably with --asdeps) alongside the official repository packages.

jacopastorius · 2019-01-19 12:39:21

Thank you. Muflone, since i am noob to arch and i really do not know if installing AUR package alongside with official ones could led to breaks risks, it is better for me to ask, before installing dependecies that are not on official repositories.
Thank you for maintaining those package in the AUR

jacopastorius · 2019-01-19 13:22:09

Trying to build gstreamer0.10-base ask me for gstreamer0.10 dependecy so I downloded it from AUR but trying to build it ask for other dependecies. Does a method to automate the retrieving of missing dependecies?

Last edited by jacopastorius (2019-01-19 13:28:17)

loqs · 2019-01-19 13:28:32

https://www.archlinux.org/packages/extra/any/intltool/
Edit:
AUR_helpers.

Last edited by loqs (2019-01-19 13:32:41)

Muflone · 2019-01-19 14:55:45

jacopastorius wrote:

it is better for me to ask, before installing dependecies that are not on official repositories.

The thumb rule is the AUR is totally unsupported, every package in the AUR could teorically lead to a security risk.
If you trust the maintainer then you decide to install the packages.

I'm not telling you to not install foxitreader or its dependencies, all of my packages are clean and built in clean chroot but I cannot guarantee about the dependencies that aren't maintained by me.

jacopastorius · 2019-01-19 15:02:03

Thank you Muflone. My main concern is not the package security, while a system break following missing updates of some dependecies (i have encountered a lot of these situation few years ago when i was using debian etch).
I have built my arch system in this last month adding piece by piece and reading a lot in the fantastic wiki and now, thanks to the community too that helped me a lot here in the forum, i have a system that has all i need.
I am sure the community will help me solving system breaks but i'd like to lear how to avoid them (i have already read the recommendations in the wiki yet)

Last edited by jacopastorius (2019-01-19 15:04:44)

Arch Linux

#1 2019-01-19 12:12:57

[SOLVED] Dependecies problems with foxit reader AUR package

#2 2019-01-19 12:18:49

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#3 2019-01-19 12:19:15

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#4 2019-01-19 12:39:21

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#5 2019-01-19 13:22:09

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#6 2019-01-19 13:28:32

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#7 2019-01-19 14:55:45

Re: [SOLVED] Dependecies problems with foxit reader AUR package

#8 2019-01-19 15:02:03

Re: [SOLVED] Dependecies problems with foxit reader AUR package

Board footer