[REQUEST] evince-gtk

knavs · 2009-02-10 21:30:35

Want to see evince without all gnome-related libs. But cant find it in AUR.
According to this post http://bbs.archlinux.org/viewtopic.php? … 77#p419177 formerly it was in AUR.

If some one can create such package pls help. All xfce/box users will appreciate it)

srcrpm for altlinux - http://sisyphus.ru/srpm/Branch4/evince-gtk

spec - http://sisyphus.ru/srpm/Branch4/evince-gtk/spec
patch1 - http://sisyphus.ru/cgi-bin/srpm.pl/Bran … getpatch/0
patch2 - http://sisyphus.ru/cgi-bin/srpm.pl/Bran … getpatch/1

Last edited by knavs (2009-02-10 21:36:30)

skottish · 2009-02-13 00:33:05

I've meaning to reply to this for a few days. This PKGBUILD is for a development version of Evince. It's only Gnome run-time dependency is gconf, and that's as minimal as I could get it. It has a few make depends that are from Gnome, as well as one from texlive. If you don't want DVI, you can eliminate the texlive stuff. You'll also need the file evince.install in the same directory. I posted it here even though it's Arch's default.

***Removed. See post #6***

Anarconda · 2009-02-13 00:43:38

Thank you skottish.

skottish · 2009-02-13 00:57:26

You're welcome. But, it needs to be updated. I forgot to add back all of the rest of the dependencies. I'll post back here when it's fixed.

--EDIT--

Fixed.

knavs · 2009-02-13 17:43:38

thanks alot skottish!
But what about gconf? Have a look at patch1, it removes gconf dependency (i hope so)

skottish · 2009-02-13 19:39:49

I'm not seeing where gconf is removed. It looks to me as if one patch is removing gnome-vfs, and the other is libgnome. Both of these can be compiled out now. After all, those patches are for evince-2.20. Am I missing something?

One more thing. If you want something way lighter, and don't mind a little less functionality, epdfview-svn is super light. Unlike the version if AUR, this one both works and is proper:

epdfview-svn

# Contributor: Tom K 
# Contributor: Philipp Robbel 
# Mutater:     skottish

pkgname=epdfview-svn
pkgver=313
pkgrel=1
pkgdesc="A free lightweight PDF document viewer"
arch=('i686' 'x86_64')
depends=('gtk2' 'poppler-glib' 'cups')
makedepends=('subversion' 'pkgconfig' 'autoconf' 'automake')
conflicts=('epdfview')
provides=('epdfview')
source=()
md5sums=()
url="http://www.emma-soft.com/projects/epdfview/"
license="GPL"

_svntrunk=svn://svn.emma-soft.com/epdfview/trunk
_svnmod=epdfview

build() {
    cd $startdir/src

    if [ -d $_svnmod/.svn ]; then
        (cd $_svnmod && svn up -r $pkgver)
    else
        svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
    fi

    msg "SVN checkout done or server timeout"
    msg "Starting make..."

    cp -r $_svnmod $_svnmod-build
    cd $_svnmod-build

    ./autogen.sh 
    ./configure --prefix=/usr
    make || return 1
    make DESTDIR=$startdir/pkg install

    rm -rf ../$_svnmod-build
}

skottish · 2009-02-27 06:08:18

--without-gconf has appeared as an option in 2.25.91. It's still a make depends, but seems to be running fine without it. I'm a little unclear about how to remove gnome-icon-theme as a dependency. It's not listed as an option -- hidden or not -- in configure.ac, so I think that we're stuck with this one for now. I need it anyway for Openbox XDG menus, so I'm not too concerned about that.

As always, build with 'makepkg -sr' to install and remove the make depends:

PKGBUILD

# $Id: PKGBUILD 20550 2008-12-05 16:48:02Z allan $
# Maintainer: Jan de Groot 
# Mutator: skottish

