[Request] Atkinson Hyperlegible Font

uberscientist · 2020-10-16 18:45:42

I'm interested in installing this new font, not sure if there's a go to guy for AUR packaging of fonts or if I should just do it and submit, here's the info and link:

Atkinson Hyperlegible font is named after Braille Institute founder, J. Robert Atkinson. What makes it different from traditional typography design is that it focuses on letterform distinction to increase character recognition, ultimately improving readability. We are making it free for anyone to use, download here!

https://www.brailleinstitute.org/freefont

Thanks!

Last edited by uberscientist (2020-10-16 18:47:19)

Awebb · 2020-10-16 21:01:54

Wiki: Fonts. Read it. Then find the fonts package guidelines in that. See other fonts for reference. Post your PKGBUILD here if you're unsure.

twelveeighty · 2020-10-16 21:50:28

uberscientist wrote:

not sure if there's a go to guy for AUR packaging of fonts or if I should just do it and submit

There isn't a "go to guy". Whether or not you want to submit it to AUR is entirely up to you. You can of course always request if someone can add it and maintain it, but if you are able and willing to maintain it going forward, that's always the better solution.

The good news is that packaging fonts is about as straight-forward as it gets. The Font Packing Guidelines is short and sweet and also provides shortcuts to samples of PKGBUILD files.

MountainX · 2020-10-24 18:48:43

uberscientist wrote:

I'm interested in installing this new font, not sure if there's a go to guy for AUR packaging of fonts or if I should just do it and submit

I'm learning about packaging. I will volunteer to help, if you want it. I can either help create the PKGBUILD or test the installation or both.

This font is OTF. The site doesn't list a license type that I could find.

MountainX · 2020-10-24 19:24:02

This PKGBUILD works for me.

# Maintainer: TODO

pkgname=otf-atkinson-hyperlegible
pkgver=102
pkgrel=1
pkgdesc='For designers and anyone interested in making written materials easier to read across the entire visual-ability spectrum. Focuses on letterform distinction to increase character recognition, ultimately improving readability.'
arch=('any')
url='https://www.brailleinstitute.org/freefont'
license=('none')
source=("https://www.brailleinstitute.org/wp-content/uploads/atkinson-hyperlegible-font/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514.zip")
md5sums=('8b01675977bd6228cb7352af67b9a160')

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd "$srcdir/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514"/'Print Fonts'
  install -m 644 Atkinson-Hyperlegible-Bold-${pkgver}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Bold.otf"
  install -m 644 Atkinson-Hyperlegible-BoldItalic-${pkgver}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-BoldItalic.otf"
  install -m 644 Atkinson-Hyperlegible-Italic-${pkgver}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Italic.otf"
  install -m 644 Atkinson-Hyperlegible-Regular-${pkgver}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Regular.otf"
}

Questions:
1. is any license needed? The upstream source doesn't list any -- calls it "free for everyone".
2. is the source url sufficient as written in the PKGBUILD?
3. is the description too long?
4. is the pkgver (102) OK? It matches the upstream source files.
5. did I handle the space in the path 'Print Fonts' correctly?

Lone_Wolf · 2020-10-24 20:36:01

1.

https://wiki.archlinux.org/index.php/PKGBUILD#license wrote:

If after researching the issue no license can be determined, PKGBUILD.proto suggests using unknown. However, upstream should be contacted about the conditions under which the software is (and is not) available.

The zip file doesn't have any licensing or copyright imformation and "free for everyone" is not a valid license.
I suggest license=('unknown') .

Maybe upstream could use one of the Creative Common licenses , see https://creativecommons.org/about/cclicenses/

2. lgtm
3. yep, needs to be shortened
4. 2020-0514 from the filename looks like a data and could also be used. Should be checked with upstream.
5. unsure

Last edited by Lone_Wolf (2020-10-24 20:36:17)

progandy · 2020-10-24 20:45:14

The fonts contain an embedded license:

