You are not logged in.

#1 2020-09-28 14:17:29

kassane
Member
From: Brazil
Registered: 2020-03-28
Posts: 3
Website

PKGBUILD: Review Request: ExpressCpp

Hello everybody!

I would like to suggest the adhesion of this package that facilitates the possibility of developing remaining and related servers in nodejs style with express using modern c++.

PKGBUILD:

# Maintainer:  Matheus Catarino <matheus-catarino@hotmail.com>

pkgname=expresscpp
pkgver=0.20.0
pkgrel=1
pkgdesc='Fast, unopinionated, minimalist web framework for C++ Perfect for building REST APIs.'
arch=('x86_64')
url='https://github.com/expresscpp/expresscpp'
license=('MIT')
depends=(fmt nlohmann-json boost)
makedepends=(cmake)
source=("expresscpp-${pkgver}.tar.gz::https://github.com/expresscpp/expresscpp/archive/v${pkgver}.tar.gz")
sha512sums=('afe554f01d8f43253a23daea086e9b67d9593b057534929e18ead99da5e41cb826374cf8c67b3df8c25e78aa6966fdb3afa0659482f96da67cec460882aa5461')

prepare() {
  cd "$pkgname-$pkgver"
}

build() {
  cmake  \
    -B build \
    -DBUILD_SHARED_LIBS=ON \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    "$srcdir/$pkgname-$pkgver"

  cmake --build build
}

package() {
  cd build
   make install DESTDIR="${pkgdir}"
   install -Dm 644 "$srcdir/$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}

Last edited by kassane (2020-09-28 15:43:16)

Offline

#2 2020-09-28 14:34:03

loqs
Member
Registered: 2014-03-06
Posts: 11,917

Re: PKGBUILD: Review Request: ExpressCpp

MIT is a special case license please see PKGBUILD#license.

depends=(fmt nlohmann-json boost)
makedepends=(cmake ninja boost-libs gcc)

gcc is in base-devel so does not need to be included in makedepends.  boost-libs will be pulled in by boost.  Normally the makedepends would be boost and the depends boost-libs so boost does not have to be present at runtime.

If you pass -B build to cmake you can drop the prepare function.

Offline

#3 2020-09-28 15:03:56

kassane
Member
From: Brazil
Registered: 2020-03-28
Posts: 3
Website

Re: PKGBUILD: Review Request: ExpressCpp

loqs wrote:

MIT is a special case license please see PKGBUILD#license.

depends=(fmt nlohmann-json boost)
makedepends=(cmake ninja boost-libs gcc)

gcc is in base-devel so does not need to be included in makedepends.  boost-libs will be pulled in by boost.  Normally the makedepends would be boost and the depends boost-libs so boost does not have to be present at runtime.

If you pass -B build to cmake you can drop the prepare function.

Ok! changed.

Offline

#4 2020-09-28 15:29:33

loqs
Member
Registered: 2014-03-06
Posts: 11,917

Re: PKGBUILD: Review Request: ExpressCpp

license=('GPL' "custom:MIT")

Was fine as

license=('MIT')

You need to install the LICENSE file in "$pkgdir/usr/share/licenses/$pkgname/"

The prepare function now being empty can be dropped.

Offline

#5 2020-09-28 15:43:39

kassane
Member
From: Brazil
Registered: 2020-03-28
Posts: 3
Website

Re: PKGBUILD: Review Request: ExpressCpp

loqs wrote:
license=('GPL' "custom:MIT")

Was fine as

license=('MIT')

You need to install the LICENSE file in "$pkgdir/usr/share/licenses/$pkgname/"

The prepare function now being empty can be dropped.

Changed!

Offline

Board footer

Powered by FluxBB