[SOLVED] Postman failed to build, where do I copy the files?

BradLivingstone · 2020-06-17 19:01:01

The recent build of postman is failing.

Found this which helped me build postman successfully

https://www.youtube.com/watch?v=ofTvg8e … e=youtu.be

however postman does not show up in rofi and if I try to run it manually from .cache/yay/postman it says "Unable to find Electron app at /usr/share/postman/app"

what files do I need to copy where to get this to work properly.

Thank You

Last edited by BradLivingstone (2020-06-17 19:47:30)

Trilby · 2020-06-17 19:09:58

That fix is no longer relevant. The AUR PKGBUILD was updated 3 days ago. It's also silly to link to a long youtube video to say you commented out the license file and checksum. Help us help you - just say what you did and/or post your modified PKGBUILD.

As for your other problems, it sounds like you didn't install the built package. Please post the output of `pacman -Qs postman`.

EDIT: it does seem the checksum is wrong again though - perhaps the EULA is being modified upstream ... actually I just checked it, that html file does not even contain the EULA. The program runs just fine though.

Last edited by Trilby (2020-06-17 19:15:49)

BradLivingstone · 2020-06-17 19:24:36

PKGBUILD

# Maintainer: Bruce Zhang
pkgname=postman
pkgver=7.26.0
pkgrel=3
pkgdesc='Build, test, and document your APIs faster'
arch=('x86_64')
url='https://www.getpostman.com/downloads/'
license=('custom:Postman EULA')
depends=('electron7')
provides=('postman')
conflicts=('postman-bin')
options=('!strip')
source_x86_64=(
  "$pkgname-$pkgver-x86_64.orig.tar.gz::https://dl.pstmn.io/download/version/$pkgver/linux64"
)
source=(
  "EULA.html::https://www.postman.com/licenses/postman-eula/"
  "postman.desktop"
  "postman.sh"
)
sha1sums=('e536f2e43c417bdd88087cf98af30a5092fc36f0'
          '35194ee810e13d3a21f224c6d46104fc201631c1'
          '7c00d44372bea7447ee8ef2acb03dcbdd3a9a279')
sha1sums_x86_64=('1832e4dd949ab452807e5d97d7933a914582b92f')

package() {
  cd "$srcdir/Postman/app/resources/app"

  # Install Postman app resource
  find . -type f -exec install -Dm644 {} "$pkgdir/usr/share/postman/app/{}" \;

  # Install bin
  install -Dm755 "$srcdir/postman.sh" "$pkgdir/usr/bin/postman"

  # Install desktop
  install -Dm755 "$srcdir/postman.desktop" "$pkgdir/usr/share/applications/postman.desktop"

  # Install icons & eula
  install -Dm644 "$srcdir/Postman/app/resources/app/assets/icon.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/postman.png"
  install -Dm644 "$srcdir/EULA.html" "$pkgdir/usr/share/licenses/postman/EULA.html"
}

pacman -Qs postman
local/pacman 5.2.1-6 (base-devel)
    A library-based package manager with dependency support
local/pacman-mirrorlist 20200411-1
    Arch Linux mirror list for use by pacman
local/yay 9.4.7-1
    Yet another yogurt. Pacman wrapper and AUR helper written in go.

Last edited by BradLivingstone (2020-06-17 19:27:51)

Trilby · 2020-06-17 19:30:16

As pacman shows, you have not installed postman. That's why rofi can't launch it.

FYI, this PKGBUILD has the (currently) proper EULA source and checksums along with some other cleanup:

pkgname=postman
pkgver=7.26.0
pkgrel=4
pkgdesc='Build, test, and document your APIs faster'
arch=('x86_64')
url='https://www.getpostman.com/downloads/'
license=('custom:Postman EULA')
depends=('electron7')
provides=('postman')
conflicts=('postman-bin')
options=('!strip')
source=(
  "$pkgname-$pkgver-x86_64.orig.tar.gz::https://dl.pstmn.io/download/version/$pkgver/linux64"
  "EULA.html::https://www.postman.com/legal/eula/"
  "postman.desktop"
  "postman.sh"
)
sha1sums=(
  '1832e4dd949ab452807e5d97d7933a914582b92f'
  '4ccd0ca153ea708196b6570fee9943a23c574f9c'
  '35194ee810e13d3a21f224c6d46104fc201631c1'
  '7c00d44372bea7447ee8ef2acb03dcbdd3a9a279'
)