$ otfinfo -i Print\ Fonts/Atkinson-Hyperlegible-Regular-102.otf 
Family:              Atkinson Hyperlegible
Subfamily:           Regular
Full name:           AtkinsonHyperlegible-Regular
PostScript name:     AtkinsonHyperlegible-Regular
Version:             Version 1.02
Unique ID:           Version 1.02;;AtkinsonHyperlegible-Regular;2019;FL712
Description:         Atkinson Hyperlegible is a neo-grotesque typeface created by Applied Design Works for Braille Institute of America, Inc. It has been developed specifically to increase legibility for readers with low vision, and to improve character recognition. 
Designer:            Elliott Scott, Megan Eiswerth, Linus Boman, Theodore Petrosky
Designer URL:        http://helloapplied.com
Manufacturer:        Applied Design Works
Vendor URL:          https://www.BrailleInstitute.org/
Copyright:           © 2020 Braille Institute of America, Inc., a 501(c)(3) Charitable Organization.
License URL:         https://www.BrailleInstitute.org/
License Description: Braille Institute of America, Inc. provides Atkinson Hyperlegible for use, without derivatives or alteration, to the public free of charge for all non-commercial and commercial work. No attribution required.

MountainX · 2020-10-24 20:51:30

Thank you. I changed the license to unknown.

Lone_Wolf wrote:

3. yep, needs to be shortened

New proposed description is:

pkgdesc='Atkinson-Hyperlegible font is easier to read across the entire visual-ability spectrum. Focuses on letterform distinction.'

Lone_Wolf wrote:

4. 2020-0514 from the filename looks like a data and could also be used. Should be checked with upstream.

That looks like a WordPress auto-generated file name. I think the actual version is "102" based on the contents of the zip file.

MountainX · 2020-10-24 20:53:02

progandy wrote:

The fonts contain an embedded license:

$ otfinfo -i Print\ Fonts/Atkinson-Hyperlegible-Regular-102.otf 
Family:              Atkinson Hyperlegible
Subfamily:           Regular
Full name:           AtkinsonHyperlegible-Regular
PostScript name:     AtkinsonHyperlegible-Regular
Version:             Version 1.02
Unique ID:           Version 1.02;;AtkinsonHyperlegible-Regular;2019;FL712
Description:         Atkinson Hyperlegible is a neo-grotesque typeface created by Applied Design Works for Braille Institute of America, Inc. It has been developed specifically to increase legibility for readers with low vision, and to improve character recognition. 
Designer:            Elliott Scott, Megan Eiswerth, Linus Boman, Theodore Petrosky
Designer URL:        http://helloapplied.com
Manufacturer:        Applied Design Works
Vendor URL:          https://www.BrailleInstitute.org/
Copyright:           © 2020 Braille Institute of America, Inc., a 501(c)(3) Charitable Organization.
License URL:         https://www.BrailleInstitute.org/
License Description: Braille Institute of America, Inc. provides Atkinson Hyperlegible for use, without derivatives or alteration, to the public free of charge for all non-commercial and commercial work. No attribution required.

How would that be used in a PKGBUILD? I do not find an actual license file at the License URL.

loqs · 2020-10-24 20:53:29

If you wanted to avoid escaping in the path you could use:

  cd Atkinson-Hyperlegible-*/Print*

Edit:

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd $_pkgname-*/Print*
  _pkgname=Atkinson-Hyperlegible
  _typeface=(Bold BoldItalic Italic Regular)
  for _font in "${_typeface[@]}" 
  do
    install -m 644 $_pkgname-$_font-${pkgver}.otf -t "${pkgdir}/usr/share/fonts/OTF"
  done
}

Last edited by loqs (2020-10-24 21:05:36)

progandy · 2020-10-24 20:56:37

You can copy that license description into a LICENSE text file (add it to sources) and set "custom" as the license as described here:

https://wiki.archlinux.org/index.php/PKGBUILD#license

Edit: LICENSE:

© 2020 Braille Institute of America, Inc., a 501(c)(3) Charitable Organization.

https://www.BrailleInstitute.org/

Braille Institute of America, Inc. provides Atkinson Hyperlegible
for use, without derivatives or alteration, to the public free of charge
for all non-commercial and commercial work. No attribution required.

Last edited by progandy (2020-10-24 21:05:16)

MountainX · 2020-10-24 21:07:30

EDIT: I see you already edited your answer. Thank you!

progandy wrote:

You can copy that license description into a LICENSE text file (add it to sources) and set "custom" as the license as described here:
https://wiki.archlinux.org/index.php/PKGBUILD#license

