You are not logged in.

#1 2009-07-23 05:07:06

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

evolution-mapi - My first PKGBUILDs, please advise.

Hi, evolution-mapi is evolution's plugin for exchange 2007 connectivity, which Ubuntu has (!!!) but we don't. I've been worrying around the edges of this for 2 weeks now, and have finally come out with some PKGBUILDs which work for me.

So, before I post them up, I'm requesting both a review of the PKGBUILDs for any mistakes to be corrected AND advise on whether they can/should be put on the AUR. Everything is installed into /usr/local, but the plugin itself is of course required to be in the evo directories. I don't do much manipulation, so any 'out-of-the-usual' files are the fault of the default install scripts. I do notice that samba4 has a ../lib path somewhere, which installs a 'torture' folder, for torturing the samba server no doubt, I just ignore that.

evolution-mapi (number 4 below) is the intended package, but it depends on libmapi (number 3 below) which depends on samba4 (number 2, this is alpha software) and talloc (number 1), a component of samba4 which I couldn't get to link properly, so I'm building it separately.

EDIT1 - 9 am 24th July 09 - Removed un-used lines and used a for loop for symlinks. Still uses /usr/local

Number 1: talloc

# Maintainer: ngoonee <n g    o o n    e e <at gmail.com, delete all spaces>>
pkgname=talloc
pkgver=1.2.1
pkgrel=1
pkgdesc="This package was SPECIFICALLY created to support libmapi, for evolution-mapi usage."
arch=('i686' 'x86_64')
url="http://www.samba.org"
license=('GPL3')
options=(!makeflags)
source=(http://us1.samba.org/samba/ftp/samba4/${pkgname}-${pkgver}.tar.gz)

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  ./configure
  make || return 1
  make DESTDIR="$pkgdir/" install
}
md5sums=('0913db077d462c951d635c94b6304b39')

Number 2: samba4

