Deletion request response for Radegast-git

fennectech · 2020-07-11 23:52:23

katt [1] filed a deletion request for radegast-git [2]:

Absolute mess of a package, maintainer decided to rename their -git
package to -ng while switching to releases, all while avoiding
.SRCINFO to presumable avoid git stopping their madness dead in its
tracks.
This is backed up by them actually submitting a separate .SRCINFO with
just an upped pkgrel.

Call the exorcist!

[1] https://aur.archlinux.org/account/katt/
[2] https://aur.archlinux.org/pkgbase/radegast-git/

This is a reply to this message.

My package is the git from the classic fork that was superseded by Radegast-ng. (Which is releases from the updated version)
Some time ago the founder of Radegast passed and the original repository was left. Radegast-NG is a fork of the codebase this package installs. I would like to keep this package around a while longer as some still do use the original version. Today’s mistake was the result of me pushing to the wrong repository. Please do not delete my package. I’m still learning git.

Trilby · 2020-07-11 23:57:17

This should go to to the AUR mailing list.

But even your other package is a mess. What the hell is "cd ../src/bin". That also justifies a call for an excorcist. There is no such directory and this PKGBUILD will just immediately fail. Did you test it before submitting?

Last edited by Trilby (2020-07-12 00:02:51)

loqs · 2020-07-12 00:05:01

It was a -git package that did not have the git repository in the source array https://aur.archlinux.org/cgit/aur.git/ … 889ba0978c
Now it is a -git package that packages a pre built binary https://aur.archlinux.org/cgit/aur.git/ … dc57aad8dc

WorMzy · 2020-07-12 00:14:15

As noted, you should post this information on the mailing list thread, the Trusted User who handles the request will be more likely to see it there.

fennectech · 2020-07-12 00:45:45

I see what happened. I got content mixed up Between the repos. This is totally borked. Bleh Thanks for reminding me. I was doing this messing about late at night without my brain turned on

EDIT. Ive resolved the issues and the package now works!

Last edited by fennectech (2020-07-12 00:54:20)

fennectech · 2020-07-12 01:01:26

I’m going to sort out Radegast-ng as well. It looks like something changed without me noticing.

Edit. Ive now fixed Radegast-NG as well.

Last edited by fennectech (2020-07-12 01:11:36)

Trilby · 2020-07-12 01:04:54

Sorry, your last push didn't make any changes:
https://aur.archlinux.org/cgit/aur.git/ … a76c2a3d3c

I'm surprised this worked, I didn't know git allowed empty commits.

Last edited by Trilby (2020-07-12 01:05:44)

loqs · 2020-07-12 01:05:29

radegast-git still looks to have the PKGBUILD for radegest-ng https://aur.archlinux.org/cgit/aur.git/ … a76c2a3d3c

fennectech · 2020-07-12 01:14:10

Dafuq. I reverted Radegast-git to previous state. AHHHHH.

loqs · 2020-07-12 01:18:14

You want to revert 95e73abbc6404f93cc4501db670823dc57aad8dc for radegest-git then update .SRCINFO

fennectech · 2020-07-12 01:20:28

Thank you verry much. Radegast-NG got its directory renamed without me noticing. So. As bolth are right now all looks good. NG is on the current release and git is back where it always should have been after this nightmarish day. I think ive averted the exorcist crisis.

Last edited by fennectech (2020-07-12 01:23:46)

loqs · 2020-07-12 01:32:13

Please fix the source array to contain the git repository add git to the makedepends and openssl-1.0 for premake5 also a pkgver function.
Edit:

# Maintainer: FennecTECH <fennectech@gmail.com>
# Based uppon the script for radegast written by Mike Swanson <mikeonthecomputer@gmail.com>
pkgname=radegast-git
pkgver=2.18.r125.g6ae2c835
pkgrel=1
pkgdesc="Lightweight client for connecting to Second Life and OpenSim worlds"
arch=('i686' 'x86_64')
url="http://radegast.org"
license=('BSD')
depends=('mono')
conflicts=('radegast')
provides=('radegast')
makedepends=('dos2unix' 'recode' 'git' 'openssl-1.0')
source=("$pkgname::git+https://github.com/radegastdev/radegast.git"
        git+https://github.com/openmetaversefoundation/libopenmetaverse.git
        radegast.desktop
        radegast)
sha256sums=('SKIP'
            'SKIP'
            '8f599f04f263361cd45f7af53cfae633881bfa92ba3f806a0ca675d1ee131567'
            '73cdc80cc4abeb6ba368b09285ff5120ffeb6052a0a5e5ac0febf08c38bb0e96')