OK, I will do that. I am sorry if this is a dumb question, but should all the following go into that LICENSE text file? Most examples I see list the copyright and a description, but I have only found examples of standard LICENSE files.

Copyright: © 2020 Braille Institute of America, Inc., a 501(c)(3) Charitable Organization.
License URL: https://www.BrailleInstitute.org/
License Description: Braille Institute of America, Inc. provides Atkinson Hyperlegible for use, without derivatives or alteration, to the public free of charge for all non-commercial and commercial work. No attribution required.

Is anything else from the otfinfo output needed in the LICENSE text file?

otfinfo -i Print\ Fonts/Atkinson-Hyperlegible-Regular-102.otf

Last edited by MountainX (2020-10-24 21:08:19)

loqs · 2020-10-24 21:12:29

See /usr/share/licenses/libarchive/COPYING and /usr/share/licenses/python/LICENSE for examples of custom license files.

MountainX · 2020-10-24 21:15:33

I see from the otfinfo output that the actual version is 1.02

otfinfo -i Print\ Fonts/Atkinson-Hyperlegible-Regular-102.otf

However, the file are named like this:

Atkinson-Hyperlegible-Bold-102.otf

Therefore, a pkgver=1.02 will not allow this type of install command:

install -m 644 Atkinson-Hyperlegible-Bold-${pkgver}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Bold.otf"

Any suggestions? I could use sed in package() to remove any punctuation from the pkgver, but that seems like a hack.

loqs · 2020-10-24 21:31:27

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd $_pkgname-*/Print*
  _typeface=(Bold BoldItalic Italic Regular)
  for _font in "${_typeface[@]}" 
  do
    install -m 644 $_pkgname-$_font-${pkgver/./}.otf "${pkgdir}/usr/share/fonts/OTF/$_pkgname-$_font.otf"
  done
}

Edit:

{pkgver/./}

Removes the .

Last edited by loqs (2020-10-24 21:35:29)

MountainX · 2020-10-24 21:59:02

loqs wrote:

Edit:
{pkgver/./}
Removes the .

Thanks. That will work. But there are multiple files, so what about transforming the pkgver just once, similar to this? This should also handle dashes (and other unwanted chars) in case they show up in the future.

  filever="${pkgver//[^[:alnum:]]/}"
  install -m 644 Atkinson-Hyperlegible-Bold-${filever}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Bold.otf"

Is that considered good practice inside the package() function?

Lone_Wolf · 2020-10-24 22:07:51

Please add local before filever to declare it as a variable local to the package() function.

loqs · 2020-10-24 22:15:46

MountainX wrote:

loqs wrote:
Edit:
{pkgver/./}
Removes the .
Thanks. That will work. But there are multiple files, so what about transforming the pkgver just once, similar to this?

The loop handled the multiple files, the string was transformed four times. Whichever form you are happy with.

MountainX · 2020-10-24 22:34:50

Lone_Wolf wrote:

Please add local before filever to declare it as a variable local to the package() function.

Thank you. I'll post the PKGBUILD after I finish testing it in a chroot. (I assume the OP may want to be the maintainer.)

MountainX · 2020-10-24 23:09:21

Here is a working PKGBUILD. I checked it in a chroot. I went with the exact file and directory names instead of using wildcards. My first thoght was it would be better to use the exact names, but I now I think using loqs' method is better, right?

# Maintainer: TODO

pkgname=otf-atkinson-hyperlegible
pkgver=1.02
pkgrel=1
pkgdesc='Atkinson-Hyperlegible font is easier to read across the entire visual-ability spectrum. Focuses on letterform distinction.'
arch=('any')
url='https://www.brailleinstitute.org/freefont'
license=('custom')
source=("https://www.brailleinstitute.org/wp-content/uploads/atkinson-hyperlegible-font/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514.zip" LICENSE)
md5sums=('8b01675977bd6228cb7352af67b9a160'
         'de83b41a6fe51ec631930f34459574f3')
