Arch Linux

l4rzy

Member

Registered: Yesterday

Posts: 4

[REQUEST] okular-mupdf-ng-git

Good afternoon,

I would like to request for this software: https://github.com/l4rzy/okular-mupdf-ng
It's a MuPDF backend plugin for Okular, with the hope of replacing all the outdated plugins. The software is in beta, but it's very much usable.
I tried my best to follow the packaging guidelines, but please tell me if anything needs to be fixed.

# Maintainer: rzy <me@23ro.org>
pkgbase=okular-mupdf-ng-git
pkgname=okular-mupdf-ng-git
_pkgname=okular-mupdf-ng
pkgver=0.1.10.r63.gb7f6b42
pkgrel=1
pkgdesc="MuPDF backend generator plugin for KDE Okular (Next Generation) - git"
arch=('x86_64')
url="https://github.com/l4rzy/okular-mupdf-ng"
license=('GPL-3.0-or-later')
depends=('gcc-libs' 'glibc' 'kcoreaddons' 'ki18n' 'okular' 'qt6-base' 'qt6-5compat' 'nss' 'libseccomp' 'libmupdf>=1.28.0' 'zlib')
makedepends=('cmake' 'extra-cmake-modules' 'git' 'jq' 'pkgconf' 'qt6-tools')
provides=('okular-mupdf-ng')
conflicts=('okular-mupdf-ng')
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
  local ver
  ver=$(jq -r '.KPlugin.Version' "$srcdir/$_pkgname/src/generator/mupdfng.json" 2>/dev/null)
  printf "%s.r%s.g%s" "$ver" "$(git -C "$srcdir/$_pkgname" rev-list --count HEAD)" \
    "$(git -C "$srcdir/$_pkgname" rev-parse --short=7 HEAD)"
}

build() {
  cmake -B "$srcdir/build" -S "$srcdir/$_pkgname" -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DUSE_SYSTEM_MUPDF=ON \
    -DMUPDF_SYSTEM_MIN_VERSION=1.28.0 \
    -DBUILD_TESTING=OFF
  cmake --build "$srcdir/build"
}

package() {
  DESTDIR="$pkgdir" cmake --install "$srcdir/build"
}

Thank you!

loqs

Member

Registered: 2014-03-06

Posts: 19,037

Re: [REQUEST] okular-mupdf-ng-git

Please use code tags for the PKGBUILD.

license=('GPL-3.0-or-later')

Is AGPL-3.0-or-later not required due to use of mupdf?

makedepends=('cmake' 'extra-cmake-modules' 'git' 'jq' 'pkgconf' 'qt6-tools')

'pkgconf' is not required as it is part of base-devel. ninja needs to be included or build will fail in a clean chroot.

  cmake -B "$srcdir/build" -S "$srcdir/$_pkgname" -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DUSE_SYSTEM_MUPDF=ON \
    -DMUPDF_SYSTEM_MIN_VERSION=1.28.0 \
    -DBUILD_TESTING=OFF
  cmake --build "$srcdir/build"

Could the build directory not be placed directly in "$srcdir" following the cmake package guidelines? Similarly  CMAKE_BUILD_TYPE=Release instead of None. Why disable tests?

l4rzy

Member

Registered: Yesterday

Posts: 4

Re: [REQUEST] okular-mupdf-ng-git

Thank you for your comments. AGPLv3 is not required, other packages do the same e.g., https://archlinux.org/packages/extra/x8 … -pdf-mupdf
PKGBUILD updated.

edit: add openssl to makedepends & change DCMAKE_BUILD_TYPE to None

# Maintainer: rzy <me@23ro.org>
pkgbase=okular-mupdf-ng-git
pkgname=okular-mupdf-ng-git
_pkgname=okular-mupdf-ng
pkgver=0.1.10.r4.gb76bd03
pkgrel=1
pkgdesc="MuPDF backend generator plugin for KDE Okular (Next Generation) - git"
arch=('x86_64')
url="https://github.com/l4rzy/okular-mupdf-ng"
license=('GPL-3.0-or-later')
depends=('gcc-libs' 'glibc' 'kcoreaddons' 'ki18n' 'okular' 'qt6-base' 'qt6-5compat' 'nss' 'libseccomp' 'libmupdf>=1.28.0' 'zlib')
makedepends=('cmake' 'extra-cmake-modules' 'git' 'openssl' 'ninja' 'qt6-tools')
provides=('okular-mupdf-ng')
conflicts=('okular-mupdf-ng')
source=("$_pkgname::git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  ( set -o pipefail
    git describe --long --tags --abbrev=7 2>/dev/null | sed -e 's/^v//' -e 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
  )
}

build() {
  cmake -B "build" -S "$srcdir/$_pkgname" -G Ninja \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DUSE_SYSTEM_MUPDF=ON \
    -DMUPDF_SYSTEM_MIN_VERSION=1.28.0 \
    -DBUILD_TESTING=ON
  cmake --build "build"
}

check() {
  ctest --test-dir "build" --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install "build"
}

Last edited by l4rzy (Today 02:09:30)

l4rzy

Member

Registered: Yesterday

Posts: 4

Re: [REQUEST] okular-mupdf-ng-git

Now that AUR registration is closed. I would like to nicely ask if any maintainer can publish this software to AUR. If anything else is required, please let me know. Thank you!

seth

Member

From: Won't reply 2 private help req

Registered: 2012-09-03

Posts: 77,678

Re: [REQUEST] okular-mupdf-ng-git

That's not how the AUR used to work or could.
You'll have to wait until it either re-opens … or gets shut down entirely.

---

How to upload text · How to boot w/o GUI · Disable Windows Fast-Start! · Fix your xinitrc

l4rzy

Member

Registered: Yesterday

Posts: 4

Re: [REQUEST] okular-mupdf-ng-git

Thank you for replying. I'll wait, and hope it won't get shut down