[Request] Jriver 19 for linux

hifi25nl · 2014-04-06 09:59:41

Could someone help for an AUR package for one of the best media center ever made?

There is a beta version for debian:
http://yabb.jriver.com/interact/index.php?board=35.0

and also this discussion about archlinux:

http://yabb.jriver.com/interact/index.php?topic=84651.0

The big problem is libcurl and fonts (see discussion above)-

Scimmia · 2014-04-06 15:44:52

libcurl isn't a big problem, we can make a package for the old lib. Are the other version issues still valid? libcrypto++ and libboost?

The font thing is just dumb. They should include the font they need if it's that specific. Much better would be to just use fontconfig,

Edit, OK, since there wasn't a soname bump in libcurl, it will be a problem. We can just build it and put it in the path they specify, though.

Edit2, they're shipping what they need for libcryptolib and libboost_regex now, so that's a non-issue. Just comes down to making a package for the version of curl they need and finding the font.

Edit3: This runs for me. I'm sure it's missing deps and optdeps, though.

# Contributor: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Florian Pritz <flo@xssn.at>

pkgbase=curl
pkgname=lib32-$pkgbase-jriver
pkgver=7.23.1
pkgrel=1
pkgdesc="An URL retrieval utility and library for JRiver Media Center(32-bit)"
arch=('x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('bash' 'ca-certificates' 'lib32-libssh2' $pkgbase)
source=("http://curl.haxx.se/download/$pkgbase-$pkgver.tar.bz2")
md5sums=('0296d3196b4bf82c896a869b38dbc5f2')


build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"

  cd "$srcdir/$pkgbase-$pkgver"

  ./configure \
    --with-random=/dev/urandom \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --disable-dependency-tracking \
    --enable-ipv6 \
    --disable-ldaps \
    --disable-ldap \
    --disable-manual \
    --enable-versioned-symbols \
    --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
    --with-random=/dev/urandom \
    --without-libidn \
    --libdir=/usr/lib/jriver/MediaCenter19/ \
    --enable-threaded-resolver

  make
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"

  make DESTDIR="$pkgdir" install

  rm -rf "$pkgdir/usr/"{bin,include,share,lib/jriver/MediaCenter19/pkgconfig}
  mv "$pkgdir/usr/lib/jriver/MediaCenter19" "$pkgdir/usr/lib/jriver/Media Center 19"

  install -d "$pkgdir/usr/share/licenses"
  ln -s $pkgbase "$pkgdir/usr/share/licenses/$pkgname"
}

# Contributor: Doug Newgard <scimmia at archlinux dot info>

pkgname=jriver-media-center
_debpkgver=19.0.124
_debpkgrel=5
pkgver=$_debpkgver.$_debpkgrel
pkgrel=1
pkgdesc="The Most Comprehensive Media Software"
arch=('x86_64')
url="http://www.jriver.com/"
license=('unknown')
depends=('lib32-alsa-lib' 'lib32-curl-jriver' 'lib32-gcc-libs' 'lib32-libx11')
source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver-$_debpkgrel.deb")
sha256sums=('216d76969cbf85670230e0b9b6ef39b690f6040c90a313445f7e1f8bbdc49b8b')

package() {
  cd "$srcdir"
  bsdtar xf data.tar.gz -C "$pkgdir"
}

Last edited by Scimmia (2014-04-07 01:03:28)

hifi25nl · 2014-04-07 07:34:06

Oh...thank you!

Scimmia · 2014-04-07 16:23:14

Oh, and add 'ttf-ms-fonts' to the deps of jriver-media-center. I think that will fix your font problem.

hifi25nl · 2014-04-07 16:45:56

I have 'ttf-ms-fonts' installed but the fonts are wrong.
They are speaking of this

-b&h-lucida-medium-r-normal-sans-12-120-75-75-p-71-iso10646-1

mouseman · 2014-04-07 17:07:37

I'm giving this a swing but its throwing me an error on makepkg on the curl pkg:

$ makepkg
==> Making package: curl 7.23.1-1 (Mon Apr 7 18:59:20 CEST 2014)
==> Checking runtime dependencies...
==> Checking buildtime dependencies...
==> Retrieving sources...
-> Downloading curl-7.23.1.tar.bz2...
% Total % Received % Xferd Average Speed Time Time Time Current
Dload Upload Total Spent Left Speed
100 2320k 100 2320k 0 0 5220k 0 --:--:-- --:--:-- --:--:-- 5215k
==> Validating source files with md5sums...
curl-7.23.1.tar.bz2 ... Passed
==> Extracting sources...
-> Extracting curl-7.23.1.tar.bz2 with bsdtar
==> Starting build()...
checking whether to enable maintainer-specific portions of Makefiles... no
checking whether to enable debug build options... no
checking whether to enable compiler optimizer... (assumed) yes
checking whether to enable strict compiler warnings... no
checking whether to enable compiler warnings as errors... no
checking whether to enable curl debug memory tracking... no
checking whether to enable c-ares for DNS lookups... no
checking for sed... /usr/bin/sed
checking for grep... /usr/bin/grep
checking for egrep... /usr/bin/grep -E
checking for ar... /usr/bin/ar
checking for a BSD-compatible install... /usr/bin/install -c
checking whether build environment is sane... yes
checking for gawk... gawk
checking whether make sets $(MAKE)... yes
checking curl version... 7.23.1
checking build system type... x86_64-unknown-linux-gnu
checking host system type... x86_64-unknown-linux-gnu
checking for style of include used by make... GNU
checking for gcc... gcc -m32
checking for C compiler default output file name...
configure: error: in `/home/citizen/Downloads/aur/jriver-curl/src/curl-7.23.1':
configure: error: C compiler cannot create executables
See `config.log' for more details.
==> ERROR: A failure occurred in build().
Aborting...

