Arch Linux

an-prata

Member

Registered: 2023-06-18

Posts: 3

[SOLVED] Requiring the "*-git" version of a package

The normal version of a dependency for this package is broken, because one of its dependencies fails to build. This is mitigated by moving to a greater version of python, specifically version >= 3.7. Because of this I have created a git version of the package, which beyond just using the git repo also requires a version of python >= 3.7. However, when using this new package in my dependency list it still attempts to use the broken dependency. I already have the "-git" version of the dependency installed and they should conflict. The AUR page also doesn't show my "-git" version as a provider in the dependencies section. How can I register my package as a provider for this (it already has "provides=('xyz)") and require that this specific provider is used?

Here's the PKGBUILD for the package I want to reuire the git verison:

# Maintainer: Evan Overman <evanrileyoverman@gmail.com>
# Contributer: Francesco Minnocci <ascoli dot minnocci at gmail dot com>

pkgname=miniplayer-git
_pkgname=miniplayer
pkgver=1.8.1.r7.g19f6759
pkgrel=2
pkgdesc='A curses based mpd client with basic functionality and album art written for the Kitty terminal.'
url='https://github.com/guardkenzie/miniplayer'
depends=('python>=3.7' 'python-mpd2' 'python-pixcat-git' 'ueberzug' 'python-colorthief')
makedepends=('git' 'python-setuptools')
provides=('miniplayer')
conflicts=('miniplayer')
license=('MIT')
arch=('any')
source=("${_pkgname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgname}"
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build(){
	cd "${srcdir}/${_pkgname}"
	python setup.py build
}


package() {
	cd "${srcdir}/${_pkgname}"
	python setup.py install --prefix=/usr --root="$pkgdir/" --optimize=1 --skip-build
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

And for the git package that should provide the "python-pixcat-git" package:

# Maintainer: Evan Overman <evanrileyoverman@gmail.com>
# Contributer: Francesco Minnocci <ascoli dot minnocci at gmail dot com>

pkgname=python-pixcat-git
_pkgname=pixcat
pkgver=0.1.4r25.69e35c0
pkgrel=2
pkgdesc="CLI and Python API to display images on a kitty terminal with optional resizing."
arch=(any)
url='https://github.com/mirukana/pixcat'
license=('LGPL3')
depends=('python>=3.7' 'python-blessed' 'python-pillow' 'python-docopt' 'python-requests' 'python-ansiwrap')
makedepends=('python-setuptools' 'git')
provides=('pixcat')
conflicts=('pixcat')
source=("${_pkgname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${_pkgname}"

	# Get the version number.
	printf "0.1.4r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build(){
  cd "${srcdir}/${_pkgname}"

  python setup.py build
}

package() {
  cd "${srcdir}/${_pkgname}"
  python setup.py install --prefix=/usr --root="$pkgdir/" --optimize=1 --skip-build
}

Last edited by an-prata (2023-06-18 20:46:51)

a821

Member

Registered: 2012-10-31

Posts: 381

Re: [SOLVED] Requiring the "*-git" version of a package

did you forget to update .SRCINFO?

seth

Member

Registered: 2012-09-03

Posts: 54,562

Re: [SOLVED] Requiring the "*-git" version of a package

Forgot to update https://wiki.archlinux.org/title/.SRCINFO ?

Edit: fuck.

Last edited by seth (2023-06-18 20:25:14)

---

How to upload text · How to boot w/o GUI · Disable Windows Fast-Start! · Fix your xinitrc

an-prata

Member

Registered: 2023-06-18

Posts: 3

Re: [SOLVED] Requiring the "*-git" version of a package

yes I did... thank you so much and sorry for the trivial problem.

a821

Member

Registered: 2012-10-31

Posts: 381

Re: [SOLVED] Requiring the "*-git" version of a package

Remember to mark your post as [solved].

an-prata

Member

Registered: 2023-06-18

Posts: 3

Re: [SOLVED] Requiring the "*-git" version of a package

Got it! thanks again!