Arch Linux

Dulbi

Member

Registered: 2026-04-01

Posts: 6

Request for a HatchZip AUR package

Hi team,

May I request anyone create a HatchZip AUR package? AFAIK, it's not present in AUR. The code comes from https://github.com/xevrion/hatchzip.

I have already made a -bin PKGBUILD file but I wonder if we can refine it, what do you think?

pkgname=hatchzip-bin
pkgver=0.1.10
pkgrel=1
pkgdesc="Free, open-source archive extractor that extracts files in place to save disk space (pre-compiled binary)"
arch=('x86_64')
url="https://github.com/xevrion/hatchzip"
license=('MIT' 'Apache-2.0')
provides=('hatchzip' 'hz')
conflicts=('hatchzip')
depends=('glibc')

source_x86_64=("https://github.com/xevrion/hatchzip/releases/download/v${pkgver}/hatchzip-x86_64-linux.tar.gz")
sha256sums_x86_64=('508b9534e2451040745de5f1cb140ee2d050e8ed114e280158d8110b392ab929')

package() {
    install -Dm755 "${srcdir}/hatchzip-x86_64-linux/hatchzip" "${pkgdir}/usr/bin/hatchzip"
    ln -s hatchzip "${pkgdir}/usr/bin/hz"

    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/man/hatchzip.1" "${pkgdir}/usr/share/man/man1/hatchzip.1"

    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/completions/hatchzip.bash" "${pkgdir}/usr/share/bash-completion/completions/hatchzip"
    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/completions/_hatchzip" "${pkgdir}/usr/share/zsh/site-functions/_hatchzip"
    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/completions/hatchzip.fish" "${pkgdir}/usr/share/fish/vendor_completions.d/hatchzip.fish"

    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/LICENSE-MIT" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-MIT"
    install -Dm644 "${srcdir}/hatchzip-x86_64-linux/LICENSE-APACHE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-APACHE"
    if [ -f "${srcdir}/hatchzip-x86_64-linux/LICENSE-UNRAR" ]; then
        install -Dm644 "${srcdir}/hatchzip-x86_64-linux/LICENSE-UNRAR" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-UNRAR"
    fi
}

Last edited by Dulbi (Yesterday 12:59:08)

Trilby

Inspector Parrot

Registered: 2011-11-29

Posts: 30,545

Website

Re: Request for a HatchZip AUR package

That PKGBUILD looks appropriate and properly done - but is there a reason you are using the precompiled binary rather than building it from source?  The latter should be preferred unless there are good reasons to do otherwise.  I can't imagine this is particularly resource intensive to build.

---

"UNIX is simple and coherent" - Dennis Ritchie; "GNU's Not Unix" - Richard Stallman

Dulbi

Member

Registered: 2026-04-01

Posts: 6

Re: Request for a HatchZip AUR package

I was not experienced enough to compile it to be honest. And it was quickiest way to get the package installed.

If you look at the assets from GitHub for other distributions, all are based directly from the binary, so I've decided to go the same way.

BTW, thanks for the assessment. Does anyone want to endorse it on AUR?

Last edited by Dulbi (Yesterday 13:48:01)