Arch Linux

CavalierBob

Member

From: San Francisco Bay Area

Registered: 2006-07-20

Posts: 110

timer-applet 2.0.1 PKGBUILD

Since there has not been an update to the timer-applet PKGBUILD in AUR for a while, I've created one updating to the current release. As this is my 1st PKGBUILD, I would appreciate a review and any comments/suggestions. I have built this applet on my system & it is installed and working properly.

# Maintainer: Bob Dundon <rsdundon@gmail.com>
# Contributor: Adian Pavone <wingot@wingot.com>
# Contributor: tranquility <trankas@gmail.com>

pkgname=timer-applet
pkgver=2.0.1
pkgrel=1
pkgdesc="A countdown timer applet for the GNOME panel."
arch=('i686')
url="http://timerapplet.sourceforge.net/"
license="GPL"
depends=('gnome-python-desktop>=2.16' 'python-notify>=0.1' 'dbus-python>=0.80')
source=(http://dl.sourceforge.net/timerapplet/$pkgname-$pkgver.tar.gz)
md5sums=('c56e5ec73ece83389e05a51aa38e0d59')

build() {
  cd $startdir/src/$pkgname-$pkgver
  ./configure --prefix=/usr
  make || return 1
  make DESTDIR=$startdir/pkg install
}

I'm going to petition to adopt this package, thus the reason it lists me as the maintainer.

There are some errors thrown when the package builds. I am not sure what the error refers to or how to correct. Here is an example:

WARNING: failed to install schema `/schemas/apps/timer-applet/prefs/play_beep' locale `de': Can't overwrite existing read-only value: Value for `/schemas/apps/timer-applet/prefs/play_beep' set in a read-only source at the front of your configuration path

Any ideas? Seems to be a language-based problem.

Thanks!

Bob

tomk

Forum Fellow

From: Ireland

Registered: 2004-07-21

Posts: 9,839

Re: timer-applet 2.0.1 PKGBUILD

There are specific actions you need to take when dealing with schemas in PKGBUILDs. Have a look at any of the official GNOME packages for examples.

CavalierBob

Member

From: San Francisco Bay Area

Registered: 2006-07-20

Posts: 110

Re: timer-applet 2.0.1 PKGBUILD

Thanks Tom....found the needed lines, added them, rebuilt and now all is well.

Also noted I did not have the license as an array so I fixed that as well.

Updated PKGBUILD:

# Maintainer: Bob Dundon <rsdundon@gmail.com>
# Contributor: Adrian Pavone <wingot@wingot.com>
# Contributor: tranquility <trankas@gmail.com>

pkgname=timer-applet
pkgver=2.0.1
pkgrel=1
pkgdesc="A countdown timer applet for the GNOME panel."
arch=('i686')
url="http://timerapplet.sourceforge.net/"
license=('GPL')
depends=('gnome-python-desktop>=2.16' 'python-notify>=0.1' 'dbus-python>=0.80')
source=(http://dl.sourceforge.net/timerapplet/$pkgname-$pkgver.tar.gz)
md5sums=('c56e5ec73ece83389e05a51aa38e0d59')

build() {
  cd $startdir/src/$pkgname-$pkgver
  ./configure --prefix=/usr
  make || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${startdir}/pkg install

  mkdir -p ${startdir}/pkg/usr/share/gconf/schemas
  gconf-merge-schema ${startdir}/pkg/usr/share/gconf/schemas/${pkgname}.schemas ${startdir}/pkg/etc/gconf/schemas/*.schemas
  rm -f ${startdir}/pkg/etc/gconf/schemas/*.schemas
}

Bob

Last edited by CavalierBob (2007-07-08 18:41:47)