You are not logged in.

#1 2019-05-22 18:18:17

benjamb
Member
Registered: 2019-05-22
Posts: 2

[SOLVED] PKGBUILD review request

AFAICT everything is sane, however since this is my first PKGBUILD I'd greatly appreciate a review. I've tested with makechrootpkg and also checked that namcap doesn't complain.

# Maintainer: Ben Brown <benjamb at pm dot me>
pkgname=dlt-viewer-git
pkgver=2.18.0.r132.g2e75489
pkgrel=1
pkgdesc="Diagnostic Log and Trace viewing program"
url="https://github.com/GENIVI/dlt-viewer"
arch=('x86_64')
license=('MPL2')
depends=('qt5-base' 'qt5-serialport')
makedepends=('git')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
source=("${pkgname%-*}::git+$url")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-*}"
  git describe --tags --long | sed 's/^v//;s/[^-]*-g/r&/;s/-/./g'
}

build() {
  cd "${pkgname%-*}"
  qmake BuildDltViewer.pro
  make
}

package() {
  cd "${pkgname%-*}"
  make INSTALL_ROOT="${pkgdir}" install
}

Last edited by benjamb (2019-05-28 09:12:49)

Offline

#2 2019-05-22 19:13:16

progandy
Member
Registered: 2012-05-17
Posts: 3,581

Re: [SOLVED] PKGBUILD review request

Looks good so far. You might want to pass CFLAGS and friends to qmake, though.


| alias CUTF='LANG=en_XX.UTF-8@POSIX ' |

Offline

#3 2019-05-22 19:51:25

benjamb
Member
Registered: 2019-05-22
Posts: 2

Re: [SOLVED] PKGBUILD review request

Ah, good to know. Thanks!

Offline

Board footer

Powered by FluxBB