prepare() {
  cd $pkgname
  git submodule init
  git config submodule.libopenmetaverse.url "$srcdir"/libopenmetaverse
  git submodule update
}

pkgver() {
  cd $pkgname
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $pkgname
  find .. -name \*.sh -exec dos2unix '{}' \;
  bash runprebuild.sh
  xbuild Radegast.sln
}

package() {
  cd $pkgname/bin
  find . -type d -print0 | xargs -0 chmod 755
  find . -type f -print0 | xargs -0 chmod 644
  install -dm755 "${pkgdir}"/usr/share/Radegast
  cp -a -- * "${pkgdir}"/usr/share/Radegast
  install -Dm644 ../Radegast/radegast.png "${pkgdir}"/usr/share/icons/radegast.png
  install -Dm644 "${srcdir}"/radegast.desktop "${pkgdir}"/usr/share/applications/radegast.desktop
  install -Dm755 "${srcdir}"/radegast "${pkgdir}"/usr/bin/radegast

  install -dm755 "${pkgdir}"/usr/share/licenses/radegast
  recode windows-1252..utf8 < ../LICENSE.txt > "${pkgdir}"/usr/share/licenses/radegast/COPYING
}

# vim:set ts=2 sw=2 et:

Last edited by loqs (2020-07-12 01:51:35)

fennectech · 2020-07-12 01:58:47

Done, Testing on my server before pushing.

fennectech · 2020-07-12 02:01:11

Yup. Works here. Didn’t update .SRCINFO because it doesnt seem necessary for this

Trilby · 2020-07-12 02:05:23

Yes it is necessary.

loqs · 2020-07-12 02:19:43

The change in pkgver could be ignored as it is a git package but the dependency changes need to be reflected in .SRCINFO.

fennectech · 2020-07-12 02:47:14

Thanks Ive bumped packagerel as per your suggestion

Trilby · 2020-07-12 11:38:34

You actually didn't need to bump the pkgrel. It's fine as is for now, but next time you make any changes and are going to re-upload this to the AUR, reset the pkgrel back to 1. Pkgrel is meant to be incremented whenever there are changes that are not reflected by an increase in pkgver. As your last upload increased pkgver, pkgrel could have been reset to 1. And now that you have a proper pkgver function, every time you prepare this for upload it will have a higher pkgver (so pkgrel can almost alwasy be 1 from now on).

fennectech · 2020-07-12 17:01:44

Trilby wrote:

You actually didn't need to bump the pkgrel. It's fine as is for now, but next time you make any changes and are going to re-upload this to the AUR, reset the pkgrel back to 1. Pkgrel is meant to be incremented whenever there are changes that are not reflected by an increase in pkgver. As your last upload increased pkgver, pkgrel could have been reset to 1. And now that you have a proper pkgver function, every time you prepare this for upload it will have a higher pkgver (so pkgrel can almost alwasy be 1 from now on).

Thank you! Ill tuck that info away and follow it next time i update things

Arch Linux

#1 2020-07-11 23:52:23

Deletion request response for Radegast-git

#2 2020-07-11 23:57:17

Re: Deletion request response for Radegast-git

#3 2020-07-12 00:05:01

Re: Deletion request response for Radegast-git

#4 2020-07-12 00:14:15

Re: Deletion request response for Radegast-git

#5 2020-07-12 00:45:45

Re: Deletion request response for Radegast-git

#6 2020-07-12 01:01:26

Re: Deletion request response for Radegast-git

#7 2020-07-12 01:04:54

Re: Deletion request response for Radegast-git

#8 2020-07-12 01:05:29

Re: Deletion request response for Radegast-git

#9 2020-07-12 01:14:10

Re: Deletion request response for Radegast-git

#10 2020-07-12 01:18:14

Re: Deletion request response for Radegast-git

#11 2020-07-12 01:20:28

Re: Deletion request response for Radegast-git

#12 2020-07-12 01:32:13

Re: Deletion request response for Radegast-git

#13 2020-07-12 01:58:47

Re: Deletion request response for Radegast-git

#14 2020-07-12 02:01:11

Re: Deletion request response for Radegast-git

#15 2020-07-12 02:05:23

Re: Deletion request response for Radegast-git

#16 2020-07-12 02:19:43

Re: Deletion request response for Radegast-git

#17 2020-07-12 02:47:14

Re: Deletion request response for Radegast-git

#18 2020-07-12 11:38:34

Re: Deletion request response for Radegast-git

#19 2020-07-12 17:01:44

Re: Deletion request response for Radegast-git

Board footer