Arch Linux

korimitsu

Member

Registered: 2016-08-14

Posts: 189

[Solved] gtk-sharp-2 needs fresh mirrors

Current source host "download.mono-project.com" is offline. The proposed PKGBUILD which works:

# Maintainer: Damian "G'lek" Mulligan <glek@glektarssza.com>
# Contributor: tobias <tobias@archlinux.org>

pkgname=gtk-sharp-2
pkgver=2.12.45
pkgrel=5
pkgdesc="gtk2 bindings for C#"
arch=(x86_64)
license=('LGPL')
url="https://www.mono-project.com/docs/gui/gtksharp/"
depends=('mono' 'gtk2')
makedepends=('monodoc')
optdepends=('perl: for gapi2xml.pl and gapi_pp.pl')
options=('!makeflags')
source=(gtk-sharp-${pkgver}.tar.gz::https://macports-distfiles.mirrorservice.org/gtk-sharp2/gtk-sharp-${pkgver}.tar.gz
        gtk-sharp2-2.12.12-gtkrange.patch
        gtk-sharp2-invalid-gpointer-cast.patch)
sha256sums=('02680578e4535441064aac21d33315daa009d742cab8098ac8b2749d86fffb6a'
            '26a1ade869ba1b54f37e544332e6e40cc6d3c93414a712d8605cb44fc212acf9'
            '82482309cab86f8321cd5ccccf41adf6026b8464c70f5a34266c8ab64ed78540')

prepare() {
  cd gtk-sharp-${pkgver}
  patch -Np1 -i ../gtk-sharp2-2.12.12-gtkrange.patch
  patch -Np1 -i ../gtk-sharp2-invalid-gpointer-cast.patch
}

build() {
  cd gtk-sharp-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd gtk-sharp-${pkgver}
  make DESTDIR="${pkgdir}" install
}

These mirrors are ok:

https://macports-distfiles.mirrorservice.org/gtk-sharp2/gtk-sharp-2.12.45.tar.gz
https://ftp.fau.de/macports/distfiles/gtk-sharp2/gtk-sharp-2.12.45.tar.gz

Last edited by korimitsu (2025-10-29 18:32:32)

glek

Member

From: Alberta, Canada

Registered: 2017-01-17

Posts: 20

Website

Re: [Solved] gtk-sharp-2 needs fresh mirrors

I would appreciate if, in the future, you could suggest those mirrors in the AUR package comments instead of flagging the package out of date due to an issue beyond my control. I would gladly have updated the "PKGBUILD" file with one of the alternative mirrors had you done so.

The out-of-date flag is meant to signal that a newer version of the upstream source is available. Comments are meant for more general discussions such as if the package is broken.

glek

Member

From: Alberta, Canada

Registered: 2017-01-17

Posts: 20

Website

Re: [Solved] gtk-sharp-2 needs fresh mirrors

Mirror updated until the Microsoft Azure DNS issue is resolved. Please remember to mark the topic as "resolved" if your problem has been resolved.

Cheers!

korimitsu

Member

Registered: 2016-08-14

Posts: 189

Re: [Solved] gtk-sharp-2 needs fresh mirrors

Now working thanks!