pkgname=evince
pkgver=2.25.91
pkgrel=1
pkgdesc="Simply a document viewer"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=('GPL')
depends=('gsfonts' 'poppler-glib>=0.10.1' 't1lib' 'libglade' 'shared-mime-info' 'libdjvu' 'desktop-file-utils' 'libspectre' 'gnome-icon-theme')
makedepends=('gnome-doc-utils>=0.14.0' 'pkgconfig' 'texlive-bin' 'intltool' 'gconf')
optdepends=('texlive-bin: DVI support')
install=evince.install
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/2.25/${pkgname}-${pkgver}.tar.bz2)
replaces=('gpdf')
md5sums=('53e6774241d08347fda26ff98cac2aff')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
            --localstatedir=/var --disable-static \
            --with-print=gtk --without-keyring \
            --without-gconf --without-libgnome \
            --enable-pdf --enable-tiff \
            --enable-djvu --enable-dvi \
            --enable-t1lib --enable-pixbuf \
            --enable-comics --enable-impress \
            --disable-schemas-install \
            --disable-scrollkeeper || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
}

evince.install

pkgname=evince

post_install() {
  gtk-update-icon-cache -q -f -t usr/share/icons/hicolor
  update-desktop-database -q
}

post_upgrade() {
  post_install $1
}

post_remove() {
  update-desktop-database -q
  gtk-update-icon-cache -q -f -t usr/share/icons/hicolor
}

knavs · 2009-02-27 12:36:11

Thats exactly what i was looking for! Man you the best! And gnome-icon-theme it's just an icon theme:)

Can u submit it to AUR as evince-gtk?

Last edited by knavs (2009-02-27 12:37:46)

skottish · 2009-02-27 15:42:48

knavs wrote:

Thats exactly what i was looking for! Man you the best! And gnome-icon-theme it's just an icon theme:)
Can u submit it to AUR as evince-gtk?

Let's make sure that it's stable first by testing for a few days. I don't see why it wouldn't be; I used only options from Evince itself and not any patches. I would also like to get some of the make depends out of the picture if possible. I'm assuming gconf is a make depends because of what I saw in configure.ac, but --without-gconf was actually there before and I missed it. Maybe I missed something else that will help?

skottish · 2009-03-03 06:26:39

Bump.

I'll push this to AUR if it seems to be working for anyone that's testing it. I'll put it there, then I'm going to look for someone to adopt it right away. Until that time I'll maintain it. So, for anyone that's using this, is it working properly for you?

