You are not logged in.

#1 2020-08-15 22:22:55

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

PKGBUILD review request: SoulAnchor v0.9

I've got it open source now and have a new PKGBUILD. I'm pretty confident it works alright and have placed it on the AUR.
BUT since i'm new at this please check it out. I welcome all comments from all you smart Archers!

# Maintainer: Anchorman <soulanchor at protonmail dot com>
pkgname=soulanchor
pkgver=0.9.0
pkgrel=1
pkgdesc="X11 Bible tool"
arch=('x86_64')
url="https://github.com/Anchorm/SoulAnchor"
license=('GPL3')
depends=(qt5-base qt5-multimedia)
source=("https://github.com/Anchorm/SoulAnchor/archive/$pkgname-$pkgver.tar.gz")
sha256sums=("8f16d8a9c9e4ce70bdbd0d68c08f0a9116ebea74cf7b874a83678d6301f5001a")
Name=SoulAnchor

build() {
    cd "SoulAnchor-$pkgname-$pkgver"
    qmake
    make -j$(nproc)
}

package() {
	cd "SoulAnchor-$pkgname-$pkgver/install"
	cp -a --no-preserve=ownership usr/ "$pkgdir/"
	install -Dm644 ../README.md "$pkgdir/usr/share/doc/soulanchor/README.md"
	install -Dm644 ../LICENSE "$pkgdir/usr/share/doc/soulanchor/LICENSE"
	install -Dm644 ../COPYING "$pkgdir/usr/share/doc/soulanchor/COPYING"
	install -Dm644 ../MOD "$pkgdir/usr/share/doc/soulanchor/MOD"
}

Offline

#2 2020-08-15 23:33:34

Slithery
Administrator
From: Norfolk, UK
Registered: 2013-12-01
Posts: 5,776

Re: PKGBUILD review request: SoulAnchor v0.9

Anchorman wrote:
Name=SoulAnchor

What's that meant to do? You haven't used it anywhere else in the PKGBUILD.

Anchorman wrote:
    make -j$(nproc)

Don't do this. It's up to the individual user to set this in their makepkg.conf if they wish.


No, it didn't "fix" anything. It just shifted the brokeness one space to the right. - jasonwryan
Closing -- for deletion; Banning -- for muppetry. - jasonwryan

aur - dotfiles

Offline

#3 2020-08-15 23:44:50

Scimmia
Fellow
Registered: 2012-09-01
Posts: 11,466

Re: PKGBUILD review request: SoulAnchor v0.9

Do NOT use -j$(nproc). Users set their own makeflags in makepkg.conf

Why are you installing another copy of the GPL when there's already one on the system?

Offline

#4 2020-08-16 09:55:55

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

Re: PKGBUILD review request: SoulAnchor v0.9

Slithery wrote:

What's that meant to do? You haven't used it anywhere else in the PKGBUILD.

Well that is proof that i stared too long at the screen without taking breaks...

Scimmia wrote:

Why are you installing another copy of the GPL when there's already one on the system?

Hehe yeah i guess one is enough.


About the make -j, i will remove it but for my understanding, can it cause problems?

Offline

#5 2020-08-16 23:31:41

eschwartz
Fellow
Registered: 2014-08-08
Posts: 4,097

Re: PKGBUILD review request: SoulAnchor v0.9

It overrides the user's explicit makepkg.conf setting and instead tells Make to voraciously consume all computing power it can until the package is done. Maybe people like to build packages in one backgrounded terminal window while watching cat videos in their browser. wink


Managing AUR repos The Right Way -- aurpublish (now a standalone tool)

Offline

#6 2020-08-17 07:23:35

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

Re: PKGBUILD review request: SoulAnchor v0.9

Makes sense, i had not considered the cat and dog videos wink

Offline

#7 2020-08-17 21:45:03

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

Re: PKGBUILD review request: SoulAnchor v0.9

Alright folks, thanks for all the comments. The new PKGBUILD is now:

# Maintainer: Anchorman <soulanchor at protonmail dot com>
pkgname=soulanchor
pkgver=0.9.0
pkgrel=1
pkgdesc="X11 Bible tool"
arch=('x86_64')
url="https://github.com/Anchorm/SoulAnchor"
license=('GPL3')
depends=(qt5-base qt5-multimedia)
source=("https://github.com/Anchorm/SoulAnchor/archive/$pkgname-$pkgver.tar.gz")
sha256sums=("8f16d8a9c9e4ce70bdbd0d68c08f0a9116ebea74cf7b874a83678d6301f5001a")

build() {
    cd "SoulAnchor-$pkgname-$pkgver"
    qmake
    make
}

package() {
	cd "SoulAnchor-$pkgname-$pkgver"
	cp -a --no-preserve=ownership install/usr/ "$pkgdir/"
	install -Dm644 -t "$pkgdir/usr/share/doc/soulanchor/" MOD README.md
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/soulanchor/LICENSE"
}

Offline

#8 2020-08-18 00:41:46

eschwartz
Fellow
Registered: 2014-08-08
Posts: 4,097

Re: PKGBUILD review request: SoulAnchor v0.9

cp -a --no-preserve=ownership

could be cp -r, since -a adds "ownership" among other things you don't actually need in 99% of cases.


Managing AUR repos The Right Way -- aurpublish (now a standalone tool)

Offline

#9 2020-08-18 11:00:52

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

Re: PKGBUILD review request: SoulAnchor v0.9

But is there a scenario possible where file permissions can get messed up?

Offline

#10 2020-08-19 17:51:52

Anchorman
Member
Registered: 2020-07-26
Posts: 49
Website

Re: PKGBUILD review request: SoulAnchor v0.9

Well it's probably not ever going to be a problem, i see cp -r  in make install instructions as well, so i'm just going to use that from now on.

On a side note, if a mod happens to read this, i  probably should have used the existing thread instead of creating a new one, is it possible to merge the threads?

Offline

Board footer

Powered by FluxBB