Arch Linux

archnoon

Member

Registered: 2020-05-06

Posts: 6

[Solved] How to get the newest version of the package "hostname"?

Normally I wouldn't ask but with a name like this, no search in any search engine proved useful...
If I execute hostname -V it returns
hostname (GNU inetutils) 1.9.4
which is from 2015 which is... old. So old that I cannot in fact execute hostname -I because it is an invalid option.

So my question is, how do I upgrade this package (or replace it by something new which does the same)?

Last edited by archnoon (2020-12-28 09:35:19)

loqs

Member

Registered: 2014-03-06

Posts: 19,027

Re: [Solved] How to get the newest version of the package "hostname"?

No version of hostname as supplied by inetutils supports the -l option that I am aware of.  Build the Debian hostname package which does support it or use something such as ip a.
Edit:

pkgname=hostname
pkgver=3.23
pkgrel=1
pkgdesc="utility to set/show the host name or domain name"
arch=('x86_64')
url="https://tracker.debian.org/pkg/hostname"
license=('GPL')
depends=('glibc')
conflicts=('inetutils')
source=("http://deb.debian.org/debian/pool/main/h/$pkgname/${pkgname}_${pkgver}.tar.gz"
        'manpage.diff')
sha256sums=('bc6d1954b22849869ff8b2a602e39f08b1702f686d4b58dd7927cdeb5b4876ef'
            '7e86e5aafa3b42b6a4ec866c8720929f6bdfdd922389f957b4639b698707a53e')

prepare() {
  cd $pkgname
  patch -p1 -i ../manpage.diff
}

build() {
  cd $pkgname
  make
}

package() {
  cd $pkgname
  make BASEDIR="$pkgdir" BINDIR=/usr/bin install
}

diff --git a/hostname.1 b/hostname.1
index 346c40b..8ba367b 100644
--- a/hostname.1
+++ b/hostname.1
@@ -105,8 +105,7 @@ command (see
 .B THE FQDN
 below).
 .LP
-The host name is usually set once at system startup in
-.I /etc/init.d/hostname.sh
+The host name is usually set once at system startup
 (normally by reading the contents of a file which contains
 the host name, e.g.
 .IR /etc/hostname ).

Last edited by loqs (2020-12-27 18:42:00)