package() {
  find . -type f -exec install -Dm644 {} "$pkgdir/usr/share/postman/app/{}" \;
  install -Dm755 postman.sh "$pkgdir/usr/bin/postman"
  install -Dm755 postman.desktop "$pkgdir/usr/share/applications/postman.desktop"
  install -Dm644 Postman/app/resources/app/assets/icon.png "$pkgdir/usr/share/icons/hicolor/128x128/apps/postman.png"
  install -Dm644 EULA.html "$pkgdir/usr/share/licenses/postman/EULA.html"
}

EDIT: but this package should not exist as it doesn't build anything (I just realized this, sorry it took so long). Use postman-bin

Last edited by Trilby (2020-06-17 19:43:42)

BradLivingstone · 2020-06-17 19:35:06

That did not help. I deleted the cached version. Re-downloaded postman(The EULA failed validity check). Replaced the PKGBUILD with the one you sent and now all of the files fail the validity check.

 ==> Making package: postman 7.26.0-4 (Wed 17 Jun 2020 12:33:27 PM PDT)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
  -> Found postman-7.26.0-x86_64.orig.tar.gz
  -> Found EULA.html
  -> Found postman.desktop
  -> Found postman.sh
==> Validating source files with sha1sums...
    postman-7.26.0-x86_64.orig.tar.gz ... FAILED
    EULA.html ... FAILED
    postman.desktop ... FAILED
    postman.sh ... FAILED
==> ERROR: One or more files did not pass the validity check!

Last edited by BradLivingstone (2020-06-17 19:35:59)

Trilby · 2020-06-17 19:46:05

Sorry I mixed up the checksums when I consolodated the multiple arrays. I also was overzealous in streamlining the package function not realizing that install wasn't recursive. I fixed both issues. It now works.

But the main point was already at the end of my last post: don't use this package. There is a pending request already in the AUR, likely for it's deletion. Use the postman-bin package.

eschwartz · 2020-06-18 00:43:17

It's proprietary software, no sources exist. Why does it need to be named -bin?

loqs · 2020-06-18 00:54:12

It already exists as postman-bin as well as postman? That appears to be unnecessary duplication.

eschwartz · 2020-06-18 01:01:19

And which one should be the preferred name? Do you think users care that it is a -bin package when they install it the only way they can?

When we repackage proprietary software in [community] (after obtaining distribution permission) do we name e.g. discord, teamspeak with -bin suffixes?

Trilby · 2020-06-18 01:23:42

The -bin package predated the other by 2 years. I think being both the first one submitted, and potentially less broken are two criteria in favor of the postman-bin PKGBUILD while the postman PKGBUILD was a duplicate and is failing to build. Whether the original postman-bin should be renamed is a different question.

eschwartz · 2020-06-18 01:39:33

That's a reasonable argument to make -- better than "but this package should not exist as it doesn't build anything". I haven't accepted the deletion request or filed one for postman-bin, because I'm not sure what the solution is.

The postman package uses a broken EULA download, while the postman-bin package circumvents this by not shipping the license at all (though it does redistribute the electron license as "LICENSE" which is stupendously misleading).

Trilby · 2020-06-18 01:56:51

Email both maintainers and make it a race for a functional and compliant PKGBUILD. Whoever submits one first gets to keep their package in the AUR

Arch Linux

#1 2020-06-17 19:01:01

[SOLVED] Postman failed to build, where do I copy the files?

#2 2020-06-17 19:09:58

Re: [SOLVED] Postman failed to build, where do I copy the files?

#3 2020-06-17 19:24:36

Re: [SOLVED] Postman failed to build, where do I copy the files?

#4 2020-06-17 19:30:16

Re: [SOLVED] Postman failed to build, where do I copy the files?

#5 2020-06-17 19:35:06

Re: [SOLVED] Postman failed to build, where do I copy the files?

#6 2020-06-17 19:46:05

Re: [SOLVED] Postman failed to build, where do I copy the files?

#7 2020-06-18 00:43:17

Re: [SOLVED] Postman failed to build, where do I copy the files?

#8 2020-06-18 00:54:12

Re: [SOLVED] Postman failed to build, where do I copy the files?

#9 2020-06-18 01:01:19

Re: [SOLVED] Postman failed to build, where do I copy the files?

#10 2020-06-18 01:23:42

Re: [SOLVED] Postman failed to build, where do I copy the files?

#11 2020-06-18 01:39:33

Re: [SOLVED] Postman failed to build, where do I copy the files?

#12 2020-06-18 01:56:51

Re: [SOLVED] Postman failed to build, where do I copy the files?

Board footer