Arch Linux

kunda

Member

Registered: 2019-01-06

Posts: 14

[REQUEST] openvoronoi - 2D voronoi diagram

2D voronoi diagram for point and line-segment sites using incremental topology-oriented algorithm. C++ with python bindings.

Source repo: https://github.com/aewallin/openvoronoi
Website: http://www.anderswallin.net/cam/
Mailing list: https://groups.google.com/forum/?hl=en# … opencamlib
License: LGPL2.1

Required Dependencies:
cmake
libqd-dev http://crd.lbl.gov/~dhbailey/mpdist
Boost graph library
graphviz (visualization for graph algorithms)

Optional Dependencies:
git (required only for the version-string)
python (if python bindings are built/used)
Boost python (if python bindings are built)
doxygen (for building documentation)
asymptote (to build white-paper figures)
lyx (to build white-paper)
libvtk (many python-scripts use VTK for visualization)
python-vtk (VTK python bindings)
truetype-tracer aewallin/truetype-tracer (some tests)
randompolygon aewallin/randompolygon (some tests)

Build/Install instructions: https://github.com/aewallin/openvoronoi … structions

loqs

Member

Registered: 2014-03-06

Posts: 17,304

Re: [REQUEST] openvoronoi - 2D voronoi diagram

First iteration a PKGBUILD python support requires python2 which will is EOL at the end of the year so disabled.
Patch applied for gcc warnings as project uses Werror.

# This is an example PKGBUILD file. Use this as a start to creating your own,
# and remove these comments. For more information, see 'man PKGBUILD'.
# NOTE: Please fill out the license field for your package! If it is unknown,
# then please put 'unknown'.

# Maintainer: Your Name <youremail@domain.com>
pkgname=openvoronoi
pkgver=2018.08
pkgrel=1
pkgdesc="2D voronoi diagram for point and line-segment sites using incremental topology-oriented algorithm"
arch=('x86_64')
url="http://www.anderswallin.net/cam/"
license=('LGPL')
depends=('qd')
makedepends=('cmake' 'boost')
source=("$pkgname-$pkgver.tar.gz::https://github.com/aewallin/$pkgname/archive/$pkgver.tar.gz"
        "https://github.com/aewallin/$pkgname/commit/92106b5f4a5f76927095e61311b3f8fdedb84787.patch")
sha256sums=('ff2024dd24147ff17511f54d4872c185040daeabda311bba94b76ed0cafe5984'
            '56844f951415ff8ff07d9f58e42bfee26eb86288c30d55dae81879eb6e18356a')

prepare() {
	cd "$pkgname-$pkgver"
	patch -p1 -i "$srcdir/92106b5f4a5f76927095e61311b3f8fdedb84787.patch"
}

build() {
	cd "$pkgname-$pkgver"
	mkdir -p build
	cd build
	cmake -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_PYTHON_MODULE=OFF ../src
	make
}

package() {
	cd "$pkgname-$pkgver/build"
	make DESTDIR="$pkgdir/" install
}