sha256sum=('9e1a65d53ddadc8253791e958a07bf5aba210ef6155ea9c91b2b4c46bbce53e3'
          '3fef2367bc4803bef3c06adad5f05f59305612009fee07a92bb6b574ad5e5974')

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd "$srcdir/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514"/'Print Fonts'
  local filever="${pkgver//[^[:alnum:]]/}"
  install -m 644 Atkinson-Hyperlegible-Bold-${filever}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Bold.otf"
  install -m 644 Atkinson-Hyperlegible-BoldItalic-${filever}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-BoldItalic.otf"
  install -m 644 Atkinson-Hyperlegible-Italic-${filever}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Italic.otf"
  install -m 644 Atkinson-Hyperlegible-Regular-${filever}.otf "${pkgdir}/usr/share/fonts/OTF/Atkinson-Hyperlegible-Regular.otf"
  install -dm 755 "${pkgdir}/usr/share/licenses/$pkgname"
  install  -m 644 "${srcdir}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Here's the alternative version (untested):

# Maintainer: TODO

pkgname=otf-atkinson-hyperlegible
pkgver=1.02
pkgrel=1
pkgdesc='Atkinson-Hyperlegible font is easier to read across the entire visual-ability spectrum. Focuses on letterform distinction.'
arch=('any')
url='https://www.brailleinstitute.org/freefont'
license=('custom')
source=("https://www.brailleinstitute.org/wp-content/uploads/atkinson-hyperlegible-font/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514.zip" LICENSE)
md5sums=('8b01675977bd6228cb7352af67b9a160'
         'de83b41a6fe51ec631930f34459574f3')
sha256sum=('9e1a65d53ddadc8253791e958a07bf5aba210ef6155ea9c91b2b4c46bbce53e3'
          '3fef2367bc4803bef3c06adad5f05f59305612009fee07a92bb6b574ad5e5974')

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd $_pkgname-*/Print*
  _typeface=(Bold BoldItalic Italic Regular)
  for _font in "${_typeface[@]}" 
  do
    install -m 644 $_pkgname-$_font-${pkgver/./}.otf "${pkgdir}/usr/share/fonts/OTF/$_pkgname-$_font.otf"
  done
  install -dm 755 "${pkgdir}/usr/share/licenses/$pkgname"
  install  -m 644 "${srcdir}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

LICENSE

© 2020 Braille Institute of America, Inc., a 501(c)(3) Charitable Organization.

https://www.BrailleInstitute.org/

Braille Institute of America, Inc. provides Atkinson Hyperlegible
for use, without derivatives or alteration, to the public free of charge
for all non-commercial and commercial work. No attribution required.

Last edited by MountainX (2020-10-24 23:13:30)

MountainX · 2020-10-25 01:25:09

loqs wrote:

The loop handled the multiple files, the string was transformed four times. Whichever form you are happy with.

