You are not logged in.

#1 2020-07-13 10:51:58

capoeira
Member
From: Vila Velha - Brasil
Registered: 2010-05-25
Posts: 470

bup has been removed, but kup requires it for incremental backups

Offline

#2 2020-07-13 11:47:23

Buddlespit
Member
From: Chesapeake, Va.
Registered: 2014-02-07
Posts: 501

Re: bup has been removed, but kup requires it for incremental backups

It appears to be a python2 issue. Two python2 files (python2-fuse & python2-pyxattr) have been removed, which broke bup(-git), probably until the developer updates bup to python version 3. We'll have to wait until then and use rsync (synchronized Backup) until then. The developer is using Debian, which means we may not see anything fixed or updated until Debian catches up with python.

Offline

#3 2020-07-13 12:46:52

arojas
Developer
From: Spain
Registered: 2011-10-09
Posts: 2,093

Re: bup has been removed, but kup requires it for incremental backups

You can always get it from AUR

Offline

#4 2020-07-13 13:03:12

capoeira
Member
From: Vila Velha - Brasil
Registered: 2010-05-25
Posts: 470

Re: bup has been removed, but kup requires it for incremental backups

Buddlespit wrote:

It appears to be a python2 issue. Two python2 files (python2-fuse & python2-pyxattr) have been removed, which broke bup(-git), probably until the developer updates bup to python version 3. We'll have to wait until then and use rsync (synchronized Backup) until then. The developer is using Debian, which means we may not see anything fixed or updated until Debian catches up with python.

thanks

arojas wrote:

You can always get it from AUR

It needs the two python files, too

Offline

#5 2020-07-13 18:49:55

loqs
Member
Registered: 2014-03-06
Posts: 17,196

Re: bup has been removed, but kup requires it for incremental backups

capoeira wrote:

It needs the two python files, too

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: Alexander Fehr <pizzapunk@gmail.com>

pkgname=python2-fuse
pkgver=1.0.0
pkgrel=1
pkgdesc="Python bindings for FUSE"
arch=('x86_64')
url="https://github.com/libfuse/python-fuse"
license=('LGPL')
depends=('fuse2' 'python2')
makedepends=('python2-setuptools')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/libfuse/python-fuse/archive/v$pkgver.tar.gz")
sha512sums=('d5e91be3e43065988053390d97ca6483ce38924bf9a49f694bf911080b7e75c836224e83d09dcbc6fab8d63781b4cd3ae016d66b65b88dd53106b06f91a6ad5c')

build() {
  cd python-fuse-$pkgver
  python2 setup.py build
}

package() {
  cd python-fuse-$pkgver
  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
}
# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Jon Bergli Heier <snakebite@jvnv.net>

pkgname='python2-pyxattr'
_pkgname=pyxattr
pkgver=0.6.1
pkgrel=2
pkgdesc='A python extension module that allows you to manipulate the extended attributes.'
arch=('x86_64')
url='https://pyxattr.k1024.org/'
license=('GPL')
depends=('python2')
makedepends=('python2-setuptools')
provides=('pyxattr')
conflicts=('pyxattr')
replaces=('pyxattr')
source=("https://pyxattr.k1024.org/downloads/pyxattr-$pkgver.tar.gz"{,.asc})
md5sums=('523e9d90f9801141c785d93e6197cc33'
         'SKIP')
validpgpkeys=('CB94E3AA3B1755D61EBB19A5F66E3E419F84F4DE') # Iustin Pop <iustin@k1024.org>

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py build
}

check() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py test
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py install --root="${pkgdir}"
}

Last edited by loqs (2020-07-13 19:10:38)

Offline

#6 2020-07-13 19:01:28

Buddlespit
Member
From: Chesapeake, Va.
Registered: 2014-02-07
Posts: 501

Re: bup has been removed, but kup requires it for incremental backups

I don't care what they say about you, loqs, you're da man!

Offline

#7 2020-07-13 22:30:14

capoeira
Member
From: Vila Velha - Brasil
Registered: 2010-05-25
Posts: 470

Re: bup has been removed, but kup requires it for incremental backups

loqs wrote:
capoeira wrote:

It needs the two python files, too

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: Alexander Fehr <pizzapunk@gmail.com>

pkgname=python2-fuse
pkgver=1.0.0
pkgrel=1
pkgdesc="Python bindings for FUSE"
arch=('x86_64')
url="https://github.com/libfuse/python-fuse"
license=('LGPL')
depends=('fuse2' 'python2')
makedepends=('python2-setuptools')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/libfuse/python-fuse/archive/v$pkgver.tar.gz")
sha512sums=('d5e91be3e43065988053390d97ca6483ce38924bf9a49f694bf911080b7e75c836224e83d09dcbc6fab8d63781b4cd3ae016d66b65b88dd53106b06f91a6ad5c')

build() {
  cd python-fuse-$pkgver
  python2 setup.py build
}

package() {
  cd python-fuse-$pkgver
  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
}
# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Jon Bergli Heier <snakebite@jvnv.net>

pkgname='python2-pyxattr'
_pkgname=pyxattr
pkgver=0.6.1
pkgrel=2
pkgdesc='A python extension module that allows you to manipulate the extended attributes.'
arch=('x86_64')
url='https://pyxattr.k1024.org/'
license=('GPL')
depends=('python2')
makedepends=('python2-setuptools')
provides=('pyxattr')
conflicts=('pyxattr')
replaces=('pyxattr')
source=("https://pyxattr.k1024.org/downloads/pyxattr-$pkgver.tar.gz"{,.asc})
md5sums=('523e9d90f9801141c785d93e6197cc33'
         'SKIP')
validpgpkeys=('CB94E3AA3B1755D61EBB19A5F66E3E419F84F4DE') # Iustin Pop <iustin@k1024.org>

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py build
}

check() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py test
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python2 setup.py install --root="${pkgdir}"
}

thanks a lot man :-)

I wonder why bup needs 126 packages.

Offline

Board footer

Powered by FluxBB