# Maintainer: ngoonee <n g    o o n    e e <at gmail.com, delete all spaces>>
pkgname=samba4
pkgver=4.0.0A6
# We use the 'A' to fake out pacman's version comparators.  Samba chooses
# to append 'a','b',etc to their subsequent releases, which pamcan
# misconstrues as alpha, beta, etc.  Bad samba!
_realver=4.0.0alpha6
pkgrel=1
pkgdesc="Alpha build of samba4. This package was SPECIFICALLY created to support evolution-mapi and may not work for any other purpose."
arch=('i686' 'x86_64')
url="http://www.samba.org"
license=('GPL3')
depends=('db>=4.7' 'popt' 'libcups' 'acl' 'libldap' 'libcap>=2.16' 'heimdal>=1.2-1' 'pam' 'fam' 'gnutls>=2.4.1' 'tdb')
options=(!makeflags)
source=(http://us1.samba.org/samba/ftp/samba4/samba-${_realver}.tar.gz)

build() {
  cd ${srcdir}/samba-${_realver}/source4
  ./configure --prefix=/usr/local --with-lockdir=/var/cache/samba4 \
        --with-piddir=/var/run/samba4 --enable-fhs
  make || return 1
  make DESTDIR="$pkgdir/" install
}
md5sums=('2f6e52349eebabe83ed3cf207a8739f3')

Number 3: libmapi

# Maintainer: ngoonee <n g    o o n    e e <at gmail.com, delete all spaces>>
pkgname=libmapi
pkgver=0.8
pkgrel=1
pkgdesc="Library for MAPI connectivity with Microsoft Exchange. This package was SPECIFICALLY created to support evolution-mapi and may not work for any other purpose."
arch=('i686' 'x86_64')
url="http://www.openchange.org"
license=('GPL3')
depends=('samba4=4.0.0A6' 'talloc')
options=(!makeflags)
source=(http://downloads.sourceforge.net/openchange/${pkgname}-${pkgver}-ROMULUS.tar.gz)

build() {
  cd ${srcdir}/${pkgname}-${pkgver}-ROMULUS
  ./configure --prefix=/usr/local
  make || return 1
  make DESTDIR="$pkgdir/" install
}
md5sums=('ac194f9952803e24821f0e530fb87465')

Number 4: evolution-mapi

# Maintainer: ngoonee <n g    o o n    e e <at gmail.com, delete all spaces>>
pkgname=evolution-mapi
pkgver=0.25.90
pkgrel=1
pkgdesc="MAPI plugin for evolution."
arch=('i686' 'x86_64')
url="http://www.go-evolution.org"
license=('GPL3')
depends=('libmapi=0.8')
options=(!makeflags)
source=(http://ftp.gnome.org/pub/gnome/sources/evolution-mapi/0.25/${pkgname}-${pkgver}.tar.gz)

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:/usr/local/lib/pkgconfig
  ./configure --prefix=/usr/local
  make || return 1
  make DESTDIR="$pkgdir/" install

  # Create necessary symlinks, for files from libmapi and samba4 installs
  for i in libmapi libdcerpc libldb libndr libsamba-hostconfig; do
    ln -s ./${i}.so ${pkgdir}/usr/local/lib/${i}.so.0
  done
}
md5sums=('d051736580cd7b2eae24f0b5080052ac')

Phew, this was hard work. Please let me know how my PKGBUILD is. Those who use evo and have an exchange server, please do test this out.

Ah, an additional question, the Packaging Guidelines say /usr/local installs are not allowed. I understand this breaks the FHS, but unless I conflict samba4 with samba I doubt there's any easy way around it. Do I have to look for a way to do this, in order to submit these to the AUR?

Last edited by ngoonee (2010-02-05 03:23:27)


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#2 2009-07-23 19:09:14

djszapi
Member
From: Cambridge, United Kingdom
Registered: 2009-06-14
Posts: 1,439
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

Hello!

You can remove such a lines:

1. # $Id$
2. backup=()

You can change for these:

1. arch=(i686 x86_64) -> arch=('i686' 'x86_64')


You can do a for; done; do statement for the making symlinks, because they're very very similar.

And Is there any special reason to install it to the /usr/local, instead of /usr ?

Offline

#3 2009-07-23 19:56:48

Stefan Husmann
Member
From: Germany
Registered: 2007-08-07
Posts: 1,391

Re: evolution-mapi - My first PKGBUILDs, please advise.

Please use depends=('libmapi>=0.8').

/usr/local is a No-Go! Never use it. It is only for things that are _not_packaged.

Offline

#4 2009-07-23 21:49:02

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

Thanks to both of you. I'll be making the edits in a bit. The only reason to use /usr/local is that I'm worried about conflicts with an existing samba install. I'll dig a bit more and find out if its possible to do a side-by-side. Specifically whether I can install a 'crippled' samba4 which doesn't touch samba files.

Just a confirmation, if my .tar.gz overwrites any files already on my system it won't install, right?

EDIT: Oh, and Stefan, I think dependency is specifically on 0.8, because it doesn't work with 0.8.2, or something of that nature.
EDIT2: Altered the PKGBUILDs in OP.

Last edited by ngoonee (2009-07-24 00:57:01)


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#5 2009-07-24 09:05:14

framas
Member
Registered: 2009-07-24
Posts: 50

Re: evolution-mapi - My first PKGBUILDs, please advise.

I build and tested it today. It works.
The email folders are very slowly synchronized. Adressbook and Calendar are not working. Maybe it's configuration / server issue.
At least the evolution-exchange plugin works better for me.

Offline

#6 2009-07-24 09:35:33

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

@framas: Thank you for your testing. My exchange account has almost no mail, hence I'm not really noticing any real slow-down. I'll try and check out the address book and calendar when I have the time, since I don't actually use those features (yet).

If you're lucky enough to have evo-exchange working, that means your server is still exchange 2003. My network admins just changed over to 2007, which breaks evo-exchange due to OWA being totally redesigned. Eventually I believe evo-exchange will be removed in favour of this mapi plugin, but that would need samba4 to come out of alpha first (or separation of some parts of it, which is actually planned from what I can tell).

Anyway, thanks for testing.


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#7 2009-07-24 12:03:51

Stefan Husmann
Member
From: Germany
Registered: 2007-08-07
Posts: 1,391

Re: evolution-mapi - My first PKGBUILDs, please advise.

ngoonee wrote:

Just a confirmation, if my .tar.gz overwrites any files already on my system it won't install, right?

You mean your .pkg.tar.gz? pacman would reject installing packages that include files that are already installed and ownd by another package unless you give the -f to pacman.

Offline

#8 2009-07-25 06:28:41

djszapi
Member
From: Cambridge, United Kingdom
Registered: 2009-06-14
Posts: 1,439
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

Yeah, Stefan has right.

Offline

#9 2009-08-07 11:10:55

Tinuva
Member
From: South Africa/Cape Town
Registered: 2008-05-29
Posts: 37
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

1st PKGBUILD can't install into /usr since there is already a file  /usr/include/talloc.h on my system, so that is a problem to consider...

david@wadavid ~ $ ls -lsah /usr/include/talloc.h
12K -rw-r--r-- 1 root root 8.4K 2009-07-31 22:52 /usr/include/talloc.h

I have tdb 3.3.7-1 installed so had to change that in the 2nd PKGBUILD.
ps. I do not have samba installed on this box so I assume that should give fairly little trouble, but I'll install it into /usr/local since I couldn't install the first package into /usr

Installing libmapi went smooth.

When I got to evolution-mapi I hit an interesting spot, I didn't have intltool installed but I guess thats only needed when building so no need to add to the PKGBUILD.

The plugin compiled and installed fine.

-----------------------------

So testing the plugin in evolution. So far so good.

My contacts are empty..but then I never used this since I moved over to our Exchange 2007 server.
Calendar is working, but I dont know what calendar it is using, since i can add stuff, but it wont show up on OWA web version, and again the ones from OWA dont show up in evolution...
Mails are fast enough, though I can see its a bit slower than IMAP was.

So after all this I was hungry for more, and noticed there are a newer version out when visiting http://ftp.gnome.org/pub/gnome/sources/evolution-mapi/

0.27.5 at the time of my visit. So updated the pkgbuild.

Unfortunately Arch has evolution 2.26 so can't use 0.27.5 so went with 0.26.2

Requested 'evolution-data-server-1.2 >= 2.27.2' but version of evolution-data-server is 2.26.3

0.26.2 compiled fine, installed fine.

This time around testing, emails opened MUCH faster, in fact so much that I am considering replacing imap with this permanently.
Status on contacts/calender is still the same unfortunately.

PKGBUILD:

# Maintainer: ngoonee <n g    o o n    e e <at gmail.com, delete all spaces>>
pkgname=evolution-mapi
pkgver=0.26.2
pkgrel=1
pkgdesc="MAPI plugin for evolution."
arch=('i686' 'x86_64')
url="http://www.go-evolution.org"
license=('GPL3')
depends=('libmapi=0.8')
options=(!makeflags)
source=(http://ftp.gnome.org/pub/gnome/sources/evolution-mapi/0.26/${pkgname}-${pkgver}.tar.gz)

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:/usr/local/lib/pkgconfig
  ./configure --prefix=/usr/local
  make || return 1
  make DESTDIR="$pkgdir/" install

  # Create necessary symlinks, for files from libmapi and samba4 installs
  for i in libmapi libdcerpc libldb libndr libsamba-hostconfig; do
    ln -s ./${i}.so ${pkgdir}/usr/local/lib/${i}.so.0
  done
}
md5sums=('95b7d814d65870c5669e38595bd36bec')

Offline

#10 2009-08-07 16:03:33

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

Hi Tinuva, thanks for the heads-up. Did not know there was a 2.26 AND 2.27 out, will update the OP once I get the time (very busy nowadays). Concerning contacts and calendar, please refer to the feature comparator, contacts aren't really working yet.


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#11 2009-08-10 09:28:28

alex_anthony
Member
From: UK
Registered: 2007-09-25
Posts: 344

Re: evolution-mapi - My first PKGBUILDs, please advise.

If you're having problems with the conflicts with samba 3, have a look at http://wiki.samba.org/index.php/Franky
if you build this and have it provide samba 3, it may work dependency-wise

Offline

#12 2009-08-10 09:52:04

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

Thank you alex_anthony, that's a great find. Unfortunately, not using samba3 myself, I'm unable to really test this. Will add it on to the bug report.


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#13 2009-08-24 09:44:08

Tinuva
Member
From: South Africa/Cape Town
Registered: 2008-05-29
Posts: 37
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

alex_anthony wrote:

If you're having problems with the conflicts with samba 3, have a look at http://wiki.samba.org/index.php/Franky
if you build this and have it provide samba 3, it may work dependency-wise

I see the official package is still at Samba 3.3.7, however according to this link Samba 3.4 also includes the Samba 4 source though only the Samba 3 code gets compiled by default, however, the '--enable-merged-build' option is set, the Samba 4 source code in the 'source4' folder will also be compiled. The Samba3 and Samba4 daemons run in parallel and share tasks, with Samba3 dealing with SMB ports and Samba4 taking care of Kerberos, LDAP and WINS.

Makes alex_anthony's suggestion much easier in my books. Only question is whether the MAPI plugin will work with that setup.

Offline

#14 2009-08-24 10:01:56

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

I would be willing to test that, but would like to wait till 3.4 hits our repos. Once it does I'll recompile with --enable-merged-build and test if it works. If it does, then I'll update the above PKGBUILDs and probably contribute them to the AUR (assuming the /usr/local problem is solved by all this hackery).


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#15 2010-02-04 18:56:28

QuimaxW
Member
From: Papua New Guinea
Registered: 2006-12-03
Posts: 228
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

I'm trying this now...so we'll see how it goes. I'm hoping it works.


"He is no fool who gives what he cannot keep to gain that which he cannot lose." -Jim Elliot

Offline

#16 2010-02-04 19:16:47

QuimaxW
Member
From: Papua New Guinea
Registered: 2006-12-03
Posts: 228
Website

Re: evolution-mapi - My first PKGBUILDs, please advise.

It all compiled/installed! The only change I had to make was remove the version dependency for tdb in samba4. With tdb 1.2.0 from the repos it compiled fine.

Currently Evolution is syncronizing with our Exchange 2007 server, so it's looking pretty good!


"He is no fool who gives what he cannot keep to gain that which he cannot lose." -Jim Elliot

Offline

#17 2010-02-05 03:23:49

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

Change made smile. Actually I changed that locally myself some time back but forgot to update this. Thanks.


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#18 2010-04-06 11:08:59

gesocks
Member
Registered: 2009-11-12
Posts: 4

Re: evolution-mapi - My first PKGBUILDs, please advise.

Hello,

i'm trying to get evolution-mapi to work with Evolution 2.30. I've updated the packagebuilds to libmapi 0.9 and samba 4 alpha 10.
After creating a package for tevent everything is compiling now, but when i try to add an account Evolution crashes.

Does anybody have a working evolution-mapi with Evolution 2.30?

Greets

Offline

#19 2010-04-06 23:38:48

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

Yes, I get the crashing as well. You need to update the PKGBUILD for evolution-mapi as well I'm sure, to grab from this link.

http://ftp.gnome.org/pub/gnome/sources/ … mapi/0.30/


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

#20 2010-04-07 07:10:56

gesocks
Member
Registered: 2009-11-12
Posts: 4

Re: evolution-mapi - My first PKGBUILDs, please advise.

I'm already using evolution-mapi 0.30.

Offline

#21 2010-04-13 06:15:40

ngoonee
Forum Fellow
From: Between Thailand and Singapore
Registered: 2009-03-17
Posts: 7,354

Re: evolution-mapi - My first PKGBUILDs, please advise.

http://bbs.archlinux.org/viewtopic.php?pid=625367

This is the place I actually posted my final PKGBUILDs, please don't post here anymore. Try it out and let me know how it works.


Allan-Volunteer on the (topic being discussed) mailn lists. You never get the people who matters attention on the forums.
jasonwryan-Installing Arch is a measure of your literacy. Maintaining Arch is a measure of your diligence. Contributing to Arch is a measure of your competence.
Griemak-Bleeding edge, not bleeding flat. Edge denotes falls will occur from time to time. Bring your own parachute.

Offline

Board footer

Powered by FluxBB