Arch Linux

tavianator

Member

From: Waterloo, ON, Canada

Registered: 2007-08-21

Posts: 858

Website

Wallpaper

I rendered this image in POV-Ray for something a while ago and just found it again, and figured it would make a nice wallpaper with some tweaking.  It looks like this (1920x1200):

The code to render it is this; if you want it in a different resolution, "povray -w<width> -h<height> orbs.pov" should render it in a few seconds.

// Copyright (C) 2007-2010 Tavian Barnes
// Distributed under the terms of the WTFPL version 2
// As published by Sam Hocevar
// http://sam.zoy.org/wtfpl/

// -w1920 -h1200

camera {
  location  <3.0, 6.0, -11.0>
  right     x*image_width/image_height
  look_at   0
}

background {
  color rgb 1
}

// inside center sphere
light_source {
  0,
  color rgb 1
}

light_source {
  2*y,
  color rgb 1
}

plane {
  y,
  -1
  hollow on
  pigment {
    rgb <0.73, 0.90, 0.97>
  }
  finish {
    diffuse 0.35
    ambient .5
  }
}

#macro sph(center)
  sphere {
    center,
    1
    texture {
      crackle
      scale 0.5
      
      texture_map {
        [ 0.03
          pigment {
            color rgb 1
          }
          finish {
            ambient 1
          }
          normal {
            facets size 0.1
          }
        ]
        [ 0.04
          pigment {
            color rgbf <1, 1, 1, 0.9>
          }
          finish {
            reflection { 0.2 }
            specular 0.1
            roughness 0.02
            conserve_energy
          }
          normal {
            facets size 0.1
          }
        ]
      }
    }
    interior {
      ior 1.3
    }
  }
#end

object {
  sph(<-2.5, 0, 2.5>)
}

object {
  sph(<0, 0, 2.5>)
}

object {
  sph(<2.5, 0, 2.5>)
}

object {
  sph(<-2.5, 0, 0>)
}

object {
  sph(<0, 0, 0>)
}

object {
  sph(<2.5, 0, 0>)
}

object {
  sph(<-2.5, 0, -2.5>)
}

object {
  sph(<0, 0, -2.5>)
}

object {
  sph(<2.5, 0, -2.5>)
}

Parts of the spheres look a bit grainy and antialiasing didn't help; I'll try to fix this and post an updated version.