Arch Linux

bsd-source

Member

Registered: 2020-11-21

Posts: 1

iwdtray - tray icon and gui for iwd written in Rust

This is essentially and alternative gui for iwd. I personally used iwgtk for several years now but didn't care for the gui much. Here is my attempt at a better gui written in Rust.

https://github.com/bsd-source/iwdtray

Screenshot (light)
Screenshot (dark)

PKGBUILD

pkgname=iwdtray
pkgver=0.1.0
pkgrel=1
pkgdesc='Tray icon and GUI front-end for iwd'
url='https://github.com/bsd-source/iwdtray'
arch=('x86_64')
license=('GPL-3.0-or-later')
depends=('iwd' 'gtk4>=4.12' 'glib2' 'gcc-libs' 'glibc')
makedepends=('cargo' 'git')
conflicts=('iwgtk')
backup=('etc/iwdtray.conf')
options=('!lto' '!debug')
source=("$pkgname::git+$url.git#tag=v$pkgver")
sha256sums=('SKIP')

prepare() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    cargo build --frozen --release
}

check() {
    cd "$pkgname"
    export RUSTUP_TOOLCHAIN=stable CARGO_TARGET_DIR=target
    cargo test --frozen --release
}

package() {
    cd "$pkgname"
    install -Dm755 -t "$pkgdir/usr/bin" target/release/iwdtray target/release/iwdtray-gui
    install -Dm644 data/iwdtray.conf "$pkgdir/etc/iwdtray.conf"
    install -Dm644 data/iwdtray.desktop "$pkgdir/etc/xdg/autostart/iwdtray.desktop"
    install -Dm644 -t "$pkgdir/usr/share/applications" data/io.github.bsd_source.iwdtray.desktop

}