[Solved] Compiling kdelibs 4.5 not recognizes FAM

zuargo · 2010-08-25 03:14:49

Hello all ;D

Why I compile kdelibs?

Becouse I need the debugging symbols, which are stripped from the package in the official repository (the packagers compile using the option "strip" in makepkg.conf. I add the option '!strip' to the default PKGBUILD). I need them to get a full backtrace using gdb and after reporting bugs on bugs.kde.org.

What is FAM?

$ pacman -Si fam
Descripción    : File Alteration Monitor

So, when I compile kdelibs 4.5 using the PKGBUILD, got by using abs (extra repo), I get this message:

The following optional packages could NOT be located on your system.
* FAM <http://oss.sgi.com/projects/fam>
File Alteration Monitor
Provides file alteration notification facilities using a separate service.

First I installed FAM using pacman:

$ sudo pacman -S fam

But still I got the message.

Then I compiled the package FAM using the default PKGBUILD (abs) but adding the option '!strip'. Still I got the message.

Really I don't know why still get the message if the package (fam) is installed on my system:

$ pacman -Ss fam
extra/fam 2.7.0-14 [installed]
    File Alteration Monitor

Perhaps the problem is in the PKGBUILD of kdelibs 4.5:

# $Id: PKGBUILD 60156 2009-12-01 10:21:15Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=kdelibs
pkgver=4.5.0
pkgrel=1
pkgdesc="KDE Core Libraries"
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
depends=('shared-mime-info' 'hal' 'xz' 'enchant' 'jasper' 'openexr' 'giflib'
         'strigi' 'libxtst' 'soprano' 'ca-certificates' 'xdg-utils' 'qca' 'polkit-qt'
         'libxss' 'phonon' 'shared-desktop-ontologies' 'attica' 'libxcursor' 'libdbusmenu-qt'
     'hicolor-icon-theme')
makedepends=('pkgconfig' 'cmake' 'automoc4' 'intltool' 'avahi' 'libgl' 'hspell' 'docbook-xsl')
replaces=('arts' 'kdelibs-experimental')
options=('!strip')
install='kdelibs.install'
source=("http://download.kde.org/stable/${pkgver}/src/${pkgname}-${pkgver}.tar.bz2"
        'kde-applications-menu.patch' 'archlinux-menu.patch' 'abs-syntax-highlight.patch')
sha1sums=('b1f6523d608433d4ed81c3ae7343a893942d8768'
          '86ee8c8660f19de8141ac99cd6943964d97a1ed7'
          '63a850ab4196b9d06934f2b4a13acd9f7739bc67'
          'd994f262356af5b9e4e9619646e471bd98c91efb')

build() {
       cd ${srcdir}/${pkgname}-${pkgver}

       # avoid file conflict with gnome-menu
       patch -p1 -i $srcdir/kde-applications-menu.patch
       # add Archlinux menu entry
       patch -p1 -i $srcdir/archlinux-menu.patch
       # add syntax highlightning for PKGBUILD and .install files
       patch -p1 -i $srcdir/abs-syntax-highlight.patch

       cd ${srcdir}
       mkdir build
       cd build
       cmake ../${pkgname}-${pkgver} \
               -DCMAKE_BUILD_TYPE=debugfull \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Arch Linux' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF \
               -DKAUTH_BACKEND=PolkitQt-1
       make
}

package() {
       cd $srcdir/build
       make DESTDIR=$pkgdir install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f $pkgdir/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt $pkgdir/usr/share/apps/kssl/ca-bundle.crt
}

Just I added the option !strip and changed the flag -DCMAKE_BUILD_TYPE from Release to debugfull

Or maybe this is a issue of the kdelibs source code

Does anyone has any idea?

I was to report this as bug on the archlinux bug tracking but first, I prefer ask

Thanks so much ;D and excuse my poor english I talk spanish

Last edited by zuargo (2010-08-25 03:16:39)

Pierre · 2010-08-25 03:31:28

You want to remove "-DWITH_FAM=OFF"

Arch Linux

#1 2010-08-25 03:14:49

[Solved] Compiling kdelibs 4.5 not recognizes FAM

#2 2010-08-25 03:31:28

Re: [Solved] Compiling kdelibs 4.5 not recognizes FAM

Board footer