Arch Linux

username6921

Member

Registered: Today

Posts: 1

New package pkgbuild submission

I decided I need to check Convey (Geary hard fork) https://gitlab.gnome.org/donnybeelo/convey but author provides scr and flatpak only, I did PKGBUILD for convey-git. I do not have an account and never submitted one. So if someone will check it and make it to AUR for easier updating, Thanks! And sorry If I did something wrong.

pkgname=convey-git
pkgver=r7459.329d971
pkgrel=1
pkgdesc="Convey application from GNOME GitLab"
arch=('x86_64')
url="https://gitlab.gnome.org/donnybeelo/convey"
license=('GPL-3.0-or-later')
depends=(
  'cairo'
  'enchant'
  'folks'
  'gcr-4'
  'glib2'
  'gmime3'
  'gnome-online-accounts'
  'gst-plugins-bad'
  'gst-plugins-base'
  'gstreamer'
  'gtk4'
  'icu'
  'iso-codes'
  'json-glib'
  'libadwaita'
  'libgee'
  'libpeas-2'
  'libsecret'
  'libsoup3'
  'libunwind'
  'libxml2'
  'sqlite'
  'webkitgtk-6.0'
  'libytnef'
)
makedepends=(
  'git'
  'gobject-introspection'
  'itstool'
  'meson'
  'ninja'
  'vala'
)
source=("git+https://gitlab.gnome.org/donnybeelo/convey.git")
sha256sums=('SKIP')

pkgver() {
  cd convey
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
  arch-meson convey build
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
}