Could this be the reason?

d--------- 2 citizen citizen 4096 Apr 7 18:59 pkg

The config.log is nowhere to be found.

I read the wiki:
https://wiki.archlinux.org/index.php/Makepkg#Usage

and a search found this thread:
https://bbs.archlinux.org/viewtopic.php?id=140055

Which suggested to remove multilib, reinstall gcc-libs gcc binutils glibc but that doesn't help. I reenabled multilib and ran pacman -Syu again.

Any ideas what's going on here?

I tried building libjpeg6 from AUR and this worked without a glitch.

Thanks.

Scimmia · 2014-04-07 17:11:45

This is a multilib package, so you need the multilib-devel group installed. I built it in a clean chroot just fine (multilib-build from devtools).

mouseman · 2014-04-07 17:20:03

Installing multilib-devel group fixed it.

Thanks.

Scimmia · 2014-04-09 03:39:30

hifi25nl, try the xorg-fonts-75dpi package in Extra.

hifi25nl · 2014-04-09 07:09:56

I already have installed, but the right font is missing.

mouseman · 2014-04-09 09:06:39

I have both xorg-fonts-75dpi and xorg-fonts-100dpi packages installed and I can confirm that my fonts in Media Center are now correct.

hifi25nl · 2014-04-22 22:17:59

With version 129-3 lib32-curl-jriver lib32-libssh2 are not more requested.

This PKGBUILD should work fine:

# Contributor: Doug Newgard <scimmia at archlinux dot info>

pkgname=jriver-media-center
_debpkgver=19.0.129
_debpkgrel=3
pkgver=$_debpkgver.$_debpkgrel
pkgrel=1
pkgdesc="The Most Comprehensive Media Software"
arch=('x86_64')
url="http://www.jriver.com/"
license=('unknown')
depends=('lib32-alsa-lib' 'lib32-gcc-libs' 'lib32-libx11')
source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver-$_debpkgrel.deb")
#source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver.deb")
sha256sums=('30bf27fc747aabe589631ec35d6e7811fd41b4524d6b7f4ffe49c35fa745b337')

package() {
  cd "$srcdir"
  bsdtar xf data.tar.xz -C "$pkgdir"
}

Last edited by hifi25nl (2014-04-22 22:18:27)

hifi25nl · 2014-05-14 13:17:25

Updated PKGBUILD

# Contributor: Doug Newgard <scimmia at archlinux dot info>

pkgname=jriver-media-center
_debpkgver=19.0.133
_debpkgrel=2
pkgver=$_debpkgver.$_debpkgrel
pkgrel=1
pkgdesc="The Most Comprehensive Media Software"
arch=('x86_64')
url="http://www.jriver.com/"
license=('unknown')
depends=('lib32-alsa-lib' 'lib32-gcc-libs' 'lib32-libx11')
source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver-$_debpkgrel.deb")
#source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver.deb")
sha256sums=('673a4481069d80a7e807605cc2dd5faa2028cc13e19949cdffe190692c92c15b')

package() {
  cd "$srcdir"
  bsdtar xf data.tar.xz -C "$pkgdir"
}

hifi25nl · 2014-05-19 06:06:15

Update to 19.0.34

# Contributor: Doug Newgard <scimmia at archlinux dot info>

pkgname=jriver-media-center
_debpkgver=19.0.134
#_debpkgrel=2
pkgver=$_debpkgver.$_debpkgrel
pkgrel=1
pkgdesc="The Most Comprehensive Media Software"
arch=('x86_64')
url="http://www.jriver.com/"
license=('unknown')
depends=('lib32-alsa-lib' 'lib32-gcc-libs' 'lib32-libx11')
#source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver-$_debpkgrel.deb")
source=("http://files.jriver.com/mediacenter/channels/v19/latest/MediaCenter-$_debpkgver.deb")
sha256sums=('a6973f35382c737ba662191bd2a143e335caa00e9d36b014df74c6a698f6d896')

package() {
  cd "$srcdir"
  bsdtar xf data.tar.xz -C "$pkgdir"
}

fsckd · 2014-05-19 10:46:50

Instead of posting updates here, upload them to the AUR. The community will benefit more that way.

hifi25nl · 2014-05-19 19:46:40

Now is online at
https://aur.archlinux.org/packages/jriver-media-center/

I hope is all right...

Arch Linux

#1 2014-04-06 09:59:41

[Request] Jriver 19 for linux

#2 2014-04-06 15:44:52

Re: [Request] Jriver 19 for linux

#3 2014-04-07 07:34:06

Re: [Request] Jriver 19 for linux

#4 2014-04-07 16:23:14

Re: [Request] Jriver 19 for linux

#5 2014-04-07 16:45:56

Re: [Request] Jriver 19 for linux

#6 2014-04-07 17:07:37

Re: [Request] Jriver 19 for linux

#7 2014-04-07 17:11:45

Re: [Request] Jriver 19 for linux

#8 2014-04-07 17:20:03

Re: [Request] Jriver 19 for linux

#9 2014-04-09 03:39:30

Re: [Request] Jriver 19 for linux

#10 2014-04-09 07:09:56

Re: [Request] Jriver 19 for linux

#11 2014-04-09 09:06:39

Re: [Request] Jriver 19 for linux

#12 2014-04-22 22:17:59

Re: [Request] Jriver 19 for linux

#13 2014-05-14 13:17:25

Re: [Request] Jriver 19 for linux

#14 2014-05-19 06:06:15

Re: [Request] Jriver 19 for linux

#15 2014-05-19 10:46:50

Re: [Request] Jriver 19 for linux

#16 2014-05-19 19:46:40

Re: [Request] Jriver 19 for linux

Board footer