I think your method is better. At first I thought it would be more "robust" to do it my way (although in hindsight I'm not sure why I thought that). Then I realized your method will be more maintenance-friendly upon future upstream updates or changes (as long as they stay consistent with the file naming convention they are using).

Last edited by MountainX (2020-10-25 01:25:37)

MountainX · 2020-10-30 16:32:55

@uberscientist: are you planning to submit this package to the AUR?

Here is the final PKGBUILD we came up with (thanks to the help above):

# Maintainer: TODO

pkgname=otf-atkinson-hyperlegible
pkgver=1.02
pkgrel=1
pkgdesc='Atkinson-Hyperlegible font is easier to read across the entire visual-ability spectrum. Focuses on letterform distinction.'
arch=('any')
url='https://www.brailleinstitute.org/freefont'
license=('custom')
source=("https://www.brailleinstitute.org/wp-content/uploads/atkinson-hyperlegible-font/Atkinson-Hyperlegible-Font-Print-and-Web-2020-0514.zip" LICENSE)
md5sums=('8b01675977bd6228cb7352af67b9a160'
         'de83b41a6fe51ec631930f34459574f3')
sha256sum=('9e1a65d53ddadc8253791e958a07bf5aba210ef6155ea9c91b2b4c46bbce53e3'
          '3fef2367bc4803bef3c06adad5f05f59305612009fee07a92bb6b574ad5e5974')

package() {
  install -dm 755 "${pkgdir}/usr/share/fonts/OTF"
  cd $_pkgname-*/Print*
  local _typeface=(Bold BoldItalic Italic Regular)
  for _font in "${_typeface[@]}" 
  do
    install -m 644 $_pkgname-$_font-${pkgver/./}.otf "${pkgdir}/usr/share/fonts/OTF/$_pkgname-$_font.otf"
  done
  install -dm 755 "${pkgdir}/usr/share/licenses/$pkgname"
  install  -m 644 "${srcdir}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

MountainX · 2020-11-03 03:34:42

Since I got no reply here after waiting for the OP, I started to submit this package today. However, I see somebody already submitted this package to the AUR recently: https://aur.archlinux.org/packages/atki … ble-fonts/

Unfortunately, the submitted PKGBUILD does not appear to be as good as the one we created in this discussion. The version number is not entirely up to par, and there is no license file included.

On the other hand, that existing PKGBUILD does install both TTF and OTF fonts, whereas I was only interested in the OTF version and that's all this PKGBUILD installs.

In a case where the one upstream source file contains both font types, what is the correct way?

What do you guys suggest to do? EDIT: I also left a comment on the AUR page referring to this thread.

Last edited by MountainX (2020-11-03 03:46:29)

Awebb · 2020-11-03 05:14:22

MountainX wrote:

What do you guys suggest to do? EDIT: I also left a comment on the AUR page referring to this thread.

That's exactly what you do in such a situation.

nstickney · 2020-11-03 13:45:36

MountainX wrote:

I see somebody already submitted this package to the AUR recently: https://aur.archlinux.org/packages/atki … ble-fonts/
EDIT: I also left a comment on the AUR page referring to this thread.

Hey, I saw the comment on the AUR package. Great work here! I'll make the updates later today when I'm sitting at an Arch box and not a Windows one.

@MountainX, would you like to Co-Maintain the package?

EDIT:

MountainX wrote:

Here is the final PKGBUILD we came up with (thanks to the help above):
  ...
  local _typeface=(Bold BoldItalic Italic Regular)
  for _font in "${_typeface[@]}" 
  ...
}

Using arrays is a Bashism, and bash isn't in base-devel.

Why not just this?

for _font in $_pkgname-*-${pkgver/./}.otf

Last edited by nstickney (2020-11-03 13:54:26)

Arch Linux

#1 2020-10-16 18:45:42

[Request] Atkinson Hyperlegible Font

#2 2020-10-16 21:01:54

Re: [Request] Atkinson Hyperlegible Font

#3 2020-10-16 21:50:28

Re: [Request] Atkinson Hyperlegible Font

#4 2020-10-24 18:48:43

Re: [Request] Atkinson Hyperlegible Font

#5 2020-10-24 19:24:02

Re: [Request] Atkinson Hyperlegible Font

#6 2020-10-24 20:36:01

Re: [Request] Atkinson Hyperlegible Font

#7 2020-10-24 20:45:14

Re: [Request] Atkinson Hyperlegible Font

#8 2020-10-24 20:51:30

Re: [Request] Atkinson Hyperlegible Font

#9 2020-10-24 20:53:02

Re: [Request] Atkinson Hyperlegible Font

#10 2020-10-24 20:53:29

Re: [Request] Atkinson Hyperlegible Font

#11 2020-10-24 20:56:37

Re: [Request] Atkinson Hyperlegible Font

#12 2020-10-24 21:07:30

Re: [Request] Atkinson Hyperlegible Font

#13 2020-10-24 21:12:29

Re: [Request] Atkinson Hyperlegible Font

#14 2020-10-24 21:15:33

Re: [Request] Atkinson Hyperlegible Font

#15 2020-10-24 21:31:27

Re: [Request] Atkinson Hyperlegible Font

#16 2020-10-24 21:59:02

Re: [Request] Atkinson Hyperlegible Font

#17 2020-10-24 22:07:51

Re: [Request] Atkinson Hyperlegible Font

#18 2020-10-24 22:15:46

Re: [Request] Atkinson Hyperlegible Font

#19 2020-10-24 22:34:50

Re: [Request] Atkinson Hyperlegible Font

#20 2020-10-24 23:09:21

Re: [Request] Atkinson Hyperlegible Font

#21 2020-10-25 01:25:09

Re: [Request] Atkinson Hyperlegible Font

#22 2020-10-30 16:32:55

Re: [Request] Atkinson Hyperlegible Font

#23 2020-11-03 03:34:42

Re: [Request] Atkinson Hyperlegible Font

#24 2020-11-03 05:14:22

Re: [Request] Atkinson Hyperlegible Font

#25 2020-11-03 13:45:36

Re: [Request] Atkinson Hyperlegible Font

Board footer