Arch Linux

n8jadams

Member

Registered: 2021-08-23

Posts: 49

[SOLVED] Two versions of Dolphin emulator?

I have two versions of dolphin-emu I want to run, the official one from pacman and this one: https://aur.archlinux.org/packages/dolp … ehack-git/

When building the primehack version I get a bunch of errors about files that apparently belong to dolphin-emu and the install fails.

How could I get this to work?

Last edited by n8jadams (2021-08-26 01:44:30)

Ammako

Member

Registered: 2021-07-16

Posts: 267

Re: [SOLVED] Two versions of Dolphin emulator?

It sounds like the package conflicts, and they should probably update their package to properly mark it as conflicting with dolphin-emu. You could probably edit the pkgbuild to point -DCMAKE_INSTALL_PREFIX to somewhere else other than /usr, maybe /opt would be viable. Also remove the line from package() about the udev rule, because you'll already have that file there from the official dolphin-emu package.

# Maintainer: Nick Lay <layns(at)mail(dot)uc(dot)edu>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Lightning <sgsdxzy@gmail.com>

# Based on the dolphin-emu-git PKGBUILD with modifications

_mainpkgname="dolphin-emu"
pkgname=("$_mainpkgname-primehack-git")
pkgver=1.0.4.r951.ge353752b6d
pkgrel=1
pkgdesc='Dolphin fork intended to give Metroid Prime Trilogy mouselook controls'
arch=('x86_64')
url="https://dolphin-emu.org"
license=('GPL2')
depends=(
	'alsa-lib' 'bluez-libs' 'enet' 'hidapi' 'libevdev' 'libgl' 'libpng'
	'libpulse' 'libx11' 'libxi' 'libxrandr' 'lzo' 'mbedtls' 'pugixml' 'qt5-base'
	'sfml' 'zlib'
	'libavcodec.so' 'libavformat.so' 'libavutil.so' 'libcurl.so'
	'libminiupnpc.so' 'libswscale.so' 'libudev.so' 'libusb-1.0.so'
)
makedepends=('cmake' 'git' 'python')
optdepends=('pulseaudio: PulseAudio backend')
source=("dolphin::git+https://github.com/shiiion/dolphin.git")
sha256sums=('SKIP')

_sourcedirectory="dolphin"

prepare() {
	cd "$srcdir/$_sourcedirectory/"
	git submodule update --init
	if [ -d 'build/' ]; then rm -rf 'build/'; fi
	mkdir 'build/'
}

pkgver() {
	cd "$srcdir/$_sourcedirectory/"
	git describe --long --tags | sed -e 's/-\([^-]*-g[^-]*\)$/-r\1/' -e 's/-/./g'
}

build() {
	cd "$srcdir/$_sourcedirectory/"
	cmake -S '.' -B 'build/' \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX='/opt' \
		-DUSE_SHARED_ENET=ON \
		-DDISTRIBUTOR=archlinux.org
	make -C 'build/'
}

package() {
	pkgdesc="$pkgdesc"
	provides=("$_mainpkgname-git")
	conflicts=("$_mainpkgname-git")

	cd "$srcdir/$_sourcedirectory/"
	make DESTDIR="$pkgdir" -C 'build/' install

	rm -rf "$pkgdir/opt/bin/primehack-dolphin"
	rm -rf "$pkgdir/opt/include"
	rm -rf "$pkgdir/opt/lib/libdiscord-rpc.a"
	rm -rf "$pkgdir/opt/share/man/man6/primehack-dolphin.6"
}

Give that a try

n8jadams

Member

Registered: 2021-08-23

Posts: 49

Re: [SOLVED] Two versions of Dolphin emulator?

That, combined with dropping a `portable.txt` file in the generated `opt/bin` directory did the trick. Thank you!