Oh yeah, has anyone tried to remove gnome-icon-theme after installing this package? I need it, so good tests are hard to come by. If someone felt like bumping it to the makedepends field (it's required for building) and reporting back how it works without, that would be great.

Army · 2009-03-03 09:16:42

Works fine here But before putting this into AUR you should give it another name!

xaiviax · 2009-03-03 21:10:48

works great here...

skottish · 2009-03-03 21:29:13

evince-gtk is what it was called before, so I guess I'll keep that.

Did anyone try with gnome-icon-theme as a makedepends then remove it? I can't do it because for some reason that I haven't bothered to check on obmenu wants it for obm-xdg. Well, I just can't test it for any length of time.

--EDIT--

Bump to:
pkgver=2.25.92
md5sums=('5e0d0fc2d900856074b556e4eacc68e6')

xaiviax · 2009-03-04 01:08:00

skottish wrote:

evince-gtk is what it was called before, so I guess I'll keep that.
Did anyone try with gnome-icon-theme as a makedepends then remove it? I can't do it because for some reason that I haven't bothered to check on obmenu wants it for obm-xdg. Well, I just can't test it for any length of time.
--EDIT--
Bump to:
pkgver=2.25.92
md5sums=('5e0d0fc2d900856074b556e4eacc68e6')

Updated to your latest build with makedepends change, got this error: (don't remember it from previous build)
I/O warning : failed to load external entity "/usr/share/gconf/schemas/evince.schemas"
Failed to open `/usr/share/gconf/schemas/evince.schemas': No such file or directory

Anyhow, seems to work fine. Removed gnome-icon-theme, seems to still work fine.

skottish · 2009-03-04 02:15:35

xaiviax wrote:

Updated to your latest build with makedepends change, got this error: (don't remember it from previous build)
I/O warning : failed to load external entity "/usr/share/gconf/schemas/evince.schemas"
Failed to open `/usr/share/gconf/schemas/evince.schemas': No such file or directory
Anyhow, seems to work fine. Removed gnome-icon-theme, seems to still work fine.

That was just with gnome-icon-theme being moved to makedepends? I ask because all of the gconf stuff including schemas should be completely removed. This is from the PKGBUILD in post #7, right?

xaiviax · 2009-03-04 02:24:59

@skottish:

PKGBUILD in post #7 with your
Bump to:
pkgver=2.25.92
md5sums=('5e0d0fc2d900856074b556e4eacc68e6')
and the gnome-icon-theme being moved to makedepends

skottish · 2009-03-04 02:48:07

I'm not seeing any errors at all. I also strangely don't need gnome-icon-theme for obmenu. I have no idea how that came about. Anyway, this hopefully will be the final PKGBUILD and install file. There have been changes in both, so try these and see if anything is different:

PKGBUILD

pkgname=evince-gtk
pkgver=2.25.92
pkgrel=1
pkgdesc="Simply a document viewer"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=('GPL')
depends=('gsfonts' 'poppler-glib>=0.10.1' 't1lib' 'libglade' 'shared-mime-info' 'libdjvu' 'desktop-file-utils' 'libspectre' 'hicolor-icon-theme')
makedepends=('gnome-doc-utils' 'pkgconfig' 'texlive-bin' 'intltool' 'gconf' 'gnome-icon-theme')
optdepends=('texlive-bin: DVI support')
install=evince-gtk.install
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/evince/2.25/evince-${pkgver}.tar.bz2)
provides=('evince')
conflicts=('evince')
md5sums=('5e0d0fc2d900856074b556e4eacc68e6')

build() {
  cd "${srcdir}/evince-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
            --localstatedir=/var --disable-static \
            --with-print=gtk --without-keyring \
            --without-gconf --without-libgnome \
            --enable-pdf --enable-tiff \
            --enable-djvu --enable-dvi \
            --enable-t1lib --enable-pixbuf \
            --enable-comics --enable-impress \
            --disable-schemas-install \
            --disable-scrollkeeper || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
}

evince-gtk.install

pkgname=evince-gtk

post_install() {
  gtk-update-icon-cache -q -f -t usr/share/icons/hicolor
  update-desktop-database -q
}

post_upgrade() {
  post_install $1
}

post_remove() {
  update-desktop-database -q
  gtk-update-icon-cache -q -f -t usr/share/icons/hicolor
}

--Removed the EDIT--

jaydoc · 2009-03-04 06:24:00

Hi there... I am looking to build a minimal, clean desktop system on top of a base arch linux install... and one important requirement is a full-featured doc viewer.

I was looking at evince and epdfviewer, when I happened to see this. Evince is too bloated with those GNOME deps, (I'm using e17, as that was the best balance I could get between good looks and small footprint). Is there any difference in functionality between this AUR package and epdfviewer....?

skottish · 2009-03-04 06:41:09

The only reason why I'm doing this is because epdfview only supports PDF. If it supported all of the document types that evince does, I'd gladly get rid of evince. But, this evince package is light. The Gnome dependencies can be removed after it's built.

If you want to use epdfview, use the PKGBUILD from earlier in this thread. It has a couple of features missing from the version in community, and the epdfview-svn package in AUR is messed up. Although, I've never tried Xyne's builds (epdview-light). He's good, I'm sure it's a good package.

To everyone, this is going into AUR tomorrow after I hear back from xaiviax or if any issues come up.

knavs · 2009-03-04 15:06:39

I tried installing with gnome-icon-theme as a makedependency. Removed gnome-icon-theme, now i have sime icons missing...

Gtk-WARNING **: Error loading theme icon 'object-rotate-left' for stock: Icon 'object-rotate-left' not present in theme
Gtk-WARNING **: Error loading theme icon 'object-rotate-left' for stock: Icon 'object-rotate-right' not present in theme
Gtk-WARNING **: Error loading theme icon 'object-rotate-left' for stock: Icon 'x-office-presentation' not present in theme

evince icons list from shell/ev-stock-icons.h:

static const EvStockIcon stock_icons [] = {
    { EV_STOCK_ZOOM,         "zoom" }, 
    { EV_STOCK_ZOOM_PAGE,        "zoom-fit-page" }, 
    { EV_STOCK_ZOOM_WIDTH,       "zoom-fit-width" }, 
    { EV_STOCK_VIEW_DUAL,        "view-page-facing" }, 
    { EV_STOCK_VIEW_CONTINUOUS,  "view-page-continuous" }, 
    { EV_STOCK_ROTATE_LEFT,      "object-rotate-left"},
    { EV_STOCK_ROTATE_RIGHT,     "object-rotate-right"},
    { EV_STOCK_RUN_PRESENTATION, "x-office-presentation"},
    { EV_STOCK_VISIBLE,          "eye"}
};

add hicolor-icon-theme as dependency

Last edited by knavs (2009-03-04 15:10:12)

skottish · 2009-03-04 15:34:48

knavs wrote:

add hicolor-icon-theme as dependency

Done. It's updated in the last PKGBUILD that I posted here (post #17). Thanks knavs.

Other than that, are we good to go with this?

xaiviax · 2009-03-04 18:41:05

Latest works great, no install errors either

skottish · 2009-03-04 18:50:26

Sweet! Thanks for the help to all of you. I'll upload it in a few minutes and post the link back here.

--EDIT--

Done:

http://aur.archlinux.org/packages.php?ID=24416

knavs · 2009-03-04 20:35:11

I m not sure if this can be usefull or not but anyways:

http://rapidshare.com/files/205341890/e … r.bz2.html - those missing icons [2b1076d64fadee40667cb1dd5cecf6d4]

pkgname=evince-gtk
pkgver=2.25.92
pkgrel=1
pkgdesc="Simply a document viewer"
url="http://www.gnome.org"
arch=(i686 x86_64)
license=('GPL')
depends=('gsfonts' 'poppler-glib>=0.10.1' 't1lib' 'libglade' 'shared-mime-info' 'libdjvu' 'desktop-file-utils' 'libspectre' 'hicolor-icon-theme')
makedepends=('autoconf' 'gconf' 'gnome-doc-utils' 'pkgconfig' 'texlive-bin' 'intltool')
optdepends=('texlive-bin: DVI support')
install=evince-gtk.install
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/evince/2.25/evince-${pkgver}.tar.bz2 
        'evince-stock-icons.tar.bz2' 'without-gnome-icons.patch')
provides=('evince')
conflicts=('evince')
md5sums=('5e0d0fc2d900856074b556e4eacc68e6' 
        '2b1076d64fadee40667cb1dd5cecf6d4'
        'f815f639d2632849a17516c45f0ea3e1') 
build() {
  cd "${srcdir}/evince-${pkgver}"
  patch -p1 < ../without-gnome-icons.patch
  autoconf -v || return 1
  ./configure --prefix=/usr --sysconfdir=/etc \
            --localstatedir=/var --disable-static \
            --with-print=gtk --without-keyring \
            --without-gconf --without-libgnome \
            --enable-pdf --enable-tiff \
            --enable-djvu --enable-dvi \
            --enable-t1lib --enable-pixbuf \
            --enable-comics --enable-impress \
            --disable-schemas-install \
            --disable-scrollkeeper || return 1
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
  cp -rP ${srcdir}/evince-stock-icons/* ${pkgdir}/usr/share/evince/icons/hicolor
}

--- evince-2.25.92/configure.ac.orig    2009-03-04 19:48:48.000000000 +0300
+++ cevince-2.25.92/configure.ac    2009-03-04 19:50:01.000000000 +0300
@@ -114,14 +114,13 @@
 AC_SUBST([GLIB_REQUIRED])
 AC_SUBST([GTK_REQUIRED])
 
-GNOME_ICON_THEME_REQUIRED=2.17.1
 LIBXML_REQUIRED=2.5.0
 
 PKG_CHECK_MODULES(LIBDOCUMENT, gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED)
 PKG_CHECK_MODULES(LIBVIEW, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
 PKG_CHECK_MODULES(BACKEND, gtk+-2.0 >= $GTK_REQUIRED)
 PKG_CHECK_MODULES(FRONTEND_CORE, gtk+-2.0 >= $GTK_REQUIRED gthread-2.0 gio-2.0 >= $GLIB_REQUIRED)
-PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gnome-icon-theme >= $GNOME_ICON_THEME_REQUIRED gthread-2.0)
+PKG_CHECK_MODULES(SHELL_CORE, libxml-2.0 >= $LIBXML_REQUIRED gtk+-2.0 >= $GTK_REQUIRED gtk+-unix-print-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED gthread-2.0)
 
 if test "$os_win32" = no; then
     PKG_CHECK_MODULES(SMCLIENT, gtk+-2.0 gthread-2.0 sm >= 1.0.0)
@@ -277,12 +276,12 @@
 AM_CONDITIONAL(ENABLE_THUMBNAILER, test x$ENABLE_THUMBNAILER = "xyes")
 
 dnl GConf configuration
-AM_GCONF_SOURCE_2
+#AM_GCONF_SOURCE_2
 
-AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
-if test "x$GCONFTOOL" = "xno"; then
-    AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
-fi
+#AC_PATH_PROG([GCONFTOOL], [gconftool-2], [no])
+#if test "x$GCONFTOOL" = "xno"; then
+#    AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
+#fi
 
 # ***
 # GIR

skottish · 2009-03-05 04:53:34

***Removed previous post***

There's an updated package now in AUR that removes the gnome-icon-theme makedepend, as well as corrects a few unnecessary configure options. Removing gconf and gnome-doc-utils is very complicated and I'm unsure whether it's safe to do so. They are both firmly ingrained in the configure script, and seem to intertwine with a number of necessary components.

Sorry knavs, but I can't write into a PKGBUILD a link to Rapid Share. It's inherently unsafe. I put a little information on the AUR page and linked back to this thread if people want to use the icons posted. Thanks a lot anyway.

Arch Linux

#1 2009-02-10 21:30:35

[REQUEST] evince-gtk

#2 2009-02-13 00:33:05

Re: [REQUEST] evince-gtk

#3 2009-02-13 00:43:38

Re: [REQUEST] evince-gtk

#4 2009-02-13 00:57:26

Re: [REQUEST] evince-gtk

#5 2009-02-13 17:43:38

Re: [REQUEST] evince-gtk

#6 2009-02-13 19:39:49

Re: [REQUEST] evince-gtk

#7 2009-02-27 06:08:18

Re: [REQUEST] evince-gtk

#8 2009-02-27 12:36:11

Re: [REQUEST] evince-gtk

#9 2009-02-27 15:42:48

Re: [REQUEST] evince-gtk

#10 2009-03-03 06:26:39

Re: [REQUEST] evince-gtk

#11 2009-03-03 09:16:42

Re: [REQUEST] evince-gtk

#12 2009-03-03 21:10:48

Re: [REQUEST] evince-gtk

#13 2009-03-03 21:29:13

Re: [REQUEST] evince-gtk

#14 2009-03-04 01:08:00

Re: [REQUEST] evince-gtk

#15 2009-03-04 02:15:35

Re: [REQUEST] evince-gtk

#16 2009-03-04 02:24:59

Re: [REQUEST] evince-gtk

#17 2009-03-04 02:48:07

Re: [REQUEST] evince-gtk

#18 2009-03-04 06:24:00

Re: [REQUEST] evince-gtk

#19 2009-03-04 06:41:09

Re: [REQUEST] evince-gtk

#20 2009-03-04 15:06:39

Re: [REQUEST] evince-gtk

#21 2009-03-04 15:34:48

Re: [REQUEST] evince-gtk

#22 2009-03-04 18:41:05

Re: [REQUEST] evince-gtk

#23 2009-03-04 18:50:26

Re: [REQUEST] evince-gtk

#24 2009-03-04 20:35:11

Re: [REQUEST] evince-gtk

#25 2009-03-05 04:53:34

Re: [REQUEST] evince-gtk

Board footer